Discussion :

[bentor22]

Bonjour à tous,

j'ai généré un code avec l enregistreur de macro pour faire une MFC.

toutefois sur excel 2003, c est limité à 3 conditions.

voici le code généré:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
    Cells.Select
    Selection.FormatConditions.Delete
    Selection.FormatConditions.Add Type:=xlExpression, Formula1:="=$A1=""PNU"""
    Selection.FormatConditions(1).Interior.ColorIndex = 15
    Selection.FormatConditions.Add Type:=xlExpression, Formula1:= _
        "=$A1=""ITU"""
    Selection.FormatConditions(2).Interior.ColorIndex = 48
    Selection.FormatConditions.Add Type:=xlExpression, Formula1:= _
        "=$A1=""GUA"""
    Selection.FormatConditions(3).Interior.ColorIndex = 34

toutefois j aurai aimé rajouter 1 parametre supplémentaire à savoir:

si $A1="oth" alors couleur grise.

en vous remerciant par avance pour votre aide.

bien cordialement,

[NEC14]

Bonjour,

Il vous suffit tout simplement de rajouter une condition à ce code, puisqu'avec Vba vous n'êtes plus limité.

[bentor22]

Bonjour, j ai essayé mais cela ne marche pas.

Je pense que comme il est issu de l enregistreur automatique, il est quand même limite a 3

[mercatog]

Utilise l'évènement Change de la feuille, tu auras plus de possibilités.

Code à mettre dans le module de ta feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Klr As Integer
Dim c As Range
 
If Target.Column = 1 Then
    For Each c In Target
        Select Case UCase(Trim(c.Value))
            Case "PNU": Klr = 15
            Case "ITU": Klr = 48
            Case "GUA": Klr = 34
            Case "OTH": Klr = 16
            Case Else: Klr = xlNone
        End Select
        c.EntireRow.Interior.ColorIndex = Klr
    Next c
End If
End Sub

[bentor22]

bonjour,

je n ai pas compris comment executer la macro

[mercatog]

1. Si tes données sont déjà saisies dans ta feuille et que tu veux colorier les lignes en fonctions des données de la cellule en colonne A, lance la procédure Execute.

2. Si tes données doivent être saisies, la coloration se fera automatiquement (par appel de l'évènement Change)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub Executer()
 
Colorier Worksheets("Feuil1").Range("A1:A1000")
End Sub
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
Colorier Target
End Sub
 
Private Sub Colorier(ByVal Rng As Range)
Dim Klr As Integer
Dim c As Range
 
If Rng.Column = 1 Then
    For Each c In Rng
        Select Case UCase(Trim(c.Value))
            Case "PNU": Klr = 15
            Case "ITU": Klr = 48
            Case "GUA": Klr = 34
            Case "OTH": Klr = 16
            Case Else: Klr = xlNone
        End Select
        c.EntireRow.Interior.ColorIndex = Klr
    Next c
End If
End Sub

[bentor22]

CA MARCHE TRES BIEN.

merci enormement