Discussion :

[Louax]

Bonjour,

Par ces lignes je colorise les lignes et les colonnes selon la position de mon curseur:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Me.Names("Septembre").RefersTo = "=" & Target.Address(external:=True)
End Sub

et dans la feuille j'utilise la mise en forme conditionnelle avec les règles suivante :

Formule =colonne()=colonne(Septembre) s'applique à =$D$1:$AH$40
Formule =ligne()=ligne(Septembre) s'applique à =$B$15:$AH$57

Cela fonctionne très bien mais voilà j'aimerai que seul les cellule partant du haut de la colonne et du début de la ligne se colorisent et s'arrêtent à la cellule sélectionnée.
Exemple pour la cellule Y31 que les cellule de la ligne 31 se colorise de B à Y et les cellule de la colonne Y se colorise de 1 à 31

Je ne dois pas être loin... mais j'ai vraiment besoin de votre aide.

Merci

[joe.levrai]

Bonjour,

si le VBA est réellement nécessaire et que la MFC ne suffit pas, peut être qu'une solution pure VBA pourrait convenir ?

voici un début, à coller dans un module de feuille, et paramétrable.

j'ai pas énormément testé, et on peut facilement ajouter d'autres paramètres (jouer sur les lignes, gérer la sélection d'une place de plusieurs cellules etc..)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Public Cell_Precedent As Range
 
Private Sub Worksheet_Activate()
' à l'activation de la feuille, la précédente cellule est créee sur la cellule active
Set Cell_Precedent = ActiveCell
End Sub
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Const LIMITE_COL As Integer = 1 ' on exclut les X premières colonnes
Const COULEUR As Long = 16305600 ' on va colorier de cette couleur
' si on est dans une colonne exclue on s'arrête
If Target.Column <= LIMITE_COL Then Exit Sub
 
 
On Error Resume Next
' on tente d'effacer la précédente sélection
Union(Cells(1, Cell_Precedent.Column).Resize(Cell_Precedent.Row, 1), _
      Cells(Cell_Precedent.Row, 2).Resize(1, Cell_Precedent.Column - LIMITE_COL)).Interior.Pattern = xlNone
On Error GoTo 0
 
' on déclarer la sélection active en tant qu'ancienne sélection
Set Cell_Precedent = Target
 
' on colorie l'ancienne sélection
Union(Cells(1, Cell_Precedent.Column).Resize(Cell_Precedent.Row, 1), _
      Cells(Cell_Precedent.Row, 2).Resize(1, Cell_Precedent.Column - LIMITE_COL)).Interior.Color = COULEUR
 
End Sub

[Louax]

Merci

Je ne connaissait pas cette méthode, je vais l'appliquer sur mon programme

Encore merci