Discussion :

[QuestVba]

Bonjour à tous,

Je suis à la recherche d'une formule. J'ai déjà tenté des trucs mais il y a un truc qui coince. Donc, je me tourne vers ma source de solutions inépuisable.

J'ai des données ainsi encodées dans une feuille :

Agent	Date	AM/PM	Lot	Actions
XX	15/10/2015	AM	1	Etiqueté
WW	15/10/2015	PM	6	Etiqueté
YY	15/10/2015	PM	2	Etiqueté
WW	23/10/2015	PM	11	Etiqueté
XX	23/10/2015	PM	12	Etiqueté
XX	15/10/2015	AM	3	Validé
XX	15/10/2015	AM	17	Validé
YY	15/10/2015	AM	18	Validé
XX	15/10/2015	AM	28	Validé
YY	15/11/2015	AM	19	Scanné
XX	15/11/2015	AM	10	Scanné
YY	15/11/2015	AM	16	Scanné

Mon but est de connaître le nombre de demi-journées différentes pour le mois d'octobre 2015 pour les actions 'étiqueté'. Dans l'exemple ce serait '3'. En effet, tous les étiquetages ont eu lieu :

• le 15/10/2015 AM (1x) > Compte pour 1
• le 15/10/2015 PM (2x) > Compte pour 1
• le 23/10/2015 PM (2x) > Compte pour 1

J'espère avoir été assez précis dans la demande. Merci pour vos pistes.

[BDA53]

Je te conseille de rajouter une colonne avec comme intitulé "Demi journée différente"
Cela te permettrait de faire le test sur chaque ligne. Cela donnerait ceci :
=SI(B2 <> B3 et C2 <>C3 ;"oui";"non")

Voilà déjà une possibilité, il y a peut-être plus simple.
Cordialement
xela57

[QuestVba]

Merci xela57.

C'est une solution mais, je préfère ne pas ajouter de colonnes étant donné que j'ai déjà beaucoup d'autres données.

[BDA53]

ou alors tu remplaces le contenu d'une de tes colonnes

[QuestVba]

moins facile à faire.

[rjamin]

Bonjour,
Une proposition
Le tableau placé en A1 en G2 la formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ET(E2="Etiqueté";SI(CONCATENER(B2;C2;E2)<>CONCATENER(B1;C1;E1);1;0));1;0)

En G1 =SOMME(G2:G13) donne 3

A vous de voir

[QuestVba]

Bien bien bien mais toujours une colonne supplémentaire.

Je cherche maintenant vers un SOMMEPROD sans doublon ou FREQUENCE. Mais je ne trouve toujours pas.

[Menhir]

Pour FREQUENCE, oublie. L'effet de cette fonction n'est pas du tout ce que tu recherches puisque, au contraire, elle cherche à grouper les éléments semblables.

[GerardCalc]

Bonjour,

Soit ton tableau en A1:E13 (avec des en-têtes en ligne 1 et donc le début des données en ligne 2) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(SI(E2:E13="Etiqueté";1/NB.SI.ENS(E2:E13;"Etiqueté";B2:B13&C2:C13;B2:B13&C2:C13)))

Matricielle à valider par Ctrl+Maj+Entrée.

A+

[QuestVba]

Bonjour, GerardCalc,

Il me donne une erreur quand je fais un bête copier-coller. J'investigue.

[LG-69]

Bonjour,

C'est la concaténation "à la volée" des 2 plages B2:B13 avec C2:C13 qui est en erreur le B2:B13&C2C13 ne fonctionne pas.
Comme ça je ne vois pas la solution, si je trouve je l'indiquerai.

[GerardCalc]

Il va donc falloir trouver autre chose. Dommage, cela fonctionnait très bien avec Calc.

[papouclo]

Bonjour,
Essayer la formule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(SI((MOIS($B$2:$B$13)=10)*($E$2:$E$13="Etiqueté");1/NB.SI.ENS($B$2:$B$13;$B$2:$B$13;$C$2:$C$13;$C$2:$C$13;$E$2:$E$13;"Etiqueté")))

à valider bien sûr avec Ctrl + Maj + Entrée
Cordialement
Claude

[GerardCalc]

Bonjour,
Essayer la formule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(SI((MOIS($B$2:$B$13)=10)*($E$2:$E$13="Etiqueté");1/NB.SI.ENS($B$2:$B$13;$B$2:$B$13;$C$2:$C$13;$C$2:$C$13;$E$2:$E$13;"Etiqueté")))

à valider bien sûr avec Ctrl + Maj + Entrée
Cordialement
Claude

Bien vu. Il suffisait de ne pas concaténer, j'ai voulu faire trop court.
J'avais zappé la condition sur le mois.
Mais cela ne va pas le faire, il faudrait aussi que le critère mois soit aussi inclus dans NB.SI.ENS...

[QuestVba]

Désolé pour le temps d'attente. Mais c'est parfait !

VIVA le Forum !