Discussion :

[art_bras_cames]

Bonjour,
en pièce jointe, je mets un fichier excel dans lequel j'aimerais que les chiffres affichés en rouge soient calculés automatiquement lorsque l'on rempli le tableau de gauche.
Merci à tous pour votre aide
NDD

[Menhir]

en pièce jointe, je mets un fichier excel

http://www.developpez.net/forums/d84...s-discussions/

Fais l'effort d'expliquer clairement ton problème.

[art_bras_cames]

J'ai un tableau qui a
en entête de colonne des chiffres de 1 a 31 représentant les dates d'un mois.
et pour les lignes des noms de personne.
dans les cases à l'intersection des abscisses et ordonnées, je mets une croix.

En bout de ligne je souhaiterais qu'apparaisse un récapitulatif par agent.
ex :
pour NDD il y a une croix dans 3, 4, 5 puis dans 22, 23 j'aimerais voir à droite de la ligne : du 3 au 5, du 22 au 23
pour ESN il y a une croix dans 1 puis dans 16, 17,18,19,20 j'aimerais voir à droite de la ligne : du 1 au 1, du 16 au 20
pour CSN il y a une croix dans 10,11,12 j'aimerais voir à droite de la ligne : du 10 au 12

J'avais pensé faire des colonnes du et une colonne au

J'espère que ces explications vous suffiront pour résoudre mon énigme.
A+

[parmi]

Bonjour,

Je ne pense pas que tu puisses y arriver sans macro.
Cette macro pourrait être activée sur l'événement Change de la plage et modifier seulement la ligne où a été apportée cette modification (Target.row)

[papouclo]

Bonjour,
On peut penser à des solutions basées sur l'emploi du VBA.
Voici une proposition sans code.
Se placer en AI3 (ou sur une autre cellule de la ligne 3) et définir les quatre noms suivants (ou autres selon inspiration bien sûr) :

• du par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=(Feuil1!$B3:$AF3="X")*(Feuil1!$A3:$AE3<>"X")*Feuil1!$B$2:$AF$2

• au par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=(Feuil1!$B3:$AF3="X")*(Feuil1!$C3:$AG3<>"X")*Feuil1!$B$2:$AF$2

• rangabsence par:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ENT(COLONNES(Feuil1!$AI3:AI3)/3)+1

• choixduau par:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOD(COLONNES(Feuil1!$AI3:AI$3);3)

Ecrire ensuite en AI3 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(PETITE.VALEUR(CHOISIR(choixduau;du;au);rangabsence+SOMMEPROD(1*(CHOISIR(choixduau;du;au)=0)));"")

et recopier cette formule dans toutes les cellules de la plage AI3:AV8.

Cordialement
Claude

[art_bras_cames]

Merci Claude pour ton aide précieuse.
Cela fonctionne exactement comme je le souhaite dans le tableau, je vais maintenant étudier de plus près les formules
A+ les amis

[Menhir]

Une solution purement fonctions Excel mais qui demande quelques modifications en raison des particularités de RECHERCHEH qui ne peut pas avoir un vecteur résultat avant le vecteur de recherche et qui ne sait pas trouver de plage vide.

Tu copie tes cases A2:AF2 en ligne 9.

Ru remplaces tes cases vides de la zone B3:AF8 par des "-".
Ca peut de faire en quelques secondes avec la commande Remplacer tout.

Tu mets en AI3 la formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=RECHERCHEH("X";$B3:$AF$9;1+LIGNE($A$9)-LIGNE(AI3);FAUX)

Tu mets en AJ3 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(RECHERCHEH("-";DECALER($B3:$AF$9;0;AI3;;1+COLONNE($AF3)-AI3);1+LIGNE($A$9)-LIGNE(AJ3);FAUX)-1;"")

Tu mets en AL3 la formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(RECHERCHEH("X";DECALER($B3:$AF$9;0;AJ3+1;;COLONNE($AF3)-AJ3);1+LIGNE($A$9)-LIGNE(AL3);FAUX);"")

Tu copies AJ3 dans AM3, AP3, AS3 et AV3
Tu copies AL3 dans AO3, AR3 et AU3

Tu copies AI3:AV3 dans les lignes 4 à 8.