Discussion :

[gege765]

Bonjour,

Voilà actuellement j'ai deux fichiers excel. Chacun d'entre eux se compose d'une feuille.

Mon but serait de regrouper des colonnes présents dans le second fichier dans le premier fichier. Cela pourra je pense être réalisé grâce à une clef unique présent dans les deux fichiers.

Éventuellement je peux déjà mettre les deux feuilles dans le même classeur.

Structure du fichier 1 :
id;nom;prénom;adresse;ville

Structure du fichier 2 :
nom;prénom;id;service;responsable;fonction

Structure du fichier souhaité :
id;nom;prénom;adresse;ville;service;fonction

Comment puis-je procéder ?
Existe-il des fonction pré-définis pour cela dans Excel 2007?

Merci.

[gFZT82]

Bonjour,

Tu pourras t‘aider de cet exemple :
J’ai regroupé les 2 feuilles dans un même classeur.
J’ai adapté ces 2 feuilles pour avoir la même structure de colonnes.
J’ai supposé que les ID sont uniques (pas de doublon).

J’ai choisi de compléter la feuille "Feuil2" (feuille de référence) avec la "Feuil1" (feuille Bis).
Pour cela, je vérifie que pour chacun des ID de la feuille bis il existe une correspondance dans la feuille de référence. Si tel est le cas, je complète la ligne de la feuille de référence. Dans le cas contraire, j’ajoute la ligne de cet ID et les données associées dans la feuille de référence.

Au final, tu obtiens l’ensemble des ID et les données associées dans la feuille de référence.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub Test()
Dim WsRef As Worksheet
Dim WsBis As Worksheet
Dim DerLigRef As Long, DerLigBis As Long
Dim PlageRef As Range, PlageBis As Range, Cel As Range, C As Range
    Set WsRef = Worksheets("Feuil2")
    Set WsBis = Worksheets("Feuil1")
    DerLigRef = WsRef.Range("A" & WsRef.Rows.Count).End(xlUp).Row
    DerLigBis = WsBis.Range("A" & WsBis.Rows.Count).End(xlUp).Row
    Set PlageRef = WsRef.Range("A2:A" & DerLigRef)
    Set PlageBis = WsBis.Range("A2:A" & DerLigBis)
    For Each Cel In PlageBis
        Set C = PlageRef.Find(Cel)
        'Si l'ID correspondant est trouvé, on complète la ligne de référence
        If Not C Is Nothing Then
            WsBis.Range(Cel.Offset(0, 3), Cel.Offset(0, 4)).Copy C.Offset(0, 3)
            WsRef.Range(C.Offset(0, 3), C.Offset(0, 4)).Font.ColorIndex = 3
        'sinon, on ajoute la ligne
        Else
            Cel.EntireRow.Copy WsRef.Range("A" & DerLigRef + 1)
            WsRef.Range("A" & DerLigRef + 1).EntireRow.Font.ColorIndex = 3
            DerLigRef = DerLigRef + 1
        End If
    Next Cel
End Sub

Cordialement.

[gege765]

Bonsoir gFZT82,

J'ai testé ta macro sur un exemple avec plus de données.

J'ai réussi à comprendre ta macro et je l'ai modifier afin d'ajouter des champs.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 WsBis.Range(Cel.Offset(0, 3), Cel.Offset(0, 6)).Copy C.Offset(0, 3)
            WsRef.Range(C.Offset(0, 3), C.Offset(0, 6)).Font.ColorIndex = 3

Elle fonctionne parfaitement, c'est super merci.

Par contre j'ai du modifier la structure des colonnes afin de grouper toute la plage à copier.

Afin d'éviter de modifier la structure des colonnes est-il possible de renseigner deux plages à copier par exemple les colonnes 3 - 4 et 7 - 8.

Merci de ton aide.

[gFZT82]

Bonjour,

Voici quelques explications complémentaires :

La clé est dans la colonne A.
La plage à copier est définie avec le décalage de position par rapport à cette clé.
Cel.Offset(0, 3) correspond à la cellule décalée de 0 ligne et 3 colonnes par rapport à la cellule Cel.
Range(Cel.Offset(0, 3), Cel.Offset(0, 6)) correspond à la plage qui inclut les 4 cellules décalées de 3, 4, 5 et 6 colonnes.

Quand tu écris
WsBis.Range(Cel.Offset(0, 3), Cel.Offset(0, 6)).Copy C.Offset(0, 3)Tu copies la plage qui inclut les 4 cellules décalées de 3, 4, 5 et 6 colonnes et tu colles cette plage à partir de la position décalée de 3 colonnes par rapport à la cellule C.

Exemple :
Cel -> A2 de Feuille Bis.
Cel.Offset(0, 3) -> D2 de Feuille Bis.
Range(Cel.Offset(0, 3), Cel.Offset(0, 6)) -> D2:G2 de Feuille Bis.
C -> A2 de Feuille de Reference.
WsBis.Range(Cel.Offset(0, 3), Cel.Offset(0, 6)).Copy C.Offset(0, 3) -> copie de D2:G2 de Feuille Bis dans D2:G2 de Feuille de Reference.

Pour copier les colonnes 3-4 et 7-8, tu dois écrire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
WsBis.Range(Cel.Offset(0, 2), Cel.Offset(0, 3)).Copy <Destination>
WsBis.Range(Cel.Offset(0, 6), Cel.Offset(0, 7)).Copy <Destination>

Cordialement.

[gege765]

Bonjour,

Merci de tes explications complémentaires.
J'avais réussi à comprendre ce principe.

La clé est dans la colonne A.
La plage à copier est définie avec le décalage de position par rapport à cette clé.
Cel.Offset(0, 3) correspond à la cellule décalée de 0 ligne et 3 colonnes par rapport à la cellule Cel.
Range(Cel.Offset(0, 3), Cel.Offset(0, 6)) correspond à la plage qui inclut les 4 cellules décalées de 3, 4, 5 et 6 colonnes.

Quand tu écris
WsBis.Range(Cel.Offset(0, 3), Cel.Offset(0, 6)).Copy C.Offset(0, 3)
Tu copies la plage qui inclut les 4 cellules décalées de 3, 4, 5 et 6 colonnes et tu colles cette plage à partir de la position décalée de 3 colonnes par rapport à la cellule C.

Le fait d'ajouter une ligne pour la deuxième plage m'a échappé...

Bon dimanche.