Discussion :

[Nemerion]

Bonsoir à la communauté !

Voila j'ai un petit soucis car je gère un fichier Excel 2010 qui a plusieurs dizaines de milliers de lignes et pour lesquelles je dois extraire le nom du fournisseur (cf fichier annexe). Le problème est que le nom de ce fournisseur peut se situer n'importe ou sur cette ligne (pour cela j'avais donc du procéder à un si(esterreur(cherche...) mais je crains d'avoir affaire à une formule gargantuesque de fournisseurs quand mon fichier fera 40 000 lignes !

Serait-il donc possible d'extraire le nom du fournisseur présent dans la colonne A de la feuille "Test" et le remettre dans la colonne B, En fonction des fournisseurs présents dans la feuille "liste fournisseurs", qui sera réalimentée régulièrement quand de nouvelles lignes de fournisseurs apparaîtront ?

Pour le moment je n'ai pas trouvé la possibilité de le faire en formules... Ce serait possible par macro ?

[papouclo]

Bonjour,
Si cela ne gène pas d'avoir un zéro dans la cellule B11 de la feuille Test, écrire comme formule en B2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX('Liste des fournisseurs '!A:A;SOMMEPROD(ESTNUM(CHERCHE(Test!A2;'Liste des fournisseurs '!$A$2:$A$10))*LIGNE('Liste des fournisseurs '!$A$2:$A$10)))

et recopier vers le bas.
Si l'on préfère une cellule vide en C11, écrire alors en B2 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(SOMMEPROD(1*ESTNUM(CHERCHE('Liste des fournisseurs '!$A$2:$A$10;Test!A2)));INDEX('Liste des fournisseurs '!A:A;SOMMEPROD(ESTNUM(CHERCHE(Test!A2;'Liste des fournisseurs '!$A$2:$A$10))*LIGNE('Liste des fournisseurs '!$A$2:$A$10)));"")

Cordialement
Claude

[Nemerion]

Merci Claude j'ai bien le fournisseur sur la colonne B c'est cool !

Mais par hasard, est ce que la formule peut prévoir qu'en cellule B2 on obtienne le même fournisseur qu'en A2 ? J'obtiens à la fois Synergie en A2 et Manpower en B2 !

Cordialement, Kévin.

[papouclo]

Bonjour,
Toutes mes excuses !
Il y avait une erreur dans la première formule avec une inversion des arguments pour la fonction CHERCHE.
La bonne formule est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX('Liste des fournisseurs '!A:A;SOMMEPROD(ESTNUM(CHERCHE('Liste des fournisseurs '!$A$2:$A$10;Test!A3))*LIGNE('Liste des fournisseurs '!$A$2:$A$10)))

Cordialement
Claude

[Nemerion]

Impeccable Claude c'est simplement parfait ! Merci beaucoup