Discussion :

[joreveur]

Bonjour
sur un petit exemple quand j'essaie d'échanger la valeur de 2 memo en passant par une chaine je n'ai pas de soucis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
procedure TForm1.Button1Click(Sender: TObject);
var swap:string;
begin
swap:=memo1.Text;
memo1.text:=memo2.Text;
memo2.Text:=swap;
end;

quand j'essaie caractère par caractère ça ne fonctionne pas sur les caractère accentués. ils sont supprimés ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
procedure TForm1.Button2Click(Sender: TObject);
var i:integer;
    swap1,swap2:string;
 
begin
  swap1:=memo1.Text;
  swap2:=memo2.Text;
  memo1.clear;
  for i:=1 to length(swap2) do
      memo1.text:=memo1.text+swap2[i];
  memo2.clear;
  for i:=1 to length(swap1) do
      memo2.text:=memo2.text+swap1[i];
end;

or justement j'ai besoin de cette deuxième méthode.

Une idée ?

voila tout le code de mon exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
unit Unit1;
 
{$mode objfpc}{$H+}
 
interface
 
uses
  Classes, SysUtils, FileUtil, Forms, Controls, Graphics, Dialogs, StdCtrls;
 
type
 
  { TForm1 }
 
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Memo1: TMemo;
    Memo2: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { private declarations }
  public
    { public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.lfm}
 
{ TForm1 }
 
procedure TForm1.Button1Click(Sender: TObject);
var swap:string;
begin
swap:=memo1.Text;
memo1.text:=memo2.Text;
memo2.Text:=swap;
end;
 
procedure TForm1.Button2Click(Sender: TObject);
var i:integer;
    swap1,swap2:string;
 
begin
  swap1:=memo1.Text;
  swap2:=memo2.Text;
  memo1.clear;
  for i:=1 to length(swap2) do
      memo1.text:=memo1.text+swap2[i];
  memo2.clear;
  for i:=1 to length(swap1) do
      memo2.text:=memo2.text+swap1[i];
 
 
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  memo1.text:='ce sera bientôt l''été';
  memo2.text:='le printemps à Pâques';
end;
 
end.

merci de vos conseils et bonne journée

[Jipété]

Yop !

quand j'essaie caractère par caractère ça ne fonctionne pas sur les caractère accentués. ils sont supprimés ...

Le problème des caractères multi-bytes, le retour

Essaye de faire l'échange en utilisant des bytes (mais je ne vois pas comment "attribuer" les bytes à la propriété "text" des mémos...)

[Roland Chastain]

Bonjour ! Chez moi (Lazarus 1.4.4, Windows), la solution suivante fonctionne. Mais il y a peut-être mieux.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
uses
  LazUTF8;
 
procedure TForm1.Button3Click(Sender: TObject);
var
  i: integer;
  swap1, swap2: UTF8String;
begin
  swap1 := Memo1.Text;
  swap2 := Memo2.Text;
 
  Memo1.Lines.BeginUpdate;
  Memo1.Clear;
  for i := 1 to UTF8Length(swap2) do
    Memo1.Text := Memo1.Text + UTF8Copy(swap2, i, 1);
  Memo1.Lines.EndUpdate;
 
  Memo2.Lines.BeginUpdate;
  Memo2.Clear;
  for i := 1 to UTF8Length(swap1) do
    Memo2.Text := Memo2.Text + UTF8Copy(swap1, i, 1);
  Memo2.Lines.EndUpdate;
end;

L'appel des méthodes BeginUpdate et EndUpdate n'est pas absolument nécessaire, mais permet d'améliorer l'affichage et aussi la vitesse de l'opération.

[ThWilliam]

Bonsoir,

En utilisant un stream, je n'ai aucun problème (Lazarus 1.4.4 sous Win7)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
procedure TForm1.Button1Click(Sender: TObject);
var
  MS: TMemoryStream;
begin
   MS:= TMemoryStream.Create;
   try
      Memo1.Lines.SaveToStream(MS);
      Memo1.Text:= Memo2.Text;
      MS.Position:= 0; // se remettre au début du stream
      Memo2.Lines.LoadFromStream(MS);
   finally
      MS.Free;
   end;
end;

Cordialement
Thierry

EDIT : Oups, je viens de me rendre compte que le vrai problème est le passage par caractères ! Désolé.

[gvasseur58]

Bonjour ! Chez moi (Lazarus 1.4.4, Windows), la solution suivante fonctionne. Mais il y a peut-être mieux.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
uses
  LazUTF8;

Bonsoir,

C'est effectivement la piste pour la solution du problème. Dans un futur proche, Lazarus aura terminé sa mue vers l'internationalisation (UTF8 essentiellement) comme Delphi l'a fait il y a plusieurs années.
Il faut par conséquent oublier le traitement comme on le pratiquait avec les caractères ASCII

[DomDA91]

On peut "composer" une chaîne UTF8 octet par octet mais il ne faut pas le faire directement dans une propriété chaîne d'un composant.

En effet, le Writer d'une propriété chaîne UTF8 d'un composant LCL peut effectuer un contrôle de validité de la chaîne pour éliminer les séquences illégales, ce qui ne manquera pas d'arriver si des caractères multi-octets sont écrits octet par octet.

Par exemple ceci ne marche pas car Edit2.Text se voie affecter successivement tous les états intermédiaires de la chaîne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Edit2.Clear;
For I := 1 To Length(Edit1.Text) Do Begin
  Edit2.Text := Edit2.Text + Edit1.Text[I];
end;

A la place il faut travailler sur une variable chaîne ordinaire qui ne fait pas ce contrôle et ceci fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
var S : String;
...
S := '';
For I := 1 To Length(Edit1.Text) Do Begin
  S := S + Edit1.Text[I];
end;
Edit2.Text := s;

Testé avec Lazarus 1.4.4 ET 1.6RC1.

[gvasseur58]

On peut "composer" une chaîne UTF8 octet par octet mais il ne faut pas le faire directement dans une propriété chaîne d'un composant.

A la place il faut travailler sur une variable chaîne ordinaire qui ne fait pas ce contrôle et ceci fonctionne...

Testé avec Lazarus 1.4.4 ET 1.6RC1.

Très juste Cependant, j'aurais tendance à déconseiller cette pratique, car il me semble qu'il vaut mieux éviter de fonder son travail sur une implémentation obsolète d'encodage des caractères. Lazarus va vers UTF8 (ou, pour le moins vers Unicode) et il est fort à parier que l'on pourra (prochainement ?) traiter les caractères de manière transparente sans s'occuper de savoir s'il s'agit d'1, 2 ou d'un nombre variable d'octets pour les représenter. Plus simplement, il vaut mieux travailler sur des caractères sans préjuger de leur implémentation.