Discussion :

[come973]

Bonjour,

Je souhaiterai a partir d'une macro pouvoir compléter un tableau a partir de la valeur dans une liste.
Je vous joint le fichier, vous comprendrez mieux.

J'avais une fonction pour le faire mais sur un tableau énorme excel plante et j'ai attendu 5 heures de calcul.

La liste est moins grande, mais je n'y arrive pas, mes exam arrive a grand pas et sans cela je vais me retrouver dans la panade.

Merci de votre aide

[jfontaine]

Bonjour,

Quelle fonction as tu utilisé?

Ci dessous une formule matricielle qui remplit le tableau. (a mettre en C2 de l'onglet Synthèse et à valider par CTRL + MAJ + ENTREE)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTERREUR(INDEX(Liste!$D$2:$D$6;EQUIV(1;(Liste!$A$2:$A$6=Synthese!$A2)*(Liste!$B$2:$B$6=Synthese!$B2)*(Liste!$C$2:$C$6=C$1);0)));"";INDEX(Liste!$D$2:$D$6;EQUIV(1;(Liste!$A$2:$A$6=Synthese!$A2)*(Liste!$B$2:$B$6=Synthese!$B2)*(Liste!$C$2:$C$6=C$1);0)))

Si les temps ne sont pas concluant, revient vers nous pour une macro

[Bear the french]

Bonsoir,

L'objectif : Remplir le tableau jaune en feuille synthèse avec des "yes" verts et des "no" rouges sur les 3 colonnes ? (est-ce qu'il y a plus à remplir que le tableau jaune ? Dans le genre les noms à gauche du tableau jaune ?)

Si tu parles de .VBS, cela veut peut-être dire que tu ne veux pas te contenter d'une formule matricielle comme le suppose Jérôme mais que l'on risque de te demande un peu de coder pour tes examens.

Cela parait faisable à priori et en théorie, avec 3 IF imbriqués (une par colonnes) et un For Loop englobant du style :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
For x = 2 to Range("a65536").End(xlUp).row
 
Next

Bertrand

[jfontaine]

Je te donne une méthode détaillée, Analyses la et poses des questions si besoin

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Sub Bouton1_Cliquer()
 
Dim ShSource As Worksheet
Dim ShCible As Worksheet
 
Dim Rg As Range
Dim strAddress As String
 
Dim i As Long
 
' Alimente les variables Feuille
Set ShSource = ThisWorkbook.Sheets("Liste")
Set ShCible = ThisWorkbook.Sheets("Synthese")
 
'Lecture de la feuille Source
For i = 2 To ShSource.Range("A" & Rows.Count).End(xlUp).Row
 
    'Recherche du nom dans la feuille cible
    Set Rg = ShCible.Range("A:A").Find(what:=ShSource.Range("A" & i).Value, lookat:=xlWhole)
 
    'Si on trouve le nom
    If Not Rg Is Nothing Then
 
            strAddress = Rg.Address
            Do
                'Test si la ligne trouvée comporte la même marque
                If Rg.Offset(0, 1).Value = ShSource.Range("B" & i).Value Then
                    'Si même marque on met a jour le tableau
                    Select Case ShSource.Range("C" & i).Value
                        Case "vert"
                            Rg.Offset(0, 2).Value = ShSource.Range("D" & i).Value
                        Case "rouge"
                            Rg.Offset(0, 3).Value = ShSource.Range("D" & i).Value
                        Case "bleu"
                            Rg.Offset(0, 4).Value = ShSource.Range("D" & i).Value
                    End Select
                    'On sort de la recherche pour passer à la ligne source suivante
                    Exit Do
                End If
 
                'Si pas la meme marque alors on cherche le nom suivant
                Set Rg = ShCible.Range("A:A").FindNext(Rg)
 
            Loop While Not Rg Is Nothing And Rg.Address <> strAddress
 
    End If
 
Next i
 
End Sub

[Bear the french]

Bravo Jérôme,

En plus ton code est bien commenté.
SELECT CASE est préférable à mes 3 IF

Bertrand

[jfontaine]

merci