Discussion :

[MarcelG]

Bonsoir le Forum,

Je voudrais créer une procédure simple rappelée dans tous les évènements Initialize de mes Userforms.

Cette procédure aurait pour effet de CACHER (et non désactiver) la croix de fermeture.

Pour ce faire, j'ai tenté d'adapter une proposition du regretté (car sauf erreur non actif) Laurent LONGRE (à consulter chez les voisins du laboratoire).

Dans un module nommé API

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Option Private Module
 
Declare Function GetWindowLongA Lib "User32" _
        (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Declare Function SetWindowLongA Lib "User32" _
        (ByVal hWnd As Long, ByVal nIndex As Long, _
        ByVal dwNewLong As Long) As Long
Declare Function FindWindowA Lib "User32" _
       (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
 
Sub Suppr_fermeture()
Dim hWnd As Long
hWnd = FindWindowA("Thunder" & IIf(Application.Version Like "8*", _
"X", "D") & "Frame", Me.Caption)
SetWindowLongA hWnd, -16, GetWindowLongA(hWnd, -16) And &HFFF7FFFF
End Sub

Et dans l'évènement Initialize de TOUS les usf

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Call Suppr_fermeture

L'erreur vient du

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.Caption

que je n'arrive pas à rendre variable.

J'ai pensé à un module de classe; mais cela reste au-desus de mes modestes capacités.

Si quelqu'un a une idée, merci par avance.

[Invité]

Soit mettre ton code dans le 'Userform':

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Option Explicit
 
Private Declare Function GetWindowLongA Lib "User32" _
        (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLongA Lib "User32" _
        (ByVal hWnd As Long, ByVal nIndex As Long, _
        ByVal dwNewLong As Long) As Long
Private Declare Function FindWindowA Lib "User32" _
        (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
 
Private Sub UserForm_Initialize()
    Dim hWnd As Long
    hWnd = FindWindowA("Thunder" & IIf(Application.Version Like "8*", "X", "D") _
    & "Frame", Me.Caption)
    SetWindowLongA hWnd, -16, GetWindowLongA(hWnd, -16) And &HFFF7FFFF
End Sub

Soit le passer en paramètre:

Code du 'Userform':

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Option Explicit
 
Private Sub UserForm_Initialize()
    Call SuppressionCroix(Me)
End Sub

Et dans un module:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Option Explicit
 
Private Declare Function GetWindowLongA Lib "User32" _
        (ByVal hWnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLongA Lib "User32" _
        (ByVal hWnd As Long, ByVal nIndex As Long, _
        ByVal dwNewLong As Long) As Long
Private Declare Function FindWindowA Lib "User32" _
        (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
 
Public Sub SuppressionCroix(UserForm As UserForm)
    Dim hWnd As Long
    hWnd = FindWindowA("Thunder" & IIf(Application.Version Like "8*", "X", "D") _
    & "Frame", UserForm.Caption)
    SetWindowLongA hWnd, -16, GetWindowLongA(hWnd, -16) And &HFFF7FFFF
End Sub

[MarcelG]

Bonsoir Vincent,

Merci pour ta réponse.

J'essaie d'adapter le code indiqué par Laurent Longre dans son développement.
Laurent indique bien la possibilité de créer une seule procédure appelée dans l'évènement Initialize de chaque usf concerné.
Sauf erreur, on ne peut évoquer de lien externe mais tu pourras trouver facilement par un moteur de recherche (Lab, Excel, Croix...)

Merci encore.

[Invité]

Voir la deuxième partie de mon post. Je l'ai rajouté après...

[MarcelG]

Le code fonctionne!

Merci Vincent.
Tu mérites vraiment ton titre de "Membre éclairé", et ceux qui vont venir ensuite, bientôt j'espère.

Juste un détail : je ne comprends donc pas ce que veut dire Laurent Longre à la fin de son post.

Bonne soirée.

[Invité]

Il dit quoi dans son post?