Discussion :

[hehee]

Bonjour,
J'ai un fichier Excel permettant d'imprimer un rapport. J'aimerais que toute la mises en page se fasse avec une macro. J'ai déjà réussit tout ce que je voulais faire à l'exception que j'aimerais, si possible, ajuster mes sauts de page pour qu'il ne coupe pas un bloc de données. Il est à noter que la grosseur des blocs peut varier aléatoirement. J'aimerais donc pour toutes les pages, si un bloc de données est coupé, que le saut de page se place au dessus du titre "À expédier le ..." afin d'avoir un beau rapport.

Pouvez-vous m'aider ?

Merci !

[parmi]

Bonjour,

Je pense que ceci devrait t'aider

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub SautDePage()
    Dim I As Long, J As Long
 
    Application.ScreenUpdating = False
 
    ActiveWindow.View = xlPageBreakPreview
    ActiveSheet.ResetAllPageBreaks
 
    For I = 1 To ActiveSheet.HPageBreaks.Count
        For J = ActiveSheet.HPageBreaks(I).Location.Row - 1 To 3 Step -1
            If InStr(1, Range("A" & J), "expédier") > 0 Then
                Set ActiveSheet.HPageBreaks(1).Location = Range("A" & J)
                Exit For
            End If
        Next
    Next
 
    ActiveWindow.View = xlNormalView
    Application.ScreenUpdating = True
End Sub

[hehee]

J'ai fait une petite correction, probablement une erreur de frappe, j'ai remplacé le 1 par I :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set ActiveSheet.HPageBreaks(1).Location = Range("A" & J)

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set ActiveSheet.HPageBreaks(I).Location = Range("A" & J)

Sinon, wow !!! Franchement, je n'aurais jamais réussis à pondre un truc du genre ! Je te remercie infiniment !

[parmi]

Effectivement, c'était un I qui devait être là.

J'oubliais aussi de mentionner qu'il se pourrait qu'un nouvelle page s'ajoute s'il y a beaucoup de saut de pages. Disons qu'au début tu as 10 pages, il se peut qu'après avoir insérer les 9 sauts de pages, tu te retrouves avec une 11e page qui ne serait pas prise en compte.

Il faudra y ajouter une autre boucle, ce qui donnerait quelque chose comme:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
    nbPageBr = Activesheet.HPageBreaks.Count
 
    For I = 1 To nbPageBr
        For J = Activesheet.HPageBreaks(I).Location.Row - 1 To 3 Step -1
            If InStr(1, Range("A" & J), "expédier") > 0 Then
                Set Activesheet.HPageBreaks(I).Location = Range("A" & J)
                Exit For
            End If
        Next
    Next
 
    If nbPageBr < Activesheet.HPageBreaks.Count Then 'vérifier si c'a changé...
        nbPageBr = Activesheet.HPageBreaks.Count
        For J = Activesheet.HPageBreaks(nbPageBr).Location.Row - 1 To 3 Step -1
            If InStr(1, Range("A" & J), "expédier") > 0 Then
                Set Activesheet.HPageBreaks(nbPageBr).Location = Range("A" & J)
                Exit For
            End If
        Next
    End If

[hehee]

Dans ta 2e boucle, tu as mis Range("C") au lieu de A... est-ce voulu ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 If nbPageBr < Activesheet.HPageBreaks.Count Then 'vérifier si c'a changé...
        nbPageBr = Activesheet.HPageBreaks.Count
        For J = Activesheet.HPageBreaks(nbPageBr).Location.Row - 1 To 3 Step -1
            If InStr(1, Range("C" & J), "expédier") > 0 Then
                Set Activesheet.HPageBreaks(nbPageBr).Location = Range("A" & J)
                Exit For
            End If
        Next
    End If

[parmi]

Non, c'est bien A...
Erreur de copie.
désolé