Discussion :

[graphikris]

Bonjour,
Je dispose d'une base de données dans laquelle j'ai plusieurs feuilles.
Dans l'une d'elle [Stages] je saisi dans les colonnes suivantes ceci :

A1 : Noms
B1 : Intitulés de stages
C1 : Dates fin stages
D1 : Recyclages Stages

En fonction de l'intitulé de stage, Excel me calcul la date de recyclage s'il ya lieu ou m'indique à défaut : Pas de recyclage.
avec ce style de formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTNA(EQUIV(B2;Param_Stages!$A$2:$A$12;0));"Pas de recyclage";DATE(ANNEE(C2);MOIS(C2)+RECHERCHEV(B2;Param_Stages!$A$2:$B$12;2;FAUX);JOUR(C2)))

A savoir qu'a chaque fois que je vais sur l'onglet [Stages], la feuille est retriée :
1 - Ordre croissant des Stages
2 - Dates fin stages
3 - Noms

Sur une autre feuille [Param_Stages], j'ai dans les colonnes suivantes :
A1 : Intitulés de stages
B1 : Durée de validité (en mois)

Sur ma feuille [Accueil], j'ai dans les colonnes suivantes :
A1 : Intitulé du Stage 1 (Word)
B1 : Intitulé du Stage 2 (Powerpoint)
C1 à G1 => Idem : Intitulé du Stage 3 puis 4 etc....

Les stages n'ayant pas de recyclage ne sont pas sur cette feuille.

A2 : n (en police Webdings) représentant un rond.
B2 à G2 : n (Webdings)

Quelle formule magique ou MFC saisir pour A2 afin que si au moins une date de recyclage arrive à échéance dans 2 mois alors le rond (n en Webdings) devienne ORANGE, puis si la date est dépassée alors le rond devienne ROUGE ?
A défaut le rond reste VERT.

Ex : Stage Word (valide 1 an)
Noms Date Fin stage Recyclage prevu
Mr Pierre 27/03/12 27/03/2013
Mr Durand 25/04/12 25/04/2013
Mr Sance 13/09/12 13/09/2013

Le Stage de Mr Pierre n'est plus Valide (Rouge)
Mr Dupont est valide mais ne le sera plus dans moins de 2 mois (Orange)
Mr Sance est valide (Vert)
Dans la feuille [Accueil] le rond (n en Webdings) devra donc être Rouge puisqu'au moins une des dates du stage (Word) est Rouge.
Si Mr Pierre n'avait pas fait ce stage alors au moins une dates est Orange alors le "n" sera Orange

Merci au Merlin qui pourra m'aider à trouver la formule secréte.

__________
Cordialement Graphikris

[Daniel.C]

Bonjour,

Pas sûr de bien comprendre. Peux-tu mettre un classeur exemple en PJ ?

[Philippe Tulliez]

Bonjour,
Un exemple avec en H1 la date de fin de stage, en H1 date de recyclage et la date du jour est représenté par une cellule nommée wrkDate et ce pour cause de test (peut être remplacé par AUJOURDHUI().
Formule a placer dans la mise en forme conditionnelle de la cellule A1.
Pour obtenir le rond rouge

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=wrkDate>I2

Pour obtenir le rond orange

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ET(DATEDIF($L2;$I2;"M")>0;DATEDIF($L2;$I2;"M")<=2)

Le dernier cas n'est pas absolument précis parce-que la formule renvoie exactement 2 mois donc si nous sommes à 2 mois et 10 jours, c'est considéré comme étant 2 mois. Il y aurait lieu d'utiliser un correctif ou une autre formule.

[graphikris]

Bonjour a vous 2 (Daniel et Philippe)

Pour Daniel, je met un fichier en exemple.

Pour Philippe, je ne comprends pas tout a fait ce que tu veux dire.

Tu me dis : en H1 la date de fin de stage, en H1 date de recyclage et la date du jour.
Ok mais H1 ne peux pas etre en meme temps 2 dates differentes.
Pour H1 date de recyclage et la date du jour ????

Peux tu par rapport au fichier joint me conseiller ?

Merci a vous deux

Cordialement
______ Graphikris

[Daniel.C]

Tu dois définir deux noms pour les valeurs des colonnes B et F de la feuille Stages; par exemple ColB défini par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=Stages!$B$2:$B$41

et ColF défini par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=Stages!$F$2:$F$41

Sélectionne la plage A2:K2 de la feuille Accueil. Définis la première condition (vert) avec la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI(ESTNUM(ColF);SI((ColB="adr")*(ColF>AUJOURDHUI())>0;(ColF))))>AUJOURDHUI()+60

Le deuxième (orange) avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI(ESTNUM(ColF);SI((ColB="adr")*(ColF>AUJOURDHUI())>0;(ColF))))>AUJOURDHUI()

et la dernière (rouge) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI(ESTNUM(ColF);SI((ColB="adr")*(ColF>AUJOURDHUI())>0;(ColF))))<=AUJOURDHUI()

Regarde le classeur joint.

[graphikris]

Bonjour Daniel,

Merci je teste sinon vas voir dans la partie Contribuez le post concernant mailing auto 1er j ...................

Cordialement

Re,

Normalement dans Accueil, concernant le stage ADR, le rond devrait etre rouge puisqu'il y a 2 dates en rouge, 1 en orange et le reste correct. Et meme s'il n'y avait eu qu'un rouge , le rond derait etre donc rouge car dès quil y a un rouge alors le rond est rouge meme si y avait 5 orange et 25 vert

Si celà s'avère trop complexe à formuler, j'ai également une autre possibilité, voir image jointe (feuille Accueil# : sous les ronds viennent s'inscrire la somme des dates dépassées #rouge#, périmées dans 2 mois #orange#, valides #vert# par stage.

[Daniel.C]

Bon; les formules deviennent respectivement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI(ESTNUM(ColF);SI(ColB=A$1;ColF)))>AUJOURDHUI()+60

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI(ESTNUM(ColF);SI(ColB=A$1;ColF)))>AUJOURDHUI()

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MIN(SI(ESTNUM(ColF);SI(ColB=A$1;ColF)))<=AUJOURDHUI()

Regarde le classeur joint.

[graphikris]

Bonjour Daniel,

Merci tout fonctionne.
Si je devais faire par rapport à la miniature postée dans mon msg du 30/03 à 19h02, je suppose que je devrais faire une formule avec SOMMEPROD. J'ai essayé mais çà me met Zéro partout.
J'ai joins un nouveau fichier.

Cordialement
______ Graphikris

[Daniel.C]

Regarde le classeur joint. Les formules sont matricielles (valider avec Ctrl+Maj+Entrée). Pour ADR :

rouge :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(SI(ESTNUM(ColF);SI(ColB=$A$5;(ColF<=AUJOURDHUI())*1;0);0))

orange :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(SI(ESTNUM(ColF);SI(ColB=$A$5;(ColF>AUJOURDHUI())*1;0);0))-C7

vert :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(SI(ESTNUM(ColF);SI(ColB=$A$5;(ColF>AUJOURDHUI()+60)*1;0);0))

[graphikris]

Nickel , Daniel

Merci
Graphikris