Discussion :

[GreatTeacherOnizuka]

Bonsoir,

J'ai deux petites questions concernant les listes object:

Première, si j'écris

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 xl.ListObjects.Add(xlSrcRange, xlSheet.Range("A9:M2000"), , xlNo).Name = "Tableau1"
           xl.ListObjects("Tableau1").TableStyle = "TableStyleLight1"

Cela génère un tableau avec en en-tête: Colonne1, Colonne2, ... est il possible de modifier le nom de ces colonnes?

Deuxième question, si je veux modifier les bordures de ce tableau, j'ai essayé:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

xl.ListObjects("Tableau1").TotalsRowRange.Borders.ColorIndex = 10

Je voudrais savoir pourquoi ça bug en fait?

Merci d'avance.

[Philippe Tulliez]

Bonjour,
1ère question
Utiliser la propriété Name de l'objet ListColumn.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ListObject.Columns(3).Name = "Prix"

ou encore

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ListObject.Columns("Qté").Name = "Quantité"

Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub ListObject()
 Dim rng As Range, oList As ListObject
 Set rng = Feuil1.Range("A1").CurrentRegion
 With rng.Worksheet
  With .ListObjects
  .Add(xlSrcRange, rng, , xlYes).Name = "t_Stock"
  End With
  Set oList = .ListObjects("t_Stock")
 End With
 With oList
 .ListColumns.Add Position:=2 ' Insère une colonne en 2ème position
 .ListColumns(2).Name = "Libellé" ' Renomme la colonne
 .ListColumns("Libellé").Name = "Désignation" ' Renomme la colonne
 End With
End Sub

2ème question

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub ListObjectBorders()
 Dim sht As Worksheet, oList As ListObject
 Set sht = ThisWorkbook.Worksheets("Feuil1")
 Set oList = sht.ListObjects("t_Stock")
 With oList.Range.Borders(xlInsideVertical)
 .LineStyle = xlContinuous
 .Color = vbRed
 .Weight = 3
 End With
End Sub

Utilise l'enregistreur de macros pour découvrir d'autres propriétés et méthodes de l'objet ListObject.

[GreatTeacherOnizuka]

Merci beaucoup, j'ai pu faire tout ce que je voulais avec ça.