Discussion :

[riaolle]

Bonjour,

Dans un UserForm, j'ai une Listbox que j'aimerais alimenter à partir d'une plage de cellules filtrées. Je procède ainsi : je filtre ma plage de cellule, puis j'alimente ma Listbox, grâce à la propriété List et à la propriété SpecialCells(xlCellTypeVisible) pour la plage de cellule.
Seulement, ma ListBox ne prend pas en compte toutes les cellules visibles. Elle prend en compte seulement les premières cellules (jusqu'à la première cellule non visible exclue). Par exemple avec les valeurs suivantes:
FAUX
FAUX
VRAI
FAUX
Si je filtre sur FAUX, la ListBox ne m'affichera que les 2 premières lignes.
Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub okButton_Click()
'**** GET THE OPEN WORK ASSOCIATED TO CATEGORY FROM COMBOBOX ****
    Dim filterNum As Integer
    Dim row_n As Long
    'conditions pour obtenir filterNum --> pas intéressant pour la question
 
    With Sheets("Selection table")
        row_n = .Cells(Rows.Count, 1).End(xlUp).Row
        If filterNum <> 0 Then
            .Range("$A$1:$J$" & row_n).AutoFilter Field:=filterNum, Criteria1:=Sheets("Database").Range("CH1").Text    'filtre sur un tableau (ça marche comme il faut)
        End If
        Me.declaListBox.List = .Range("A2:F" & row_n).SpecialCells(xlCellTypeVisible).Value    'je veux récupérer dans la Listbox seulement les cellules visibles après le filtre.
        If filterNum <> 0 Then .Range("$A$1:$J$" & row_n).AutoFilter Field:=filterNum      
    End With
End Sub

Pour faire des tests, j'ai fait un copié-collé de la plage de cellules visibles et j'ai bien toutes les lignes visibles qui sont collées. Donc, a priori, c'est bien au niveau de la ListBox qu'il y a un problème.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub okButton_Click()
'**** GET THE OPEN WORK ASSOCIATED TO CATEGORY FROM COMBOBOX ****
    Dim filterNum As Integer
    Dim row_n As Long
    'conditions pour obtenir filterNum --> pas intéressant pour la question
    
    With Sheets("Selection table")
        row_n = .Cells(Rows.Count, 1).End(xlUp).Row
        If filterNum <> 0 Then
            .Range("$A$1:$J$" & row_n).AutoFilter Field:=filterNum, Criteria1:=Sheets("Database").Range("CH1").Text    'filtre sur un tableau (ça marche comme il faut)
        End If
        .Range("A2:F" & row_n).SpecialCells(xlCellTypeVisible).Copy destination:=.Range("A10")
        Me.declaListBox.List = .Range("A2:F" & row_n).SpecialCells(xlCellTypeVisible).Value    'je veux récupérer dans la Listbox seulement les cellules visibles après le filtre.
        If filterNum <> 0 Then .Range("$A$1:$J$" & row_n).AutoFilter Field:=filterNum      
    End With
End Sub

Voyez-vous le problème?
Merci beaucoup pour votre aide

[Invité]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.ListBox1.RowSource = Range("Feuil1!$A$1:$C$17").SpecialCells(xlCellTypeVisible).Address

[unparia]

Bonjour Robert
La propriété Rowsource ne sait à ma connaissance gérer qu'une plage de cellules contigües.

[Invité]

Bonjour unpari,
Je vérifie

[Philippe Tulliez]

Bonjour Robert, Unparia,

La propriété Rowsource ne sait à ma connaissance gérer qu'une plage de cellules contigües

Je confirme

[boisgontierjacques]

Bonsoir,

Zone filtrée dans ListBox

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Private Sub UserForm_Initialize()
  Sheets.Add
  Sheets("BD").Range("_FilterDataBase").Offset(1).SpecialCells(xlCellTypeVisible).Copy [A1]
  Me.ListBox1.List = [A1].CurrentRegion.Value
  Application.DisplayAlerts = False
  ActiveSheet.Delete
  For i = 1 To 3
    Me("label" & i) = Sheets("bd").Cells(1, i)
  Next i
End Sub

Sans feuille intermédiaire (Colonnes 1 et 2)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Private Sub UserForm_Initialize()
  Dim Liste(): ReDim Liste(1 To [_FilterDataBase].Offset(1).Resize(, 1).SpecialCells(xlCellTypeVisible).Count, 1 To 2)
  For Each c In [_FilterDataBase].Offset(1).Resize(, 1).SpecialCells(xlCellTypeVisible)
    i = i + 1:    Liste(i, 1) = c: Liste(i, 2) = c.Offset(, 1)
  Next c
  Me.ComboBox1.List = Liste
End Sub

Boisgontier
http://boisgontierjacques.free.fr

[riaolle]

Merci, c'est parfait !
J'ai utilisé la première méthode que je comprends mieux.
Y a-t-il des avantages et des inconvénients à utiliser une méthode plutôt que l'autre?
Si j'ai bien compris, la propriété List ne peut prendre qu'une plage de cellules contigues et c'est pourquoi j'avais mon problème?

Merci à tous pour votre participation!

[unparia]

Si j'ai bien compris, la propriété List ne peut prendre qu'une plage de cellules contigues et c'est pourquoi j'avais mon problème?

De manière plus générale :
on ne peut affecter directement les plages de cellules non contigües ni à une propriété Rowsource, ni à une matrice (pour les mêmes raisons, d'ailleurs).

Or, tu précisais que tu avais des lignes non visibles intercalées.