Discussion :

[marcobosio]

Bonjour,

et tout d'abord merci d'avance pour toutes les suggestions que vous pourriez m'apporter. Dans le cadre de mon travail, je suis amené à retraiter des résultats issus d'un questionnaire administré à environ 600 personnes.
Les réponses sont stockées dans une base Access.

Mon besoin :
A partir de la table stockant toutes les réponses, je voudrais créer n tables (à exporter ensuite sous Excel), chaque table contenant les enregistrements correspondant à un critère d'un champs spécifique.

Ex.
- Un champs de la table indique la Direction (ex. Finance, Marketing, Logistique, etc.)
- Je voudrais créer une table contenant tous les enregistrement correspondant au critère 'Direction=Finance', une autre table pour les enregistrements correspondant à 'Direction=Marketing', etc., soit n tables s'il y a n valeurs dans le champs Direction (dans mon cas, n=97 Directions)

Je sais le faire avec la requête création de table, mais en créant une table à la fois... et comme le nombre de Directions correspond à 97, j'aimerais pouvoir automatiser ce processus (ainsi que l'export sous Excel de chaque table).


Si vous avez des idées, n'hésitez pas !!

D'avance merci

[pc75]

Bonjour,

Une idée ?

- select distinct direction from matable => dans un recordset
- do while not MonRecordset.EOF
select * into MonRecordset("direction") from matable where direction = MonRecordset("direction")
MonRecordset.movenext
Loop

[marcobosio]

Merci !

Néanmoins, je ne suis pas un pro de SQL ... est-ce que vous pourriez expliciter un peu ? ;-)

[marcobosio]

... je viens de regarder dans l'aide d'Access et je me dis que ce sont sûrement des commandes à créer dans un module.

Est-ce bien le cas ?

Si vous pouviez m'en dire un peu plus ce serait super sympa ! ;-))

[Arkham46]

slt,

Créer 97 tables n'est certainement pas utile.
Utilse plutôt une requête.

Ce que je ferais :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
- Création d'une requête vide, nommée RExport
- On ne mets rien dans cette requête, elle sera modifiée par le code
- En VBA :
      - On lit les différentes Directions 
      - Pour chaque direction :
              - On modifie la requête Rexport
              - Et on exporte la requête avec l'instruction TransferSpreadsheet

Le code avec en gras ce qui doit être adapté à ton cas :
- TReponses : la table qui contient les réponses
- Direction : le nom du champ de la table TReponses qui contient la direction
- RExport : la requête pour l'export

Ca devrait exporter les données de chaque direction dans un fichier sur le C:

Ne pas oublier de cocher Microsoft DAO dans Outils --> Références

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

Public Sub ExportDirections()
On Error GoTo Gestion_Erreurs
    Dim rs As DAO.Recordset
    Dim db As DAO.Database
    Dim qd As DAO.QueryDef
    ' Base de données courante
    Set db = CurrentDb
    ' Requête d'export
    Set qd = db.QueryDefs("RExport")
    ' Sélection dans rs des différentes Directions
    Set rs = db.OpenRecordset("select distinct Direction from TReponses")
    ' Positionnement sur le premier enregistrement
    rs.MoveFirst
    ' Boucle pour traiter chaque Direction
    While Not rs.EOF
        ' Modifie le SQL de la requête en fonction de la Direction
        qd.SQL = "select * from TReponses where Direction = '" & rs!Direction & "'"
        ' Export les données pour une Direction dans un fichier Excel
        DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, _
                                               "RExport", "c:\Direction_" & rs!Direction & ".xls"
        ' Passe à l'enregistrement suivant
        rs.MoveNext
    Wend
    ' Ferme et libère les objets
    rs.Close
    Set rs = Nothing
    Set qd = Nothing
    Set db = Nothing
Gestion_Erreurs:
    If Err.Number <> 0 Then MsgBox Err.Number & ":" & Err.Description
End Sub

bye

[marcobosio]

Bonjour Arkham,

et un grand merci pour ta réponse !!! Ca fonctionne très bien et ça répond parfaitement à mon besoin...

merci merci merci !! :-)


Bon dimanche

Marco