Discussion :

[lexus92]

Bonjour à tous,

Je souhaites copier coller une colonne avant de la modifier. Je m'explique, si j'ai A1= 10, ce que j'aimerais, c'est que si je modifie A1=15, par exemple, la valeur 10 se copie dans une colonne. Puis si je modifie à nouveau A1=20, la valeur 15 se copiera dans une colonne et la valeur 10 se supprimera.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Application.Intersect(Target, Range("A1:A30")) Is Nothing Then
Range("A1:A30").Select
Selection.Copy
Range("D1").Select
ActiveSheet.Paste
 
End If
 
End Sub

J'ai fait la macro suivante. Le problème, c'est que lorsque je rentre une valeur dans A, il la recopie dans D. Hors j'aimerais que la colonne D soit l'ancienne valeur de la colonne A.

Merci d'avance

Cordialement,

Alexandre

[Theze]

Bonjour,

Regarde si ça convient :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Public Valeur
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
    If Not Application.Intersect(Target, Range("A1:A30")) Is Nothing Then
 
        'à la 1ère entrée en colonne A rien ne sera inscrit en colonne D
        'à voir sur l'évènement "Workbook_Open" pour récupérer les valeurs
        'et les stocker dans la variable (probablement qu'un tableau sera nécessaire) ???
        Target.Offset(0, 3) = Valeur
        Valeur = Target
 
    End If
 
End Sub

Hervé.

[lexus92]

Bonjour,

Tout d'abord merci. C'est presque ça. Quand j'applique la macro, le résultat est le suivant:

Colonne A Colonne D

1 5
2 1
3 2
4 3
5 4

Ce que je souhaiterais, c'est que premiere phase:

Colonne A Colonne D

1 0
2 0
3 0
4 0
5 0

Puis, je décide de modifier certaines valeurs (ou toutes)

Colonne A Colonne D

12 1
14 2
3 0
21 4
5 0

Il faut que quand je modifie une valeur, la nouvelle valeur v s'inscrive dans la colonne A (normal), et que la valeur V n-1 (valeur précedente) s'incrive dans D.

C'est pas évident à expliquer, je sais

[fring]

Bonjour,

Essaie ceci :

Code à insérer dans le module de la feuille :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Dim vVal As Variant
 
Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Application.Intersect(Target, Range("A1:A30")) Is Nothing Then
        Target.Offset(0, 3) = vVal
    End If
End Sub
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not Application.Intersect(Target, Range("A1:A30")) Is Nothing Then
        vVal = Target.Value
    End If
End Sub

[lexus92]

Merci beaucoup, c'est excatement ce que je voulais

Bon week end,

Cordialement,

[lexus92]

Bonjour Fring, le forum,

Une fois de plus, merci pour la solution que tu m'as apporté vendredi. Elle marche très bien. Je me demandais simplement. La macro ne marche que si je modifie directement la celulle. Hors ma celulle A1 est une somme de 2 celulles. Si je modifie B1, C1, la macro ne fonctionne pas.

J'ai essayé de bidouiller le code avec Private Sub Worksheet_Calculate(), mais je n'ai pas du bien m'y prendre.

Merci d'avance,

Cordialement,

Alexandre

[fring]

Si je comprend bien, la colonne A est le résultat des colonnes B et C. Dans ce cas, plutôt que de vérifier un changement sur la plage A1 à A30, vérifie si il y a un changement sur la plage B1 à C30

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Dim vVal As Variant
 
Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Application.Intersect(Target, Range("B1:C30")) Is Nothing Then
        Cells(Target.Row, 4) = vVal
    End If
End Sub
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not Application.Intersect(Target, Range("B1:C30")) Is Nothing Then
        vVal = Cells(Target.Row, 1)
    End If
End Sub

[lexus92]

Merci,

C'est beaucoup plus simple que ma solution qui était plus compliquée, et très énervante. Une fois de plus merci pour ton aide.

Cordialement,

Alexandre

Re Bonjour,

La macro marche parfaitement, j'essaye de l'adapter par rapport à mon fichier original, et je suis face à un problème. J'ai d'abord pensé que j'avais mal adapter la macro, mais elle marche dans mon fichier test. Le problème, c'est que c'est que les celulles contiennent une formule. Pour éclaircir:

Y1=Somme(Z1;AB1): dans mon fichier test, ça marche en réadaptant le code.
Z1= un nombre + une celulle dans une autre feuille
AA1 et AB1 = formule décaler par rapport à une autre feuille.

Je pensais que la macro allait marcher sans problème, mais apparement non.

Merci d'avance pour l'aide apportée

Cordialement,

Alexandre

[fring]

Effectivement avec des cellules contenant des formules faisant référence à d'autres feuilles cela devient compliqué à utiliser l’évènement Worksheet_Change.

Teste ceci en adaptant le nombre de ligne et le nom de la feuille. L'idée est de mémoriser les valeurs de la colonne A dans une "Collection" et de comparer ces valeurs suivant l'évènement Worksheet_Calculate.
(après avoir insérer les codes, il faut fermer et ré-ouvrir le classeur pour initialiser la Collection)

• Code à insérer dans un module standard
  

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  1
  2
  3
  4
  5
  6
  7
  8
  9
  10
  11
  12
  13
  14
  15
  16
  17
  Dim Col As Collection, i As Integer
   
  Sub Col_Init()
      Set Col = New Collection
      For i = 1 To 5 '<-- adapter le nombre de lignes
          Col.Add Sheets("Feuil1").Cells(i, 1).Value '<-- adapter le nom de la feuille
      Next
  End Sub
   
  Sub Col_Verif()
      For i = 1 To 5 '<-- adapter le nombre de lignes
          With Sheets("Feuil1") '<-- adapter le nom de la feuille
              If .Cells(i, 1) <> Col(i) Then .Cells(i, 4) = Col(i)
          End With
      Next
      Col_Init
  End Sub

• Code à insérer dans le module de la feuille en question
  

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  1
  2
  3
  Private Sub Worksheet_Calculate()
      Col_Verif
  End Sub

• Code à insérer dans le module ThisWorkbook
  

  Code :

  Sélectionner tout - Visualiser dans une fenêtre à part

  1
  2
  3
  Private Sub Workbook_Open()
      Col_Init
  End Sub

[lexus92]

Merci énormément. La macro met un certain temps à se charger, puisque j'ai deux autres macros qui se chargent avant mais je vais maintenant pouvoir nettoyer, et arranger mon fichier.

En tout cas, une fois de plus merci.

Cordialement,

Alexandre