Initialisation objet checkbox ActiveX Word.

**flav_cm** · 18/04/2016, 17h19

Bonjour,

Je dispose de plusieurs dizaines de CheckBox ActiveX dans un document Word et je souhaite cocher certaines de ces cases depuis une procédure VBA executée depuis excel.

Pour tester, les quelques lignes de codes exécutées dans un module Excel fonctionnent parfaitement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
For i = 1 To 5
   If tab_bruit(1, i) Then
      wordDoc.CB_Infr_rout.Value = True
      If i = 1 Then wordDoc.CB_Cat1.Value = True
      If i = 2 Then wordDoc.CB_Cat2.Value = True
      If i = 3 Then wordDoc.CB_Cat3.Value = True
      If i = 4 Then wordDoc.CB_Cat4.Value = True
      If i = 5 Then wordDoc.CB_Cat5.Value = True
   End If
Next i

Ayant pas mal d'éléments, je souhaiterais pouvoir initialiser un objet d'après le nom de la variable. Malgré pas mal de recherche je ne trouve pas de solution. Dans l'idéal, ça pourrait ressembler à ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
For i = 1 To 5
   If tab_bruit(1, i) Then
      wordDoc.CB_Infr_rout.Value = True
 
      Set chBx = checkbox("CB_Cat" & i) ' ???
      wordDoc.chBx.Value = True
 
   End If
Next i

J'ai déjà cherché du côté de word avec une solution de ce type (qui ne marche pas lorsque l'appel se fait depuis Excel...) :

APPEL DE LA FONCTION :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
For i = 1 To 5
   If tab_bruit(1, i) Then
      wordDoc.CB_Infr_rout.Value = True
      Set obj = getControl("CB_cat" & i, wordDoc)
      If Not obj Is Nothing Then
         obj.Object.Value = True
      End If
   End If
Next i

FONCTION :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function getControl(name As String, doc As Document) As OLEFormat
 
    Dim ish As InlineShape
 
    For Each ish In doc.InlineShapes
        If ish.Type = wdInlineShapeOLEControlObject Then
            If ish.OLEFormat.Object.name = name Then
                Set getControl = ish.OLEFormat
                Exit Function
            End If
        End If
    Next
 
    Set getControl = Nothing
 
End Function

"Erreur d’exécution 13 : incompatibilité de type" à la ligne 8...

En espérant avoir été clair, merci d'avance pour vos conseils.

**parmi** · 18/04/2016, 17h54

Bonjour,

Peut-être ainsi ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

wordDoc.Controls("CB_Cat" & i).Value = True

**flav_cm** · 19/04/2016, 09h00

Bonjour parmi et merci pour ta proposition.

Malheureusement, ça ne fonctionne pas : Erreur d'exécution 438 Propriété ou méthode non gérée par cet objet...

**parmi** · 19/04/2016, 12h04

Pas évident Word...
Tu peux peut-être te baser là-dessus (?)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
    For I = 1 To ActiveDocument.Fields.Count
'        MsgBox ThisDocument.Fields.Item(I).OLEFormat.Object.Name
        If I = 1 Then ThisDocument.Fields.Item(I).OLEFormat.Object.Value = True
        If I = 2 Then ThisDocument.Fields.Item(I).OLEFormat.Object.Value = False
    Next

**flav_cm** · 19/04/2016, 14h07

Envoyé par parmi

Pas évident Word...[/CODE]

En effet il n'est pas toujours facile de trouver comment lier Excel et Word alors même que les même manipulations seraient relativement faciles en restant sous la même application.

En essayant simplement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

wordDoc.Fields.Item(3).OLEFormat.Object.Value = True

Une "erreur d'exécution '91' Variable objet ou variable de bloc With non définie" apparaît...

Comment pourrais-je vérifier que la collection .Fields.Item comprend bien l'ensemble de mes checkbox ?

**cerede2000** · 19/04/2016, 14h15

Re !

Avec ma fonction (donné en section VBA Word et avec ta modif), essaye comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function getControl(name As String, doc As Document) As Variant
 
    Dim ish As InlineShape
 
    For Each ish In doc.InlineShapes
        If ish.Type = wdInlineShapeOLEControlObject Then
            If ish.OLEFormat.Object.name = name Then
                Set getControl = ish.OLEFormat
                Exit Function
            End If
        End If
    Next
 
    Set getControl = Nothing
 
End Function

**flav_cm** · 19/04/2016, 14h40

Génial cerede2000 merci pour cette solution efficace !

**flav_cm** · 19/04/2016, 17h10

Grace à ta fonction ci-dessus, je gère le cochage des checkbox dans mon programme principal de la façon suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
            For i = 1 To 8 ' on parcours les colonnes
                If tab_constats(1, i) Then
                    Set obj = getControl(tab_CB(1, i) & "_et1", wordDoc) ' OUI
                Else
                    Set obj = getControl(tab_CB(1, i) & "_et10", wordDoc) ' NON
                End If
                If Not obj Is Nothing Then
                    obj.Object.Value = True
                End If
                If tab_constats(2, i) <> "ERREUR" Then
                    Set obj = getControl(tab_CB(1, i) & "_et" & tab_constats(2, i), wordDoc)
                    If Not obj Is Nothing Then
                        obj.Object.Value = True
                    End If
                End If
                If tab_constats(3, i) Then
                    Set obj = getControl(tab_CB(1, i) & "_ch11", wordDoc) ' OUI
                Else
                    Set obj = getControl(tab_CB(1, i) & "_ch101", wordDoc) ' NON
                End If
                If Not obj Is Nothing Then
                    obj.Object.Value = True
                End If
                If tab_constats(4, i) <> "ERREUR" Then
                    Set obj = getControl(tab_CB(1, i) & "_ch" & tab_constats(4, i) & "1", wordDoc)
                    If Not obj Is Nothing Then
                        obj.Object.Value = True
                    End If
                End If
                If tab_constats(5, i) <> "ERREUR" Then
                    Set obj = getControl(tab_CB(1, i) & "_" & tab_constats(5, i), wordDoc)
                    If Not obj Is Nothing Then
                        obj.Object.Value = True
                    End If
                End If
            Next i

Cela fonctionne, mais est relativement long. Mon rapport s'édite en 185 secondes avec ce code, contre 15 secondes lorsque cette partie est commentée...

Pensez-vous qu'il serait possible d'optimiser ce temps de calcul d'une façon ou d'une autre ?

Merci d'avance !

**clementmarcotte** · 19/04/2016, 23h01

Bonjour,

Envoyé par flav_cm

Grace à ta fonction ci-dessous, je gère le cochage des checkbox dans mon programme principal de la façon suivante :

Pensez-vous qu'il serait possible d'optimiser ce temps de calcul d'une façon ou d'une autre ?

Merci d'avance???

En n'essayant pas de zigonner des contrôles activex de Word en partant d'Excel. OLE demande beaucoup de ressources et de mémoire.`

Je te dirais de regarder deux alternatives :

Un UserForm dans Excel qui permet de définir d'un seul coup les conditions à respecter dans le document Word et ne pas utiliser de ChexBoxes dans Word.

ou, si tu veux absolument des CheckBoxes dans Word

De te créer un modèle Word avec des macros.

et ensuite, tu insères ta fonction comme une nouvelle Sub dans ton modèle Word et tu te sers de ton objet Word.application, que tu ne peux pas éviter dans Excel de toutes façons, et de lui faire lancer par lui ta macro dans ton modèle Word.

**flav_cm** · 20/04/2016, 11h39

Bonjour clementmarcotte et merci pour tes remarques !

En exécutant ma fonction de recherche d'objet directement dans Word c'est extrêmement plus rapide, mon programme est maintenant à 23s contre 185 auparavant.

Merci beaucoup.

Initialisation objet checkbox ActiveX Word.

Macros et VBA Excel

Discussions similaires

Partager

Partager