Cascade combox et ajout données

**ericdev67** · 01/06/2013, 10h40

Bonjour,

J'utilise l'excellent tuto de Silkyroad (merci pour tous tes apports) sur la création de combox en cascade :

http://excel.developpez.com/faq/?pag...omboboxCascade

mais j'aimerai savoir s'il est possible de rajouter des données....

je m'explique (prenons l'exemple du classeur de Silkyroad), admettons que je sélectionne

Ville01

, donc dans le "champ2", j'ai les différentes proposition, mais admettons qu'elle n'existe pas (=pas dans la feuille "Base"), j'aimerai pouvoir rajouter

Ville01_Q5

, est-ce possible...sans passer par la base ??

Exemple : j'ai un Userform qui me sert de masque de saisie, le champ1 = fruits, légumes, dans le champ2, j'ai : orange, pomme, poire, carottes, artichaud,...Admettons que je clique sur le champ1, je sélectionne "fruits" et dans ma liste, n'apparait pas "banane", il faudrait qu'une combox s'ouvre, demande de saisir le nouvel élément (=banane) et le mette dans la feuille "Base", pour que la prochaine fois où j'utiliserai le fichier, "Banane" fasse parti des choix..

Est ce possible ?

Une petite idée ?

Merci,

A+

Invité · 01/06/2013, 11h43

Salut Ericdev67

En partant du classeur de notre ami Silkyroad, voici le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Private Sub ComboBox2_AfterUpdate()
  Dim NLig As Long, MemStr As String
  ' Si la valeur saisie n'existe pas, valeur retournée de ListIndex = -1
  If Me.ComboBox2.ListIndex = -1 Then
    If MsgBox("Cette valeur n'existe pas, voulez-vous l'ajouter ?", _
      vbQuestion + vbYesNo, "QUESTION ...") = vbNo Then
      Me.ComboBox2.Value = ""
      Exit Sub
    End If
    ' Si l'utilsateur répond oui
    ' Mémoriser la valeur saisie car on va réalimenter la combo
    MemStr = Me.ComboBox2.Text
    ' on ajoute la valeur à la base sans oublier le premier champ
    With Sheets("Base")
      NLig = .Range("A" & Rows.Count).End(xlUp).Offset(1, 0).Row
      .Range("A" & NLig).Value = Me.ComboBox1.Text
      .Range("B" & NLig).Value = Me.ComboBox2.Text
    End With
  End If
  ' Réalimenter le combobox
  Alim_Combo 2, ComboBox1.Value
  ' Inscrire la valeur mémoriser
  Me.ComboBox2.Value = MemStr
End Sub

A+