Discussion :

[Phanloga]

Bonjour.

Dans une cellule, j'ai la formule ci dessous :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

="Données RH extraites du SI à fin "&MOIS(AUJOURDHUI())&" "&ANNEE(AUJOURDHUI())

Le résultat donne le mois sur 2 chiffres.

Comment forcer l'affichage du nom du mois complet ?
J'ai tenté tout ce que je connaissais en matière de format personnalisé.

Merci.

[Philippe Tulliez]

Bonjour,
C'est la formule TEXTE avec la même syntaxe de formatage que le format personnalisé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

="Données RH extraites du SI à fin " & TEXTE(AUJOURDHUI();"mmmm aa")

[EDIT] Autres possibilités
Dans les exemples ci-dessous, Les constantes en italique, les variables en gras
Exemple 1
En A3 la somme à payer en (4500), B3, le nombre de jours d'échéances (20) et AUJOURDHUI() (16/11/2012).
La formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

="Veuillez virer la somme de " & TEXTE(A3;"#.### €") & " pour le " & TEXTE(AUJOURDHUI()+B3;"jjjj, j mmmm aaaa")

Valeur renvoyée : Veuillez virer la somme de 4.500 € pour le jeudi, 6 décembre 2012
Exemple 2
En A12 (12000), en B12 (12,5)
La formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

="Chiffre d'affaires réalisé : " & TEXTE(A12;"# ### €") & " soit " & TEXTE(B12;"#0,00%") & " du total."

Valeur renvoyée : Chiffre d'affaires réalisé : 12 000 € soit 12,50% du total.

Autre syntaxe pour l'exemple 2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

="Chiffre d'affaires réalisé : " & TEXTE(A12;"# ### €") & " soit " & TEXTE(B12;"#0,0#%") & " du total."

Valeur renvoyée : Chiffre d'affaires réalisé : 12 000 € soit 12,5% du total.
Dans la première syntaxe nous voyons 12,50% dans l'autre 12,5%

[Phanloga]

Merci.
Encore un pas franchi vers la connaissance ultime !

[Philippe Tulliez]

Bonjour,
J'ai ajouté quelques exemples des possibilités offertes par la combinaison de la formule TEXTE et la concaténation de chaînes de caractères.
(Voir mon intervention d'hier)