Discussion :

[reinruof77]

Bonjour a tous et toutes

en ce début de soirée je continu a cherchez une solution a mon problème et je compte sur votre aide.

voila je cherche le moyen de récupérer les donné des cellules et de les envoyer dans l'userform de modification.

la base de recherche ce fait sur la cellules E2 mais sur toutes les feuilles

j'espere que vous pourrez m'aider

MERCI de votre aide

[Theze]

Bonsoir,

Une piste. Comme le nombre de feuilles est inconnu, j'utilise ici un module de classe. Code à mettre dans un module de classe nommé "Classe1" afin de reporter dans la cellule correspondante la valeur modifiée dans le TextBox qui a le Focus :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Public WithEvents GroupeTxt As MSForms.TextBox
 
Private Sub GroupeTxt_Change()
 
    Worksheets(GroupeTxt.Name).Range("E2").Value = GroupeTxt.Text
 
End Sub

Code à mettre dans le module de la Form :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
Dim Txt() As New Classe1
 
Private Sub UserForm_Initialize()
 
    Dim Fe As Worksheet
    Dim Ctrl As MSForms.TextBox
    Dim I As Integer
    Dim Haut As Long
 
    'position de départ du premier TextBox
    Haut = 5
 
    'parcour les feuilles
    For Each Fe In Worksheets
 
        'crée le TextBox correspondant avec le nom de la feuille
        I = I + 1
        Set Ctrl = Me.Controls.Add("Forms.Textbox.1", Fe.Name, True)
 
        'dimensionne et positionne le TextBox
        With Ctrl
 
            .Left = 10
            .Top = Haut
            .Width = Me.Width - 20
            .Height = 20
            .Text = Fe.Range("E2").Value '<--lui affecte la valeur de la cellule de la feuille
 
        End With
 
        'incrémente
        Haut = Haut + 20
 
        'si la Form est trop petite, augmente sa hauteur
        If Haut + 30 > Me.Height Then Me.Height = Haut + 30
 
        'stocke le TextBox dans le tableau
        ReDim Preserve Txt(1 To I)
        Set Txt(I).GroupeTxt = Ctrl
 
    Next Fe
 
End Sub

Pour tester, tu ajoute à ton projet une Form et un module de classe (nommé Classe1") tu colle le code correspondant à chacun d'eux et puis tu active la Form dans le VBE puis F5 et tu teste en changeant la valeur dans le TextBox de la feuille active pour voir le resultat.

Hervé.

[reinruof77]

Merci Hervé

Je Viens d'essayer et j'ai une erreur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
'stocke le TextBox dans le tableau
        ReDim Preserve Txt(1 To I)
        Set Txt(I).GroupeTxt = Ctrl

Variable non Defini


et je vois pas pourquoi?

Merci

[Theze]

Re,

cette ligne de code doit se trouver en tête du module de la Form (je pense qu'elle est passée à la trappe au copier/coller) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Dim Txt() As New Classe1

Hervé.