Discussion :

[Noizette]

Bonsoir,
J'ai besoin d'extraire un tableau de données formatées au milieau d'une page HTML, et de les copier dans un tableau Excel.
Le tableau a une structure complexe, avec des cellules fusionnées sur certaines lignes, ce qui se retrancrit proprement par un copier/coller manuel de la selection dans ma page web vers une feuille Excel.
Je veux automatiser le processus en VBA.
J'ai donc écrit le code qui récupère ma table HTML dans un objet vba de type HTMLTable, mais je n'arrive pas à l'intégrer dans mon fichier Excel ni par l'objet table ni par son code HTML.

Est-ce que quelqu'un connait un moyen de copier les données formattées sans connecter l'ensemble de la page à la feuille excel, et si possible sans passer par un fichier intermédiare ?

Merci d'avance pour vos pistes éclairées.

[Marc-L]

Bonjour,

le plus simple est encore depuis la feuille de calculs d'utiliser la fonction Nouvelle requête sur le Web et,
en activant le Générateur de macros, le code VBA est livré sur un plateau ! (Voir dans l'aide VBA l'objet QueryTable)

Sinon en cas d'échec, il y a deux méthodes pour lire un élément <Table> d'une page HTML,
la lecture cellule par cellule (exemple dans cette discussion)
ou la copie de la table dans le presse-papiers (effectuer une recherche dans ce forum sur clipboardData) …

__________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé puis sur pour clore cette discussion …

[Noizette]

Merci Marc-L.
Après avoir passé une partie de la nuit dernière à suivre ta saga sur le rafraichissement de données d'une page Web, je suis ravi que tu me donnes ces pistes.
J'avais commencé à chercher dans MSDN ce qu'était le query Table, mais j'ai pas encore testé, ca sera certainement plus rapide en le générant depuis excel.
J'ai le présentiment que le clipboarddata sera ma solution préférée.
Je vais explorer tout ça et reviendrai dans quelques jours pour conclure cette discussion.

[Noizette]

J'ai pris le temps de regarder les tois solutions proposées:
Le queryTable parrait vraiment très pratique selon les pages HTML, mais n'a pas fonctionné dans mon cas: Message d'erreur dans Excel « aucune données renvoyée par la requête sur le Web……. ». je ne l'ai donc développé en VBA.
La lecture cellule par cellule serait trop lourde à gérer dans mon cas: 1500 lignes de pouvant avoir différentes structures (cellules fusionnées différemment seln le contenu de la ligne).
Me restait donc de passer par le clipboard, qui s'est avéré très efficace: en passant le code html dans le presse-papier, puis le coller dans la première cellule de la feuille excel de destination, alors la table est bien rfecopiée en respectant son format html.

Merci Marc-L pour m'avoir exposé la palette de solution qui m'a permis de résoudre mon dossier.

ci dessous un extrait du code utilisé (qui necessite d'activer la référence "Microsft Forms 2.0 Object Library" que je suis allé chercher en faisant parcourir surla DLL "FM20.DLL")

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub test()
 
Dim WinShell As New ShellWindows
Dim IE As New InternetExplorer
Dim IEDoc As HTMLDocument
Dim TableHTML As HTMLTable
Dim NumTableHTML As Integer
 
'pour passer du texte dans le presse papier, activer Outils\References\Microsoft Forms 2.0  Object Library depuis FM20.DLL
Dim objData As New MSForms.DataObject
 
'comme mon code VBA est dans un module access, activer Outils\References\Microsoft Excel 15.0 Object Library
'Crée un fichier excel pour recevoir le contenu de ma table HTML
Dim xlApp As New Excel.Application
Dim xlBook As Excel.Workbook
Dim xlSheetData As Excel.Worksheet
xlApp.Visible = True
Set xlBook = xlApp.Workbooks.Add
Set xlSheetData = xlBook.sheets(1)
 
'Ouvre la page HTML et récupère la table voulue dans un objet table
IE.Navigate "https//test.html" 'mettre l'url de la page contenant la table à récupérer
WaitIE IE ' procédure qui vérifie que la page soit complètement chargée
Set IEDoc = IE.Document
Set TableHTML = IEDoc.getElementsByTagName("TABLE")(10) 'sur ma page  c'est la 11éme table qui était à récupérer
 
'Copie le code HTML de la table dans le presse-papier
objData.SetText TableHTML.outerHTML
objData.PutInClipboard
 
'et enfin copie de la table dans la feuille Excel
xlSheetData.Range("A1").PasteSpecial
 
End Sub

[Marc-L]

Merci de ton retour !

Sinon via clipboardData intégré à IE il n'est pas nécessaire d'activer MS Forms 2.0 …

[Noizette]

Effectivement, un peu difficile de trouver une documentation VBA du clipboardData d'Internet Explorer, mais la solution est effectivement plus simple.
Voici mon code optimisé par cette fonctionnalité:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub test_developpez()
 
Dim WinShell As New ShellWindows
Dim IE As New InternetExplorer
Dim IEDoc As HTMLDocument
Dim TableHTML As HTMLTable
Dim NumTableHTML As Integer
 
'comme mon code VBA est dans un module access, activer Outils\References\Microsoft Excel 15.0 Object Library
'Crée un fichier excel pour recevoir le contenu de ma table HTML
Dim xlApp As New Excel.Application
Dim xlBook As Excel.Workbook
Dim xlSheetData As Excel.Worksheet
xlApp.Visible = True
Set xlBook = xlApp.Workbooks.Add
Set xlSheetData = xlBook.sheets(1)
 
'Ouvre la page HTML et récupère la table voulue dans un objet table
IE.Navigate "https//test.html" 'mettre l'url de la page contenant la table à récupérer
Set IEDoc = IE.Document
Set TableHTML = IEDoc.getElementsByTagName("TABLE")(10) 'sur ma page  c'est la 11éme table qui était à récupérer
 
'Copie la table dans le presse-papier
IEDoc.parentWindow.clipboardData.setData "Text", TableHTML.outerHTML
 
'et enfin copie de la table dans la feuille Excel
xlSheetData.Range("A1").PasteSpecial
 
End Sub

[Marc-L]

C'est normal de ne pas trouver une documentation VBA de clipboardData car ce n'est pas du VBA mais du Windows ‼

Elle se trouve facilement sur MSDN ou encore via une recherche dans les discussions de ce forum …