Discussion :

[MonSavon]

Bonjour!

J'ai peut être un petit peu trop "le nez dans le guidon" cependant je n'arrive pas à identifier mon erreur !

Voilà, je cherche à importer une feuille particulière d'un fichier vers le miens. Lorsque ma macro s'éxécute aucun problème, mais alors que j'espérais avoir ma copie dans une feuille bien précise, ma macro préfère créer une nouvelle feuille et mettre ses résusltats dedans!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Sub ImportWorksheet()
 
    ' This macro will import a file into this workbook
    Worksheets(1).Select
    PathName = "G:\COMMUN SERVICES\DEV\VALVE\HALF_LIFE_3\"
    Filename = "INFO_TOP_SECRET.xls"
    TabName = "THIS_IS_NO_FAKE"
    ControlFile = "JUSTKIDDING.xls"
 
    Workbooks.Open Filename:=PathName & Filename
    Workbooks(Filename).Worksheets(TabName).Copy Before:=Workbooks(ControlFile).Worksheets(2)
 
    Workbooks(Filename).Close SaveChanges:=False
 
End Sub

Merci !

[Philippe Tulliez]

Bonjour,

j'espérais avoir ma copie dans une feuille bien précise, ma macro préfère créer une nouvelle feuille et mettre ses résusltats dedans!

C'est tout à fait normal dans ta ligne de code (ligne 12), tu fais une copie de feuille et pas de cellules de plus tu indiques dans l'instruction d'insérer la feuille avant la deuxième de l'autre classeur.

[Menhir]

C'est logique puisque tu copies la Worksheet et non son contenu (tu places la méthode Copy sur l'objet Worksheet).

C'est un peu comme si, manuellement, tu faisais glisser un onglet d'un classeur à un autre. Ce n'est pas ça qui te permettrait de copier le contenu de ta feuille source dans un feuille existante.

Il faudrait que tu décrives mieux ce que tu souhaites faire comme copie pour qu'il soit possible de t'orienter vers la bonne procédure mais ça devrait être quelque chose comme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Workbooks(Filename).Worksheets(TabName).cells.copy
Workbooks(ControlFile).Worksheets(2).cells(1,1).PasteSpecial  XlPasteType:=xlPasteAll

Si tu veux conserver les largeurs de colonnes, il faudra passer par Columns plutôt que par Cells.

[MonSavon]

Bonjour, et merci de ton aide!

Et bien je souhaite copier une feuille spécifique X vers une feuille Y de mon classeur.
(Je travaille depuis le classeur Y)
En plus si possible j'aimerais importer une zone assez spécifique de ma feuille X, c'est à dire les colonnes A à M
J'ai bien essayé ton code, mais comme à chaque fois, je rencontre une erreur 1004...

Le code n'a pas évolué de façon significative depuis la dernière fois.

Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Workbooks.Open Filename:=PathName & Filename
Workbooks(Filename).Worksheets(TabName).Range("A:M").Copy
Workbooks(ControlFile).Worksheets(2).Range("A:M").PasteSpecial XlPasteType:=xlPasteAll

ça ne marche pas, mais ne montre aucun signe d'erreur!
Cependant, un petit message annexe m'embête, message concernant la quantité importante d'info dans le Presse Papier.

[Invité]

test ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub ImportWorksheet()
 Dim WsCible As Worksheet
 Dim WbSource As Workbook
    ' This macro will import a file into this workbook
    Set WsCible = Worksheets(1)
    PathName = "G:\COMMUN SERVICES\DEV\VALVE\HALF_LIFE_3\"
    Filename = "INFO_TOP_SECRET.xls"
    TabName = "THIS_IS_NO_FAKE"
    ControlFile = "JUSTKIDDING.xls"
 
    Set WbSource = Workbooks.Open(Filename:=PathName & Filename)
    WbSource.Worksheets(TabName).UsedRange.Copy WsCible.Range("A1")
 
  WbSource .Close SaveChanges:=False
 
End Sub

[Menhir]

Et bien je souhaite copier une feuille spécifique X vers une feuille Y de mon classeur.
(Je travaille depuis le classeur Y)

Là, tu ne fais que répéter ce que tu as écrit dans ton premier message. Heureusement, le code que tu as écris ensuite est plus parlant.

Si j'ai bien compris, tu comptes copier les données se trouvant dans les colonnes A à M de ta feuille TabName du classeur Filename pour le mettre remplacer les colonnes A à M du deuxième onglet du classeur ControlFile en écrasant un contenu éventuel.
C'est bien ça ?

J'ai bien essayé ton code, mais comme à chaque fois, je rencontre une erreur 1004...

Comment l'as-tu inséré ?
C'est sur cette ligne que l'erreur s'est déclenchée ?
Il n'y avait pas un petit bout de texte avec le code d'erreur ?

ça ne marche pas, mais ne montre aucun signe d'erreur!

Ca, on peut dire que c'est précis comme description de problème...

Essaye de remplacer les "Range" de ton code par des "Columns".

[MonSavon]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
 
Sub ImportWorksheet()
 
    ' This macro will import a file into this workbook
    Worksheets(1).Select
    PathName = "L:\...\...\...\"
    Filename = "YY.xls"
    TabName = "xx"
    ControlFile = "Classeur1.xls"
 
    On Error Resume Next
    Open PathName & Filename For Binary Access Read Write Lock Read Write As #1
    Close #1
    If Err.Number <> 0 Then
        Err.Clear
        MsgBox "Fichier " & Filename & "; ouvert, ou utilisé."
        GoTo fichierOuvert
    End If
 
    Workbooks.Open Filename:=PathName & Filename
    Workbooks(Filename).Worksheets(TabName).Range("A:M").Copy
    Workbooks(ControlFile).Worksheets(2).Columns("A:M").PasteSpecial XlPasteType:=xlPasteAll
    Workbooks(Filename).Close SaveChanges:=False
 
fichierOuvert:
End Sub

Avec ce code, il n'y a plus d'erreurs, cependant, rien ne s'affiche sur la feuille de destination...
Généralement l'erreur 1004 avait lieu à la ligne du "PasteSpecial".

[Menhir]

Avec ce code, il n'y a plus d'erreurs,

Introduire un On Error dans le code ne fait que masquer le problème sans le résoudre et empêche d'obtenir les renseignements permettant de le résoudre. Il vaut donc mieux éviter.

Essaye

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
    Workbooks.Open Filename:=PathName & Filename
 
    Workbooks(Filename).Worksheets(TabName).Columns("A:M").Copy
    Workbooks(ControlFile).Worksheets(2).Columns("A:M").PasteSpecial (xlPasteAll)
 
    Workbooks(Filename).Close SaveChanges:=False
 
End Sub

Cela dit, la solution avec un USedRange proposée par rdurupt est plus élégante et plus légère pour la quantité copiée.
Mais elle a le défaut de ne pas limiter la copie à la colonne M (ce qui est sans conséquence si tu n'as rien au dela de cette colonne).

Petit conseil aussi : tu devrais déclarer tes variables avec des Dim, ce serait plus propre.

[MonSavon]

Problème Résolu !

La fonction 'IsFileOpen' provient du F.A.Q.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
Function IsFileOpen(ByVal strFic As String) As Boolean
 
    Dim fic As Integer
 
    On Error Resume Next
 
    fic = FreeFile()
    Open strFic For Input Access Read Lock Read Write As fic
 
    If Err.Number = 0 Then
        IsFileOpen = False
        Close fic
    Else
        IsFileOpen = True
    End If
End Function
 
Sub ImportWorksheet()
 
' This macro will import a file into this workbook
 
' Définition des variables, chemin, et fichier cible
    Dim PathName As String, Filename As String, TabName As String, ControlFile As String
 
    PathName = "L:\...\....\"
    Filename = "UUU.xls"
    TabName = "target"
    ControlFile = ActiveWorkbook.Name
 
' Cas où le fichier est déjà ouvert, ou utilisé, gère l'erreur et continu
    If (IsFileOpen(PathName & Filename) = True) Then GoTo fichierOuvert
 
' Dans le cas où le fichier n'est pas ouvert, transfert de la zone de worksheet désirée
    Workbooks.Open Filename:=PathName & Filename
    ' Utilisation et remplissage du PRESSE-PAPIER
    Workbooks(Filename).Worksheets(TabName).Columns("A:M").Copy
    Workbooks(ControlFile).Worksheets(2).Columns("A:M").PasteSpecial (xlPasteAll)
    ' On vide le P-P
    Application.CutCopyMode = False
    Workbooks(Filename).Close SaveChanges:=False
 
fichierOuvert:
End Sub