Discussion :

[neiluj26]

Bonjour le forum,

J'ai une table avec des prix spéciaux pour des clients. Je souhaite exporter en pdf la liste de ces prix pour chaque client.
Pour le faire, j'ai écrit le code suivant qui ouvre l'état "Exportation", change le filtre, et l'exporte en pdf.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
 
strCheminDeSauvegarde = "C:..."
 
strSQL = "SELECT DISTINCT tbl_Prix.Code, tbl_Prix.Branche, tbl_Prix.Code & [Branche] AS Concatenation FROM tbl_Prix;"
 
Set cnc = CurrentProject.Connection
rst.Open strSQL, cnc, adOpenDynamic, adLockReadOnly
 
DoCmd.Echo False
 
DoCmd.OpenReport "rpt_Exportation", acViewPreview
 
While Not rst.EOF
'    Debug.Print rst("Concatenation")
    With Reports("rpt_Exportation")
        .Filter = "tbl_Prix.Code & tbl_Prix.Branche = '" & rst("Concatenation") & "'"
        .FilterOn = True
        .FilterOnLoad = True
        strNomDuFichier = Reports("rpt_Exportation").CodeClient & "-" & Reports("rpt_Exportation").NomClient & "-" & Reports("rpt_Exportation").Pays & ".pdf"
'    Debug.Print strCheminDeSauvegarde & strNomDuFichier
    DoCmd.OutputTo acOutputReport, "rpt_Exportation", "PDF", strCheminDeSauvegarde & strNomDuFichier
    End With
    rst.MoveNext
Wend
DoCmd.Echo True
 
rst.Close
Set cnc = Nothing: Set rst = Nothing

Mon problème est le suivant. En pas à pas, le code fonctionne sans problème. Par contre, dès que je veux lancer l'exécution complète, le code patine. Le filtre est bien changé, mais la sauvegarde se fait toujours avec le même nom de fichier.
Au total, je devrais avoir un peu plus de 300 pdf à la fin. Est-ce que la charge est trop lourde? Est-ce que je devrais mettre une "pause" quelque part?

[loufab]

Bonjour,

Le parcours de la table va plus vite que la création du fichier.

place une temporisation après ton output. (boucle quelconque)

Cordialement,

[ClaudeLELOUP]

Bonjour,

nb. non testé

Peut-être essayer avec un DoEvents après la commande "output"

[Tonioyo]

Bonjour,

L'instruction DoCmd.OutputTo est peut-être exécutée avant que les changements sur les propriétés de l'état ne soient prises en compte.

De mémoire j'ai déjà eu ce problème et pour le corriger j'ai ouvert l'état en mode design, modifié les propriétés, enregistré l'état puis réouvert en préview avant l'instruction OutputTo.

Le fait de le réouvrir à provoqué la réévaluation de la requête avec les filtres modifiés.

Cette méthode est à tester dans votre contexte.

Cordialement,

[loufab]

... j'ai ouvert l'état en mode design, ...

et surtout prier pour que neiluj26 ne souhaite jamais livrer un mde/accde.

[loufab]

Après avoir vu ton code, regarde cette variante.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
strCheminDeSauvegarde = "C:..."
 
strSQL = "SELECT DISTINCT tbl_Prix.Code, tbl_Prix.Branche, tbl_Prix.Code & [Branche] AS Concatenation FROM tbl_Prix;"
 
Set cnc = CurrentProject.Connection
rst.Open strSQL, cnc, adOpenDynamic, adLockReadOnly
 
DoCmd.Echo False
 
 
 
While Not rst.EOF
 
        myFilter = "tbl_Prix.Code & tbl_Prix.Branche = '" & rst("Concatenation") & "'"
        DoCmd.OpenReport "rpt_Exportation", acViewPreview,,myfilter
 
        doevents
 
        strNomDuFichier = Reports("rpt_Exportation").CodeClient & "-" & Reports("rpt_Exportation").NomClient & "-" & Reports("rpt_Exportation").Pays & ".pdf"
 
    DoCmd.OutputTo acOutputReport, "rpt_Exportation", "PDF", strCheminDeSauvegarde & strNomDuFichier
        docmd.close acreport,"rpt_Exportation"
    rst.MoveNext
Wend
DoCmd.Echo True
 
rst.Close
Set cnc = Nothing: Set rst = Nothing

[neiluj26]

Bonjour,

Merci pour les réponses et pardon pour le retard. Je vais les tester de ce pas.

Par contre, je n'ai pas compris la remarque sur accde/mde... je suppose qu'on ne peut pas ouvrir un formulaire en mode design avec un accde? Je débute encore, hein?

[Tonioyo]

Bonjour,

Oui loufab à raison. Il est possible d'enregistrer une base de donnée en format accde/mde. Le format mde est la même chose que l'accde. accde est une extention récente, à partir d'Access 2007.

Une base en format accde/mde interdit toute modification d'objet présent dans la base et supprime les modules de codes écris en haut niveau (écris par le développeur en VBA). il reste le code compilé dans cette base, il est donc executable. Il s'agit de code MSIL (Microsoft Intermediate Language).

Pour faire simple il s'agit du langage machine qui serra directement executé par Access. Ce code lui même n'est donc plus modifiable.

Il est donc très important de prendre beaucoup de précautions, surtout faire beaucoup de copies de sauvegarde de la base source.

[neiluj26]

Ok, donc la solution de loufab marche impeccablement. Merci pour votre aide.