Discussion :

[demouret]

Bonjour le forum

J'ai trouvé un bout de code que je voudrai personnaliser
Je m explique :

Lorsque je suis sur Outlook avec un rendez vous ouvert à l'ecran je voudrai creer une macro qui m ouvre un classeur excel et me copie les infos du RV sur une feuille excel

jusqu' a l ouverture de mon fichier excel ca fonctionne mais aprés je n'arrive pas a copier les données de mon rendez-vous selectionné vers ma feuille excel

voici le bout de code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub openex()
 
Dim appXl As Excel.Application
Dim Wb As Excel.Workbook
Set appXl = CreateObject("Excel.Application")
appXl.Visible = True
Set Wb = appXl.Workbooks.Open("C:\Users\Pierre\Documents\te st.xlsx")
 
Sheets("feuil1").Range("A1") = Subject
Sheets("feuil1").Range("A2") = Location
 
 
End Sub

Si une bonne ame pouvait donner un petit coup de main

Merci à vous

[Maxence HUBICHE]

Hello !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Sheets("feuil1").Range("A1") = ThisOutlookSession.ActiveInspector.CurrentItem.Subject
Sheets("feuil1").Range("A2") = ThisOutlookSession.ActiveInspector.CurrentItem.Location

[demouret]

Maxence je te remercie du fond du coeur
Tu peux pas savoir à quel point je suis content de ce morceau de code
Merci beaucoup !!!

[Maxence HUBICHE]

Ca me fait plaisir d'avoir pu t'aider

[demouret]

Pardonne moi mais c'est rigolo ca ne fonctionne qu'une fois sur deux !!??

en fait une fois sur deux j'ai la fenetre de deboguage qui s'ouvre et le message suivant :

"erreur d execution 1004
la methode charts de l objet global a echoue"

si je clique sur fin et que je relance la macro ca fonctionne impec

Même en l'état je suis prenneur mais si ca fonctionnait à 100 % ce serait... mieux... ;-)

Merci

[carden752]

Bonjour,

Peut être une mauvaise réinitialisation des paramètres.

A mettre peut-être dans la méthode before_close du workbook d'Excel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
Set Wb = Nothing
Set appXl=Nothing

[demouret]

Oui je pense aussi a un problème de ce genre..

ca ne change malheureusement rien avec cette insersion dans le before_close

je continu a chercher

[Maxence HUBICHE]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Dim appXl As Excel.Application
Dim Wb As Excel.Workbook
Set appXl = CreateObject("Excel.Application")
appXl.Visible = True
Set Wb = appXl.Workbooks.Open("C:\Users\Pierre\Documents\te st.xlsx")

Sheets("feuil1").Range("A1") = Subject
Sheets("feuil1").Range("A2") = Location
 

wb.save
wb.close
set wb=nothing
appXL.quit
set appXL = nothing

[demouret]

ca fait pareil ... 1 fois sur deux
comprends pas pourquoi C'est enervant hein ;-)

[Maxence HUBICHE]

"erreur d execution 1004
la methode charts de l objet global a echoue"

Tu n'aurais pas une macro dans ton classeur par hasard

[demouret]

non je viens de verifier
j'ai meme pris un nouveau classeur pour etre sure
Mais ca fait pareil
Pour le coup avec ton dernier code 1 fois sur deux le classeur reste ouvert et j ai le message d'erreur. ce qui est drole c'est que si je clique sur "fin" et que je relance la macro ca marche...

[Maxence HUBICHE]

Ce qui est étonnant, c'est qu'il te parle de méthode Charts...
Or, nous n'en utilisons pas.

Essaie de faire du pas-à-pas détaillé (F8) pour voir à quel moment ça buggue !

[demouret]

Un collegue excellisite m a fait remarqué que l'on ne précisais pas que feuil1 appartient à Wb

Il m'a proposé cette modification et ca à l air de marcher nickel

En tout cas merci à toi Maxence et à Carden

je suis très content de ce petit bout de code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub openexcel()
 
Dim appXl As Excel.Application
Dim Wb As Excel.Workbook
Set appXl = CreateObject("Excel.Application")
appXl.Visible = True
Set Wb = appXl.Workbooks.Open("C:\Documents and Settings\Administrateur\Mes documents\test.xls")
 
With ThisOutlookSession.ActiveInspector.CurrentItem
Wb.Sheets("feuil1").Range("A1") = .Subject
Wb.Sheets("feuil1").Range("A2") = .Location
Wb.Sheets("feuil1").Range("A3") = .Body
Wb.Sheets("feuil1").Range("A4") = .Start
End With
 
 
Wb.Save
Wb.Close
Set Wb = Nothing
appXl.Quit
Set appXl = Nothing
End Sub

[Maxence HUBICHE]

Exact !
Comme quoi, des fois, on passe VRAIMENT à côté de l'essentiel !