Discussion :

[kris12]

Bonjour à tous,

J'ai un tableau avec des valeurs numériques quelconque de A1 à A100 dans ma feuille 1. Je souhaiterais à l'aide de ma macro, attribuer un nom pour chaque valeur différente que je trouve en parcourant les valeurs dans cette colonne. Voilà le code que j'ai commencé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
    Dim valeur1 As Integer
    Dim valeur2 As Integer
    Dim valeur3 As Integer
    Dim valeur4 As Integer
    Dim valeur5 As Integer
    Dim valeur6 As Integer
    Dim valeur7 As Integer
    Dim valeur8 As Integer
    Dim valeur9 As Integer
    Dim valeur10 As Integer
    (il ne peut y a voir plus de 10 valeurs différentes dans la colonne)
 
    k = 1
 
 
    valeur1 = Sheets("Feuil1").Cells(1, 1).Value
 
 
    If Sheets("Feuil1").Cells(k, 1).Value <> valeur1 Then
 
    valeur2 = Sheets("Feuil1").Cells(k, 1).Value
 
    End If
 
 
    If Sheets("Feuil1").Cells(k, 1).Value <> valeur1 And Sheets("Feuil1").Cells(k, 1).Value <> valeur2 Then
 
    valeur3 = Sheets("Feuil1").Cells(k, 1).Value
 
    End If
 
    etc...

Donc, la macro m'enregistre bien la première valeur de la colonne en tant que valeur1, ensuite la première valeur différente à valeur1 rencontrée est enregistrée en tant que valeur2, mais dès que il y a une troisième valeur différente, il m'enregistre celle-ci en tant que valeur2 et non pas valeur3. Je pense bien que le problème viens de ces deux lignes du code:

valeur2 = Sheets("Feuil1").Cells(k, 1).Value

valeur3 = Sheets("Feuil1").Cells(k, 1).Value

mais je ne sais pas comment le dire autrement.

J'espère avoir été clair et que quelqu'un pourra m'aider. Merci d'avance

[Bear the french]

Bonjour Kris12,

Ton problème vient du fait que k ne s'incrémente pas.

Même si je n'aurai pas du tout fait un code de cette manière, je t'ai corrigé un minima le tien :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
    k = 1
    valeur1 = Sheets("Feuil1").Cells(k, 1).Value
    k = k + 1
 
    If Sheets("Feuil1").Cells(k, 1).Value <> valeur1 Then
         valeur2 = Sheets("Feuil1").Cells(k, 1).Value
         k = k + 1
    End If
 
    If Sheets("Feuil1").Cells(k, 1).Value <> valeur1 And Sheets("Feuil1").Cells(k, 1).Value <> valeur2 Then
        valeur3 = Sheets("Feuil1").Cells(k, 1).Value
        k = k + 1
    End If

Il conviendrait plutôt de faire une boucle (For i=1 to ...) pour parcourir la colonne et affecter les noms en fonction.

Bertrand

[gFZT82]

Bonjour,

Tu peux utiliser une collection qui se prête bien à ce genre d'exercice

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Option Explicit
Sub Test()
Dim MaPlage As Range, Cel As Range
Dim C As Collection
Dim DerLig As Long, i As Long
Dim Valeur()
Dim Message As String
    Set C = New Collection
    On Error Resume Next
    With Worksheets("Feuil1")
        DerLig = .Range("A" & .Rows.Count).End(xlUp).Row
        Set MaPlage = .Range("A1:A" & DerLig)
        For Each Cel In MaPlage
            If Cel <> "" Then C.Add Cel, CStr(Cel)
        Next Cel
        On Error GoTo 0
        For i = 1 To C.Count
            Message = Message & "Valeur " & i & " : " & C.Item(i) & Chr(10)
        Next i
    End With
    MsgBox Message
    Set C = Nothing
End Sub

Cordialement.

[Didier Gonard]

Bonjour,

tu peux utiliser un filtre avancé sans doublon, au niveau optimisation du code, il n'y a pas photo, ici je prend une plage de 13 cellules avec 2 doublons et 1 titre.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Option Explicit
Option Base 1 'impératif, cf aide VBA
 
Sub Macro1()
'Si le contexte s'y prête, une varaible tableau est bien plus souple que xx variables indicées....
Dim tboVAleur(10) As Long 'ou autre / contexte
Dim cell As Range
Dim I As Byte
 
I = 1
Range("A1:A13").AdvancedFilter Action:=xlFilterInPlace, Unique:=True
' Range("_FilterDataBase") = plage nommée (nom masqué) créée dès la mise en place d'un filtre.
For Each cell In Range("_FilterDataBase").Offset(1, 0).Resize(Range("_FilterDataBase").Rows.Count - 1).SpecialCells(xlCellTypeVisible)
'on ne tient pas compte de la ligne de titre, cf aide VBA à Resize
   tboVAleur(I) = cell.Value
   I = I + 1
Next cell
    Stop 'voir dans fenêtre variables locales les valeurs de tboVAleur, et affecter selon besoin
ActiveSheet.ShowAllData ' montre tout
End Sub

Cordialement,

Ps : si le côté technique de la réponse = OK ou pas => pensez à cliquer sur les pouces et quand question résolue à la taguer résolue, et chaque action vous rapporte des points

Didier