VBA - Télécharger deux fichier excel depuis yahoo finance

**larson101** · 30/04/2011, 18h27

Bonjour,

Dans le cadre de mes cours, je dois réaliser un projet en VBA en finance risk management. Mon problème est le suivant:

J'aimerais pouvoir télécharger deux fichier depuis Yahoo finance sans qu'excel me dise qu'il y a un problème.

Voici mon code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub polet()
 
    Workbooks.Open Filename:= _
        "http://ichart.finance.yahoo.com/table.csv?s=UBSN.VX&d=3&e=28&f=2011&g=d&a=6&b=10&c=2006&ignore=.csv"
    ActiveWindow.Visible = False
    Windows("table.csv").Visible = True
 
Workbooks.Open Filename:= _
        "http://ichart.finance.yahoo.com/table.csv?s=%5ESSMI&d=3&e=30&f=2011&g=d&a=10&b=9&c=1990&ignore=.csv"
    ActiveWindow.Visible = False
    Windows("table.csv").Visible = True
 
    End Sub

Dès lors, pouvez-vous me dire quel code dois-je utiliser pour qu'Excel accepte que je télécharge deux fichier en même temps ??????

Je vous remercie, d'avance, de votre réponse

Larson

**kiki29** · 30/04/2011, 22h29

Salut,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Option Explicit
 
Sub Tst()
 
    Application.ScreenUpdating = False
    Workbooks.Open Filename:= _
                   "http://ichart.finance.yahoo.com/table.csv?s=UBSN.VX&d=3&e=28&f=2011&g=d&a=6&b=10&c=2006&ignore=.csv"
 
    Application.DisplayAlerts = False
    ActiveWorkbook.SaveAs Filename:=ThisWorkbook.Path & "\" & "Fichier1.csv", FileFormat:=xlCSV, Local:=True
    ActiveWindow.Close
 
    Windows("Classeur1.xls").Activate
    Workbooks.Open Filename:= _
                   "http://ichart.finance.yahoo.com/table.csv?s=%5ESSMI&d=3&e=30&f=2011&g=d&a=10&b=9&c=1990&ignore=.csv"
    ActiveWorkbook.SaveAs Filename:=ThisWorkbook.Path & "\" & "Fichier2.csv", FileFormat:=xlCSV, Local:=True
    ActiveWindow.Close
 
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
End Sub

**pgz** · 30/04/2011, 22h38

Bonsoir.

Le pb vient de ce que les classeurs chargés ont le même nom. Pour éviter cela, il faut enregistrer le premier sous un autre nom avant d'ouvrir le deuxième.

Si tu ne veux pas les enregistrer, alors il faut ruser et faire des copies dans des classeurs nouveaux, comme ceci, par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub polet()
 
Dim oWbk As Excel.Workbook
 
Set oWbk = Application.Workbooks.Open("http://ichart.finance.yahoo.com/table.csv?s=UBSN.VX&d=3&e=28&f=2011&g=d&a=6&b=10&c=2006&ignore=.csv")
oWbk.Worksheets(1).Copy
oWbk.Close False
 
Set oWbk = Application.Workbooks.Open("http://ichart.finance.yahoo.com/table.csv?s=%5ESSMI&d=3&e=30&f=2011&g=d&a=10&b=9&c=1990&ignore=.csv")
oWbk.Worksheets(1).Copy
oWbk.Close False
 
Set oWbk = Nothing
End Sub

Tu auras 2 classeurs nouveaux nommés "ClasseurN" et ClasseurN+1" et non enregistrés.

Cordialement,

PGZ

**larson101** · 01/05/2011, 15h49

Merci beaucoup de votre aide!!!

Savez-vous s'il est possible de réunir sur une même page les données du SMI et du titre UBS ? Si oui comment ?

En effet, lorsque je fais ce que vous m'indiquer, j'ai deux fenêtres qui s'ouvrent. Il faudrait que les données du titre UBS soit dans le "classeur deux" et que les données du SMI se trouve aussi dans le "calsseur 2" (même onglet), par exemple de les copier à partir de la cellue H1! (Sans oublier de fermer le classeur 3). En fait, j'ai besoin de cela car je dois ensuite comparer les données du SMI et du titre UBS avec des dates identiques.

Je profite pour vous demander une autre question:

Il faudrait que les dates du titre UBS correspondent aux dates du SMI. Comme nous pouvons le voir dans le "classeur 3" les données du SMI sont depuis 1990, alors que les données du titre UBS sont depuis 2006. Donc je voudrais supprimer toutes les dates du SMI (en l'occurence toute la ligne qui se réfère à la date, soit les données suivantes du SMI: Open, High, Low, Close, Volume, Adj Close) qui ne correspondent pas aux dates du titre UBS.

Par exemple dans le classeur 2, il est noté 28.04.2011 dans la cellule A2, donc j'aimerai que dans la cellule H2 il y ait la date du 28.04.2011 mais avec les données du SMI (H2 = date, I2= open, J2=High, K2=low etc). Bref, je ne peux pas avoir dans la cellule A3 la date du 27.04.2011 et dans la cellule H3 la date du 28.04.2011. Tout doit correspondre. (l’exemple que je prends est valable pour autant que nous pouvons coller les données du SMI à partir de la cellule H2)

Je m’excuse encore pour toutes ces questions mais cela me rendrait un grand service si vous pouviez m’indiquer le code que je devrais écrire dans l’interface de VBA. Ensuite, je pourrais me débrouiller tout seul pour la suite de mon travail. Merci d’avance.

Meilleures salutations

**pgz** · 01/05/2011, 20h40

Bonsoir.

C'est une nouvelle question.
En plus c'est compliqué, car entre les 2 tableaux de données, il n'y a pas un simple décalage, ce serait trop simple. EN fait les dates de cotations ne sont pas les mêmes.
Ce que je te propose c'est de charger chaque classeur de données dans une variable tableau, v1 et v2; et de construire un tableau de synthèse vT.

Il reste à copier vT quelque part. J'ai choisi une feuille "Tables" que j'ajoute au classeur qui contient le code, mais cela peut être n'importe où.

J'ai laissé la colonne H vide pour séparer les deux valeurs.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
Sub poletII()
 
Dim oWbk As Excel.Workbook
Dim v1 As Variant, v2 As Variant, vT As Variant '1 = valeur 1; 2 = valeur2; T = les 2 valeurs
Dim i1 As Long, i2 As Long, iT As Long, j As Integer
Dim oSh As Excel.Worksheet, oRng As Excel.Range
 
Set oWbk = Application.Workbooks.Open("http://ichart.finance.yahoo.com/table.csv?s=UBSN.VX&d=3&e=28&f=2011&g=d&a=6&b=10&c=2006&ignore=.csv")
v1 = oWbk.Worksheets(1).UsedRange.Value
oWbk.Close False
 
Set oWbk = Application.Workbooks.Open("http://ichart.finance.yahoo.com/table.csv?s=%5ESSMI&d=3&e=30&f=2011&g=d&a=10&b=9&c=1990&ignore=.csv")
v2 = oWbk.Worksheets(1).UsedRange.Value
oWbk.Close False
 
'ajoute une feuille en dernier
ThisWorkbook.Worksheets.Add , ThisWorkbook.Worksheets(ThisWorkbook.Worksheets.Count)
Set oSh = ActiveSheet
oSh.Name = "Tables"
Set oRng = oSh.Range("A1:N" & UBound(v1, 1) + UBound(v2, 1) - 1)
vT = oRng.Value
 
'renseigner la ligne des titres
vT(1, 1) = v1(1, 1)
For j = 1 To 6
    vT(1, j + 1) = v1(1, j + 1)
    vT(1, j + 8) = v1(1, j + 1)
Next j
 
i1 = 2
i2 = 2
iT = 2
 
While (i1 <= UBound(v1, 1)) Or (i2 <= UBound(v2, 1))
 
    'date : vt = sup(v1,v2)
    If i1 <= UBound(v1, 1) Then
        vT(iT, 1) = v1(i1, 1)
        If i2 <= UBound(v2, 1) Then
            If vT(iT, 1) < v2(i2, 1) Then vT(iT, 1) = v2(i2, 1)
        End If
    Else
        vT(iT, 1) = v2(i2, 1)
    End If
 
    'écriture v1
    If i1 <= UBound(v1, 1) Then
        'si date(v1) = date(vT)
        If v1(i1, 1) = vT(iT, 1) Then
            For j = 1 To 6
                vT(iT, j + 1) = v1(i1, j + 1)
            Next j
            i1 = i1 + 1
        End If
    End If
 
    'écriture v2
    If i2 <= UBound(v2, 1) Then
        'si date(v2) = date(vT)
        If v2(i2, 1) = vT(iT, 1) Then
            For j = 1 To 6
                vT(iT, j + 8) = v2(i2, j + 1)
            Next j
            i2 = i2 + 1
        End If
    End If
 
    iT = iT + 1
 
Wend
 
oRng.Value = vT
Set oRng = Nothing
Set oSh = Nothing
Set oWbk = Nothing
v1 = Empty
v2 = Empty
vT = Empty
 
End Sub

Cordialement,

PGZ

**larson101** · 01/05/2011, 22h18

Merci beaucoup pour votre message et le temps que vous y avez consacré.

Je voulais juste savoir si vous pouviez tout de même laisser les dates correspondant au SMI dans la colonne H, ce serait juste une preuve pour vérification....

De plus, serait-il possible de supprimer les lignes où il n'y a pas de données pour le titre UBS. Par exemple, j'aimerais supprimer la ligne 2, 6, 86, 91 etc... En effet, à la ligne 6, date du 25.04.2011, il n'y a pas de données pour le titre UBS, donc je voulais savoir, si on pouvait supprimer toute la ligne afin que ça efface également les données du SMI.

Si cela fonctionne, il ne devrait plus y avoir de dates qui s'insrivent après le 10.07.2006 et donc plus de données dans la zone: I1226 à N5164.

Si ce n'est pas possible, je vous remercie déjà mille fois pour votre aide...

Meilleures salutations

**pgz** · 01/05/2011, 23h05

Bonsoir.

Je n'avais pas compris. Au temps pour moi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
Sub poletIII()
 
Dim oWbk As Excel.Workbook
Dim v1 As Variant, v2 As Variant, vT As Variant '1 = valeur 1; 2 = valeur2; T = les 2 valeurs
Dim i1 As Long, i2 As Long, iT As Long, j As Integer
Dim oSh As Excel.Worksheet, oRng As Excel.Range
 
Set oWbk = Application.Workbooks.Open("http://ichart.finance.yahoo.com/table.csv?s=UBSN.VX&d=3&e=28&f=2011&g=d&a=6&b=10&c=2006&ignore=.csv")
v1 = oWbk.Worksheets(1).UsedRange.Value
oWbk.Close False
 
Set oWbk = Application.Workbooks.Open("http://ichart.finance.yahoo.com/table.csv?s=%5ESSMI&d=3&e=30&f=2011&g=d&a=10&b=9&c=1990&ignore=.csv")
v2 = oWbk.Worksheets(1).UsedRange.Value
oWbk.Close False
 
'ajoute une feuille en dernier
ThisWorkbook.Worksheets.Add , ThisWorkbook.Worksheets(ThisWorkbook.Worksheets.Count)
Set oSh = ActiveSheet
oSh.Name = "Tables"
Set oRng = oSh.Range("A1:O" & UBound(v1, 1) + UBound(v2, 1) - 1)
vT = oRng.Value
 
'renseigner la ligne des titres
For j = 1 To 7
    vT(1, j) = v1(1, j)
    vT(1, j + 8) = v2(1, j)
Next j
 
i1 = 2
i2 = 2
iT = 2
 
While (i1 <= UBound(v1, 1)) And (i2 <= UBound(v2, 1))
 
    'synchroniser v1 et v2
    While v1(i1, 1) <> v2(i2, 1)
        If v1(i1, 1) > v2(i2, 1) Then
            i1 = i1 + 1
        Else
            i2 = i2 + 1
        End If
    Wend
 
    'écriture v1 et v2
    For j = 1 To 7
        vT(iT, j) = v1(i1, j)
        vT(iT, j + 8) = v2(i2, j)
    Next j
 
    i1 = i1 + 1
    i2 = i2 + 1
    iT = iT + 1
 
Wend
 
oRng.Value = vT
Set oRng = Nothing
Set oSh = Nothing
Set oWbk = Nothing
v1 = Empty
v2 = Empty
vT = Empty
 
End Sub

En fait, le code est plus simple.

Cordialement,

PGZ

**larson101** · 02/05/2011, 09h52

Merci beaucoup, c'est exactement ce que je voulais...

Par contre, le problème c'est que ça fonctionne une seule fois. En fait, lorsque je réactive la macro: il me met: Erreur d'exécution "1004" - Erreur définie par l'application ou par l'objet. Donc c'est un peu problématique car chaque fois que je vais écrire un nouvau code, je dois fermer le fichier excel et recommencer à 0 afin de voir si ce que j'ai rajouté est correct ou pas.Y-a-t-il un moyen pour résoudre cela? Il faudrait que chaque fois que je réactive ma macro, la feuille "table" où se trouve les données téléchargées s'efface et retélécharge à nouveau les nouvelles données sur le fichier tables....

Avez-vous une idée comment résolver ce problème ?

Une toute dernière question, savez-vous s'il y a un code qui permet d'afficher un message d'erreur dans le cas où les deux fichiers n'ont pas pu être téléchargés. Par exemple, dans le cas où la personne n'a pas pu se connecter à internet....

Merci d'avance

Meilleures salutations

**pgz** · 02/05/2011, 11h57

Bonjour.

Ce sont des aménagements mineurs. On peut, par exemple, faire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
Option Explicit
 
Sub poletIV()
 
Dim oWbk As Excel.Workbook
Dim v1 As Variant, v2 As Variant, vT As Variant '1 = valeur 1; 2 = valeur2; T = les 2 valeurs
Dim i1 As Long, i2 As Long, iT As Long, j As Integer
Dim oSh As Excel.Worksheet, oRng As Excel.Range
Const csSheetName As String = "Tables"
 
On Error GoTo lblErreur1
    Set oWbk = Application.Workbooks.Open("http://ichart.finance.yahoo.com/table.csv?s=UBSN.VX&d=3&e=28&f=2011&g=d&a=6&b=10&c=2006&ignore=.csv")
On Error GoTo 0
v1 = oWbk.Worksheets(1).UsedRange.Value
oWbk.Close False
 
On Error GoTo lblErreur2
    Set oWbk = Application.Workbooks.Open("http://ichart.finance.yahoo.com/table.csv?s=%5ESSMI&d=3&e=30&f=2011&g=d&a=10&b=9&c=1990&ignore=.csv")
On Error GoTo 0
v2 = oWbk.Worksheets(1).UsedRange.Value
oWbk.Close False
 
's'assurer d'une feuille "Tables"
On Error Resume Next
    Set oSh = ThisWorkbook.Worksheets(csSheetName)
On Error GoTo 0
If oSh Is Nothing Then
    ThisWorkbook.Worksheets.Add , ThisWorkbook.Worksheets(ThisWorkbook.Worksheets.Count)
    Set oSh = ActiveSheet
    oSh.Name = csSheetName
Else
    oSh.UsedRange.Delete
End If
 
Set oRng = oSh.Range("A1:O" & UBound(v1, 1) + UBound(v2, 1) - 1)
vT = oRng.Value
 
'renseigner la ligne des titres
For j = 1 To 7
    vT(1, j) = v1(1, j)
    vT(1, j + 8) = v2(1, j)
Next j
 
i1 = 2
i2 = 2
iT = 2
 
While (i1 <= UBound(v1, 1)) And (i2 <= UBound(v2, 1))
 
    'synchroniser v1 et v2
    While v1(i1, 1) <> v2(i2, 1)
        If v1(i1, 1) > v2(i2, 1) Then
            i1 = i1 + 1
        Else
            i2 = i2 + 1
        End If
    Wend
 
    'écriture v1 et v2
    For j = 1 To 7
        vT(iT, j) = v1(i1, j)
        vT(iT, j + 8) = v2(i2, j)
    Next j
 
    i1 = i1 + 1
    i2 = i2 + 1
    iT = iT + 1
 
Wend
 
oRng.Value = vT
 
lblSortie:
    Set oRng = Nothing
    Set oSh = Nothing
    Set oWbk = Nothing
    v1 = Empty
    v2 = Empty
    vT = Empty
    Exit Sub
 
lblErreur1:
    MsgBox "Une erreur s'est produite lors du premier chargement. Abandon."
    GoTo lblSortie
 
lblErreur2:
    MsgBox "Une erreur s'est produite lors du deuxième chargement. Abandon."
    GoTo lblSortie
 
End Sub

Si cela répond à la question, pense à taguer

Cordialement,

PGZ

**larson101** · 02/05/2011, 14h43

Oui c'est parfait, je vais taguer cette discussion tout de suite.

En tout cas un grand MERCI pour votre précieuse aide...

Meilleures salutations

VBA - Télécharger deux fichier excel depuis yahoo finance [XL-2010]

Macros et VBA Excel

Discussions similaires

Partager

Partager