Discussion :

[pessoantoi]

Bonjour,

J'ai un problème assez spécifique, je vais essayer de m'expliquer le plus clairement possible.

Tout d'abord la structure de mes classeurs.
J'ai deux classeurs : toto.xlsm et tata.xlsm
Dans tata.xlsm, dans la feuille "feuille1", deux colonnes A et B :
..........A..............B
1...xxxTITIxxx.......5
2...xxxxxxxxxx.......7
3...xTITIxxxxx.......6
4...xxxTITIxxx.......1
5...xxxxxxxxxx.......2
6...xxxxxxTITI.......5

Dans toto.xlsm, je veux obtenir la somme des valeurs de B qui ont "TITI" dans A.
Par exemple ici je veux trouver 5+6+1+5=17.

Voici la formule que j'applique dans toto.xlsm, et qui ne fonctionne pas... :

=SOMME.SI('\\dossier1\dossier2\[tata.xlsm]feuille1'!A1:A6;"*TITI*";'\\dossier1\dossier2\[tata.xlsm]feuille1'!B1:B6)

J'ai fais quelques tests, et toutes les choses suivantes fonctionnent :
dans toto.xlsm :
=SOMME('\\dossier1\dossier2\[tata.xlsm]feuille1'!B1:B6) renvoie bien 5+7+6+1+2+5=26, donc la référénce externe fonctionne avec une simple somme.
dans tata.xlsm :
=SOMME.SI(A1:A6;"*TITI*";B1:B6) renvoie bien 5+6+1+5=17, donc la somme conditionnelle fonctionne seule.

C'est lorsque je combine les deux que cela ne marche plus, cela me retourne #VALEUR!, avec le message "le type de données d'une valeur utilisée dans la formule est incorrect".

Cela fait une journée de boulot que je sèche là dessus, je ne vois pas mon erreur !

Merci d'avance à ceux qui auraient une idée...

Cordialement,

Antoine.


PS :
j'ai utilisé des alias pour simplifier l'explication, mais voici ma véritable formule (au cas où vous découvriez une erreur de syntaxe...) :
=SOMME.SI('\\sfs.corp\Projects\A350\PDT_POWERPLANT\A25_EARNED_VALUE_MANAGEMENT\EVM REPORTS\KV 1000 LAST EVM REPORT\[EVM REPORT_ALL.xlsm]RD-FORECAST (2)'!E11:E411;"*PYLON*";'\\sfs.corp\Projects\A350\PDT_POWERPLANT\A25_EARNED_VALUE_MANAGEMENT\EVM REPORTS\KV 1000 LAST EVM REPORT\[EVM REPORT_ALL.xlsm]RD-FORECAST (2)'!W11:W411)

[Philippe Tulliez]

Bonjour,
Si ma mémoire est bonne la formule SOMME.SI ne fonctionne pas si le classeur en référence est fermé.
En effet lorsque dans une cellule ont fait référence à la cellule ou à une plage de cellules d'un autre classeur certaines formules ne fonctionnent pas si le classeur de référence est fermé.
Les formules NB.VIDE, NB.SI et DECALER entre autres ne fonctionnent pas non plus

[pessoantoi]

Merci de ta réponse, même si elle ne m'arrange pas
Y a-t-il un autre moyen pour parvenir à mes fins, sans passer par des cellules intermédiaires dans l'un ou l'autre de mes fichiers ? Car ce sont des fichiers assez sensibles dans lesquels j'aimerais éviter de rajouter des cellules inutiles...

[Philippe Tulliez]

Bonjour,
Tu peux passer par la formule SOMMEPROD qui fonctionne avec les classeur fermés et qui peut te renvoyer le même résultat que SOMME.SI.

[pessoantoi]

Merci beaucoup, ça fonctionne !

Pour info :

=SOMMEPROD((ESTNUM(CHERCHE("PYLON";'\\sfs.corp\Projects\A350\PDT_POWERPLANT\A25_EARNED_VALUE_MANAGEMENT\EVM REPORTS\KV 1000 LAST EVM REPORT\[EVM REPORT_ALL.xlsm]RD-FORECAST (2)'!E11:E411)))*('\\sfs.corp\Projects\A350\PDT_POWERPLANT\A25_EARNED_VALUE_MANAGEMENT\EVM REPORTS\KV 1000 LAST EVM REPORT\[EVM REPORT_ALL.xlsm]RD-FORECAST (2)'!W11:W411))