Discussion :

[127.0.0.1]

Bonjour à tous !


J'ai réalisé une procédure faisant un select avec une clause where A = B, avec un curseur afint d'obtenir plusieurs résultats. Tout fonctionne à merveille !
voici un exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
CREATE OR REPLACE PROCEDURE a_proc
AS
    CURSOR Mon_Curseur IS
        SELECT  REF_BATCH
        FROM    TBL_REF_MAP
        WHERE   TRIGRAMME = 'AA';
 
    TAB  Mon_Curseur%ROWTYPE;
    TYPE TAB_CURSEUR IS TABLE OF TAB%TYPE; 
    StrTab TAB_CURSEUR;
BEGIN
    OPEN  Mon_Curseur;
    FETCH Mon_Curseur BULK COLLECT INTO StrTab;
    CLOSE Mon_Curseur;
 
    FOR indx IN 1..StrTab.COUNT LOOP
        DBMS_OUTPUT.PUT_LINE(StrTab(indx).REF_BATCH);
    END LOOP;
END a_proc;
/
EXECUTE  a_proc

Ce qui me renvoit :

Procédure PL/SQL terminée.

AA-S****
AA-S****-*********-********

Les deux résultats sont correct

Dans un soucis de perfection, je me suis dit.. allez.. faut que j'envoie mon Trigramme ou bi-gramme en paramètre !
et la ça ce complique

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
CREATE OR REPLACE PROCEDURE Entre_Trigramme (Trigramme IN VARCHAR2)
AS
        CURSOR  Mon_Curseur IS
        SELECT  REF_BATCH
        FROM    TBL_REF_MAP
        WHERE   TRIGRAMME = Trigramme ;
 
        TAB  Mon_Curseur%ROWTYPE;
        TYPE TAB_CURSEUR IS TABLE OF TAB%TYPE; -- must use type
        StrTab  TAB_CURSEUR;
BEGIN
    OPEN  Mon_Curseur;
    FETCH Mon_Curseur BULK COLLECT INTO StrTab;
    CLOSE Mon_Curseur;
 
    FOR indx IN 1..StrTab.COUNT LOOP
        DBMS_OUTPUT.PUT_LINE(StrTab(indx).REF_BATCH);
    END LOOP;
 
        DBMS_OUTPUT.PUT_LINE('Trigramme en paramètre : -'|| Trigramme ||'-');
END;
/
EXECUTE Entre_Trigramme ('AA');

En renvoit j'obtiens toutes les clés qui sont présente dans la table (tout est faux).. le trigramme lui est correcte (ici 'AA' donc je l’envoi bien en paramètre )

Pourquoi ai-je obtenus un tel résultat ? cela doit provenir de ma requête sql, j'ai essayé avec '@' pour la variable Trigramme mais rien n'y fait... j'obtiens des erreurs sql

voilà, Merci de m'aider !
même si vous n'avez pas de solution fiable à 100% mais que vous avez un semblant d'idée ou de piste à explorer faites moi pars de vos commentaires !

[al1_24]

Le langage PL/SQL n'est pas sensible à la casse.
Alors comment veux-tu que dans l'expression WHERE TRIGRAMME = Trigramme, il soit fait une différence entre le paramètre de ta requête et la colonne de ta table ?
La solution la plus sûre est de changer le nom du paramètre. Pourquoi pas en le préfixant avec un p.
Et qualifier le nom de colonne dans la requête en lui adjoignant l'alias de la table.
C'est une bonne habitude à prendre. Ici, il n'y a qu'une seule table mais dès qu'il y a des jointures, les choses sont tout de suite plus claires.

[127.0.0.1]

ok j'essaierais demain ! Merci pour ces informations. Je vois souvent des allias mais je ne savais pas que ça avait autant d'importance (je trouvais qu'une requête avec plein d'alias peut rendre difficile la lecture/compréhension). Je ne savais pas également pour la casse, comme quoi ce n'est pas comme du php ou du c ^^ merci d'avoir été aussi rapide ! je vous tiens au courrant demain.

Bonne soirée

[mnitu]

La solution correcte consiste en préfixer le paramètre par le nom de la procedure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
...
WHERE   TRIGRAMME = Entre_Trigramme.Trigramme ;

[al1_24]

Merci mnitu, j'avais oublié dette syntaxe.
Mais il faut dire aussi que je ne fais du PL que sous la contrainte.

[127.0.0.1]

La solution correcte consiste en préfixer le paramètre par le nom de la procedure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
...
WHERE   TRIGRAMME = Entre_Trigramme.Trigramme ;

Merci à vous deux sa fonctionne ! J'ai maintenant une procédure avec laquelle je peu recevoir un [bigramme/trigramme] en paramètre !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
CREATE OR REPLACE PROCEDURE Entre_Trigramme (Trigramme IN VARCHAR2)
AS
        CURSOR  Mon_Curseur IS
        SELECT  REF_BATCH
        FROM    TBL_REF_MAP
        WHERE   TRIGRAMME = Entre_Trigramme.Trigramme ;
 
        TAB  Mon_Curseur%ROWTYPE;
        TYPE TAB_CURSEUR IS TABLE OF TAB%TYPE; -- must use type
        StrTab  TAB_CURSEUR;
BEGIN
    OPEN  Mon_Curseur;
    FETCH Mon_Curseur BULK COLLECT INTO StrTab;
    CLOSE Mon_Curseur;
 
    FOR indx IN 1..StrTab.COUNT LOOP
        DBMS_OUTPUT.PUT_LINE(StrTab(indx).REF_BATCH);
    END LOOP;
END;
/
EXECUTE Entre_Trigramme ('AA');

so happy !