Discussion :

[Mike Reason]

Bonjour à tous,

Voilà...
Je joue un peu avec Excel et je suis bloqué sur un problème que je n'arrive pas à résoudre après avoir cherché un tit moment sur le WEB.

Au départ, je voulais simuler des appuies de touches de l'utilisateur pour qu'il puisse passer une fenêtre avec un mot de passe... Facile :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
    Call SendKeys("MyPass")
    Call SendKeys("{Enter}")

Problème #1 :
Quand l'utilisateur vérouille son poste... A marche pu !
Du coup en cherchant un peu, j'ai trouvé la fonction "SendMessage" qui permet d'envoyer des événements en passant le numéro de la fenêtre.
Voilà le code que j'ai récupéré :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Private Declare Function PostMessage Lib "user32" Alias "PostMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
 
Private Const WM_SETTEXT = &HC
Private Const EM_SETSEL = &HB1
 
Private Const WM_KEYDOWN = &H100
 
 
Private Sub SendPassword(ByVal hWnd As Long, ByVal sPass As String)
  'Send password as text
  SendMessage hWnd, WM_SETTEXT, 0&, ByVal sPass
  'Set the selection of the edit/text box
  SendMessage hWnd, EM_SETSEL, Len(sPass), 0&
  'Send Enter/return key
  PostMessage hWnd, WM_KEYDOWN, &HD&, &H1C0001
End Sub

Et donc me suis dit que pour balancer mon mot de passe, suffisait que j'envoie le handle de mon application et le mot de passe tout simplement via une fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Sub testSend()
    Call SendPassword(Application.hWnd, "TST")
End Sub

Problème #2
Ca marche pas !
J'aurais au moins voulu que le SendMessage fasse pareil que SendKeys, mais j'y arrive pas !

J'ai fouillé sur le net et à chaque fois tout le monde a résolu sons problème on sait pas trop comment....
Quelqu'un sait comment que ça marche ?

Merci d'avance à tout ceux qui voudront bien me répondre !

[AlainTech]

Et encore un qui résoud son problème sans dire comment il a fait...

[Mike Reason]

Et oui, vu que je n'avais pas de réponses, je me suis dit que ça devait pas intéressé grand monde...
Et comme le dise la plupart des gens qui veulent poster sur un forum, va voir ici et tu trouveras la solution !

Bref, bref...

SendMessage ne marche pas du tout comme SendKeys. SendKeys simule des actions claviers alors que SendMessage envoi un message vers un processus cible. C'est pour ça que SendMessage peut être utilisé sans avoir l'ordi dévérouillé.

Mon problème était exactement le même que dans ce post :
http://www.ozgrid.com/forum/showthread.php?t=157064
Je me suis donc inspiré de la solution mise en place pour mon programme.

En fait, il fallait que j'accéde à la fenêtre d'ouverture du fichier, pis au contrôle contenant le contrôle de la zone éditable, pis au contrôle contenant la zone éditable, pis à la zone éditable et enfin faire mon SendMessage vers cette zone en question :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
 
Option Explicit
 
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, _
    ByVal lpWindowName As String) As Long
Private Declare Function SetForegroundWindow _
    Lib "user32" (ByVal hWnd As Long) As Long
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" (ByVal hWnd1 As Long, _
    ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
 
Public Const WM_SETTEXT = &HC
Public Const BM_CLICK As Long = &HF5&
 
Public Sub Upload_Set_Filename(sFilePathName As String)
    Dim hWnd As Long
    Dim timeout As Date
    timeout = Now + TimeValue("00:00:10")
    Do
        hWnd = FindWindow("#32770", "Choisir un fichier à télécharger")
        DoEvents
    Loop Until hWnd Or Now > timeout
    If hWnd Then
        SetForegroundWindow (hWnd)
        hWnd = FindWindowEx(hWnd, 0, "ComboBoxEx32", vbNullString)
    End If
    If hWnd Then
        hWnd = FindWindowEx(hWnd, 0, "ComboBox", "")
    End If
    If hWnd Then
        SetForegroundWindow (hWnd)
        hWnd = FindWindowEx(hWnd, 0, "Edit", "")
    End If
    If hWnd Then
        SendMessage hWnd, WM_SETTEXT, 0, ByVal sFilePathName
    End If
End Sub

Et ça marche !

Donc, pour faire un SendMessage il faut connaitre l'architecture de la fenêtre cible, savoir les contrôles contenus et connaitre avec quel contrôle on veut interragir !