Discussion :

[estebandelago]

Bonjour,

Je me suis appuyé sur la faq access "Ajout de rendez-vous dans Microsoft Outlook à l'aide d'Automation" pour créer la fonction correspondante.

Le problème est que je ne connais pas le vocabulaire pour ajouter un ou plusieurs destinataires (ou participants), du coup, le rendez-vous s'ajoute sur mon calendrier.

Voilà, la syntaxe:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
 
Set olApp = CreateObject("Outlook.Application")
Set ai = olApp.CreateItem(olAppointmentItem)
With ai
    .Subject = strSujet
    .Body = strCorps
    .Start = dteDebut
    .Save
    'dans l'idée cela devrait ressembler à cela non? 
    .recipients.add("john doe") 
End With

Ma question est donc: Comment faire pour ajouter des destinataires à un rendez-vous via vba?

Merci et bonne journée
Esteban

[Maxence HUBICHE]

Je ne comprends pas le sens de ta question.

Ca ne te va pas Recipients.add ?

[estebandelago]

Hello,

le problème est que cette syntaxe ne doit pas être la bonne puisque le rendez-vous ne s'ajoute pas dans le calendrier de la personne.

Si cette syntaxe est la bonne:
que doit-on mettre au niveau du nom?
Prénom Nom
nom du compte de la personne
ou
l'adresse email interne de la personne

[Maxence HUBICHE]

mais... est-ce que tu le lui 'envoies' (send) ou est-ce que tu te contente de l'enregistrer ???

[estebandelago]

je l'enregistre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ai.save

Serait-ce le début d'une piste?

[estebandelago]

Hello,

la bonne syntaxe est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.RequiredAttendees = "john doe"

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 Dim oRecipt As Outlook.Recipient
Set oRecipt = .Recipients.Add("john doe")
oRecipt.Type = olTo 
...
.send

Cette fonction envoie un rendez-vous à la personne requise, libre à elle de l'accepter ou non et inscrit le rendez-vous dans le calendrier de celui qui envoie (= organisateur)
J'ai 2 problèmes:
- comment faire pour inscrire le rendez-vous directement dans le calendrier de la personne
- comment faire pour que l'organisateur n'est pas de rendez-vous inscrit dans son calendrier?

Qu'en pensez-vous?
Esteban

[estebandelago]

re-hello,

exchange est la solution...

voici une fonction qui permet d'écrire le rendez-vous dans le calendrier d'une autre personne sans pour autant écrire dans le calendrier local

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
 
Function AjoutRendezVousAutreCalendrier(ByVal strSujet As String, ByVal strCorps As String, ByVal dteDebut As Date, ByVal dteFin As Date) As Boolean
 
    Dim objApp As Outlook.Application
    Dim objNS As Outlook.Namespace
    Dim objRecip As Outlook.Recipient
    Dim objFolder As Outlook.MAPIFolder
    Dim objAppt As Outlook.AppointmentItem
 
    Dim strName As String
    Dim blnRdvCree As Boolean
 
    blnRdvCree = False
 
    strName = "john.doe"
 
    Set objApp = CreateObject("Outlook.Application")
    Set objNS = objApp.GetNamespace("MAPI")
    Set objRecip = objNS.CreateRecipient(strName)
    objRecip.Resolve
 
    If objRecip.Resolved Then
     Set objFolder = objNS.GetSharedDefaultFolder(objRecip, olFolderCalendar)
      If Not objFolder Is Nothing Then
       Set objAppt = objFolder.Items.Add
        If Not objAppt Is Nothing Then
          With objAppt
           .Subject = strSujet
           .Body = strCorps
           .Start = dteDebut
           .AllDayEvent = True
           .Save
           End With
          blnRdvCree = True
        End If
      End If
    Else
     blnRdvCree = False
    End If
 
    AjoutRendezVousAutreCalendrier = blnRdvCree
 
    Set objApp = Nothing
    Set objNS = Nothing
    Set objRecip = Nothing
    Set objFolder = Nothing
    Set objAppt = Nothing
End Function

Il me reste encore un souci... Comment ajouter des participants obligatoires et/ou facultatifs...