Discussion :

[elodouwen]

salut à tous
ma grand mère est malvoyante mais peut encore faire ses mails sur son vieux mac ; par contre, quand elle doit me donner le mot de passe de la session teamviewer c'est toute une aventure car c'est écrit en petit.
je cherche à faire un script tout simple qui fait une capture d'écran et qui l'envoie par mail à mon adresse perso
comme ça je peux voir son mot de passe et le taper sur mon ordi
je précise que sur son mac elle n'a aucune donnée sensible sauf 3 ou 4 mails par jour ne contenant des choses qui n'ont d'importance que l'aventure humaine qui est derrière..
je ne fais jamais de programmation en applescript et je suis débordé de boulot, si peut être il se trouve quelqu'un dans la liste qui peut me faire le script en 3 secondes, j'avoue que je serais preneur...
Vincent

[PBELL]

Bonjour,
Le plus simple est de faire un Service Automator qui contient une seule action: "exécuter un Applescript".
Ouvre Automator, créer un nouveau service.
En haut, spécifie qu'il n'y a aucune entrée et que le service est valable pour toutes applications (ou éventuellement Safari si le code Teamviewer est sur Safari)
Ajoute une action "Exécuter un Applescript" et remplace, dans cette action, l'emplacement prévu du code par le script ci-dessous en ayant pris soin de changer ton adresse mail :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
set Fichier to ((path to desktop folder) as string) & "Copie_Ecran.png"
do shell script "screencapture  -tjpg " & quoted form of POSIX path of Fichier-- copie l'écran dans le fichier (jpg pour meilleure compression)
set Mon_Sujet to "copie d'écran"
set Mon_Content to "Voici en pj la copie d'écran"
set Mon_Destinataire to "toto@gmail.com" -- met ici ton adresse email


tell application "Mail"
activate
    set newMessage to make new outgoing message with properties {visible:true, subject:Mon_Sujet, content:Mon_Content}
    tell newMessage
make new to recipient at end of to recipients with properties {name:"", address:Mon_Destinataire}
make new attachment with properties {file name:(Fichier as alias)} at after the last paragraph
delay 2 -- attendre 2 secondes que le fichier soit copié en pj par mail
send
    end tell
end tell


tell application "Finder" to delete (Fichier as alias) -- supprimer le fichier
delay 1 -- Attente de la fin de l'envoi du mail (selon taille écran !)
say "le mail est envoyé"

Enregistre le service. Il sera accessible dans le menu Service (ou Safari/Service si tu as restreint à Safari).
Tu peux aussi ajouter un raccourci clavier pour l'appeler directement, à condition de ne pas utiliser des raccourcis qui exigent déjà ! Pour cela, voir Clavier/Raccourcis/Services dans les préférences système.

Selon le Mac utilisé, il se peut que tu sois amené à changer les délais, en particulier celui pendant lequel mail copie le fichier en pj. Cela dépend aussi de la taille de l'écran.
J'ai ajouté un "say" qui énoncera que le mail est envoyé.
C'est plus pratique qu'un dialogue pour une personne qui a des difficultés à lire. Cela implique que la voix soit réglée dans les préférences système.

Cordialement