Discussion :

[Rotax27]

Bonjour à tous,
Je voudrais selectionner des cellules non contiguës dans une même ligne définie par une variable.

Exemple :
J'utilise la fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
selig = Selection.row
Range(cells(selig,5)).select

Je voudrais selectionner dans la même ligne (selig) les cellules de la colonne A,E,F,G,H,I,M,N par exemple.
Je voudrais écrire ce code sur une seule ligne: comment écrire ce code ?

Merci !

[joe.levrai]

Bonjour,

en les unissant une par une

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub toto()
Dim Colonne(), Ligne As Long, Plage As Range
Colonne = Array("A", "E", "B")
Ligne = 3
    For Each c In Colonne
        If Not Plage Is Nothing Then
            Set Plage = Application.Union(Plage, Range(c & Ligne)) ' rattacher une feuille au Range()
        Else
            Set Plage = Range(c & Ligne) ' rattacher une feuille au Range()
        End If
    Next c
Plage.Select
End Sub

[Rotax27]

Cela me parait bien compliqué, je pensais aussi à
Range(cells(selig,1,5-9)).select mais la syntaxe est incorecte
ou
Range("A1;E1").select mais cela ne marche pas comme je voudrais

[joe.levrai]

il n'y a rien de compliqué, c'est le strict minimum si tu veux que ta procédure soit dynamique et facile à maintenir, puisque tout se passe dans tes deux variables Colonne et Ligne

mais si c'est pas ton objectif, avec uniquement la ligne 7 de ma proposition, tu peux écrire une looooongue ligne de code qui remplace tout le reste et qui inclus tout tes Range(Colonne & Ligne) dans le Application.Union (attention aux limites, regarde bien l'aide ), une méthode pour unir des plages qui est impérative.


tu peux même en faire une fonction de base, tu lui passes les colonnes et la ligne où faire l'union, très facile à utiliser

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub toto()
Dim MaPlage As Range
Set MaPlage = Unis(Array("A", "E", "B"), 3)
    MaPlage.Select
End Sub
 
Function Unis(Colonne As Variant, Ligne As Long) As Range
Dim Plage As Range
    For Each c In Colonne
        If Not Plage Is Nothing Then
            Set Plage = Application.Union(Plage, Range(c & Ligne))
        Else
            Set Plage = Range(c & Ligne)
        End If
    Next c
Set Unis = Plage
End Function

[eriiic]

Bonjour,

en une ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set pl = Intersect(Selection.EntireRow, [A:A, E:I, M:N])

eric

[Rotax27]

Bonjour Eriic et merci pour ta réponse.
Vu les réponses que vous me faites, çà ne répond pas à mes attentes, ou,j'ai du mal présenter mon problème.

J'ai une liste d'adhérents dans un classeur classée par ordre alpha, avec sur la même ligne, le nom, prénom,adresse, code postal ,tel, catégorie, fonction, @mail, etc ...
Je voudrais extraire un certain nombre de données concernant 1 adhèrent (donc sur la même ligne).
Je sélectionne la cellule contenant le nom et en appuyant sur un bouton j'exécute une macro qui va extraire certaines données (pas toutes)de cet adhèrent.
Copier ces données et les coller dans une autre feuille de calcul toujours sur une même ligne et sans "blancs".
Début de la macro:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Selig=Selection.Row

(me donne le n° ligne de la cellule sélectionnée)
Si je lance un apprentissage de la macro çà donne çà:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("A66,D66:I66,P66,S66:T66,W66").Select

(selection manuelle des données à extraire de la ligne 66))
Je voudrais écrire cette fonction en lui incluant la variable "selig" pour le n° de ligne.
J'ai essayer avec:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range(cells(selig,1),cells(selig,5),cells(selig,6))

mais suis très vite limité par le nombre d'élément et je ne sais comment m'y prendre pour inclure des éléments qui se suivent et/ou qui ne se suivent pas. la commande doit être envoyée en une seule fois pour avoir une sélection simultanée de ces cellules.
En fin de compte je cherche la syntaxe de cette commande.
Merci

[eriiic]

Si c'est pour copier pas besoin de les sélectionner.
Et si c'est pour les coller sans blanc il faut le faire par bloc de cellules contiguës :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Intersect(Selection.EntireRow, [A:C]).Copy Sheets("Feuil2").[A2]

eric

[unparia]

Bonjour (et un salut à eriic)

Si tu avais compris le code que t'as montré eriic, tu l'aurais immédiatement adapté, ainsi, par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set pl = Intersect(Rows(sellig), Range("A:A, E:I, M:N"))

[riaolle]

Bonjour,
est-ce que ce sont toujours les mêmes colonnes qui doivent être copiées?
Alors, si on copie de la feuil1 ver la feuil2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim i As Long
    Dim n As Long
    i = ActiveCell.Row     'ligne à copier
    n = Sheets("feuil2").Cells(Rows.Count, 1).End(xlUp).Row + 1  'première ligne vide de feuil2
    With Sheets("feuil1")
        Sheets("feuil2").Range("A" & n).Value = .Range("A" & i).Value     'copie de feuil1 ver feuil2
        Sheets("feuil2").Range("B" & n).Value = .Range("D" & i).Value
    End With

Cette ligne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("feuil2").Range("B" & n).Value = .Range("D" & i).Value

doit être adaptée avec les bonnes colonnes. Il faut une ligne de code par colonne à recopier.

[Rotax27]

Merci à tous,
Vous avez raison je n'ai pas tout compris mais la réponse de Unparia me convient parfaitement et fonctionne très bien

Cela à parfaitement fonctionner au premier essai,
Sauf que pour les essais suivants seule la première cellule est prise en compte, est copiée vers l'autre feuille.

[eriiic]

https://www.developpez.net/forums/d1...e/#post9126741

[Rotax27]

https://www.developpez.net/forums/d1...e/#post9126741

J'ai recopié en adaptant comme il est expliqué le code de Riaolle et çà marche très très bien.
Je commence à en comprendre l'architecture.

Merci à vous tous
Cordialement