Discussion :

[marot_r]

Bonjour à tous et merci de votre aide et de votre temps.

• J'ai trois niveaux hiérarchiques : Direction, Territoire et Groupe d'affectation.
• J'ai une requête de regroupement un peu complexe qui fait actuellement le regroupement au niveau du groupe d'affectation.
  Elle me donne entre autre le nombre de personnes. (ex : 21 personnes dans le groupes d'affectation 1).
• J'ai la possibilité de filtrer mes données par niveau hiérarchique (ex : je ne veux voir que les données du territoire 1 qui comprend 6 groupes).
  Donc j'ai fait un DCount("ClefPersonne", "MaRequête", MonFiltreVariable) pour trouver le nombre au trois niveaux avec une seule et même requête.
  MonFiltreVariable contient quelque chose comme [NoDir]=0 and [NoTerr]=1.
  Ce filtre est composé par VBA en réaction aux choix du client.

Tout allait bien jusqu'à ce que mon client me demande la possibilité d'avoir une personne dans plusieurs groupes d'affectation.
Donc si je fais un bête regroupement au niveau de la direction, une même personne est comptées autant de fois qu'elle a de groupes.

J'ai trouvé une parade : passer un paramètre [prmNiveauHierarchique] à ma requête de regroupement qui va "annuler" les niveaux hiérarchiques dont je n'ai pas besoin (ex : Annule le niveau Groupe quand je demande un total au niveau du territoire).

Là je ne trouve pas de moyen de passer à la fois le filtre ET mon paramètre ni pour le moment de voie de contournement simple.

Comme ma requête est complexe ET que je fais souvent des modifs, je n'ai pas envie d'avoir une requête pour la direction, le territoire et le groupe.

Dernier point, j'appelle ce DCount() depuis pas mal d'endroits et donc je ne peux pas supposer qu'un formulaire soit ouvert au moment où j'en ai besoin.
On pourrait envisager d'utiliser une variable globale pour passer [prmNiveauHierarchique], mais je ne suis pas un grand amateur de variable globale.

Compte tenu de ces contraintes, quelqu'un aurait-il une idée ou une piste ?

A+

[Invité]

Bonjour,

DAO est interdit ? sinon possible...

[User]

Bonsoir,

Je ne suis pas sûr de bien tout comprendre, mais la 1re idée qui me vient c'est de passer par une requête intermédiaire qui élimine les doublons au niveau des personnes, en vba ça ferait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Dim leSql as string
Dim qry as querydef
 
leSql = "select distinct ClefPersonne from MaRequête where " & MonFiltreVariable
 
On Error Resume Next
DoCmd.DeleteObject acQuery, "MaRequête"
 
Set qry = CurrentDb.CreateQueryDef("MaRequête", leSql)
 
Effectif = DCount("ClefPersonne","MaRequête")
 
...

CDlt,

[Invité]

Bonne idée User, mais Dcount attend un nom de table ou de requête

La même mais en passant par DAO :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Public Function DistinctCount(ByVal Expr As String, ByVal Domain As String, Optional ByVal Criteria As String) As Long
'v1.01 : COUNT(*) -> COUNT(Expr) pour ne pas compter les éventuelles valeurs NULL sauf si Expr = *
Dim oDb As DAO.Database, oRs As DAO.Recordset, sql As String
On Error GoTo Catch
sql = "SELECT COUNT(" & Expr & ") As C FROM (SELECT DISTINCT " & Expr & " FROM " & Domain
If Trim$(Criteria) = vbNullString Then
    sql = sql & ") As R"
Else
    sql = sql & " WHERE " & Criteria & ") As R"
End If
Set oDb = CurrentDb
Set oRs = oDb.OpenRecordset(sql, dbOpenSnapshot)
If Not oRs.EOF Then DistinctCount = oRs.Fields(0)
oRs.Close
fin:
Set oRs = Nothing
Set oDb = Nothing
Exit Function
Catch:
    MsgBox "Erreur n°" & err.Number & vbCrLf & "Description: " & err.Description, vbExclamation, "DistinctCount()"
    Resume fin
End Function

[User]

Bonne idée User, mais Dcount attend un nom de table ou de requête

La même mais en passant par DAO :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Public Function DistinctCount(ByVal Expr As String, ByVal Domain As String, Optional ByVal Criteria As String) As Long
Dim oDb As DAO.Database, oRs As DAO.Recordset, sql As String
On Error GoTo Catch
sql = "SELECT COUNT(*) As C FROM (SELECT DISTINCT " & Expr & " FROM " & Domain
If Trim$(Criteria) = "" Then
    sql = sql & ") As R"
Else
    sql = sql & " WHERE " & Criteria & ") As R"
End If
Set oDb = CurrentDb
Set oRs = oDb.OpenRecordset(sql, dbOpenSnapshot)
If Not oRs.EOF Then DistinctCount = oRs.Fields(0)
oRs.Close
fin:
Set oRs = Nothing
Set oDb = Nothing
Exit Function
Catch:
    MsgBox "Erreur n°" & err.Number & vbCrLf & "Description: " & err.Description, vbExclamation, "DistinctCount()"
    Resume fin
End Function

Oui merci j'avais corrigé et ne m'étais pas relu

[Invité]

Ca me rassure, même les meilleurs ont parfois un oubli !

[marot_r]

Merci de vos réponse.

Je vais étudier cela demain matin.

A+

[User]

Ca me rassure, même les meilleurs ont parfois un oubli !

Merci c'est sympa, mais vous êtes aussi bien actif sur le forum et c'est utile pour les intervenants, donc merci pour eux

[marot_r]

Merci Galoir c'est exactement ce dont j'avais besoin.

A+