Discussion :

[Maady]

Bonjour,

je souhaiterais pouvoir calculer l'écart type d'un échantillon avec une condition.Les solutions de pré filtrage ne me conviennent pas.

J'ai essayé une formule du type :
=ECARTYPE(SI(C:C=1;E:E;""))
mais ça ne fonctionne pas.

Je souhaiterais calculer l'écart type de la colonne E pour les données contenant le chiffre 1 dans la colonne C.

Y a t-il un moyen de le faire sans passer par un pré filtrage (j'ai beaucoup de colonne dans ma feuille)?

Merci pour votre aide

M

[Pierre Fauconnier]

Bonjour

Il faut utiliser une fonction validée en matricielle.

Avec des données en C2:C10 et E2:E10, tu pourras utiliser la formule suivante:

=ECARTYPE(SI((C2:C10=1)*E2:E10<>0;(C2:C10=1)*E2:E10;""))

Attention! Tu dois valider la formule en matricielle, c'est-à-dire avec

CTRL+MAJ+ENTER (CTRL+SHIFT+ENTER)

Excel ajoute alors des accolades de part et d'autre de la fonction pour signaler qu'elle est validée en matricielle.

Depuis 2007, cette fonction est obsolète et il est préférable d'utiliser ECARTYPE.STANDARD...

[Maady]

Merci beaucoup ! Ça fonctionne parfaitement. Cependant, n'y a t-il pas moyen de lui donner la colonne d'un tableau plutôt qu'une formulation matricielle ? Ou alors, peut-on convertir une colonne de tableau en formulation matricielle ?
Des lignes vont être ajoutées à mon tableau au fil des mois, et j'aimerais ne pas avoir à modifier la formule à chaque fois si possible.

Merci encore

M

[Pierre Fauconnier]

Tu dois passer par une matricielle car c'est la validation matricielle qui permet d'obtenir le résultat correct (traitement des données ligne par ligne puis agrégat des résultats intermédiaires), mais tu peux lui passer en paramètres des colonnes de tableau (versions 2007 et 2010. Pour la version 2003, on peut s'appuyer sur des plages nommées qui s'appuient sur une liste [données > Liste > Créer une liste...] pour les faire évoluer en fonction des saisies dans la "liste". Pour les versions antérieures à la 2003, on peut utiliser des plages nommées avec DECALER())

=ECARTYPE(SI((Tableau1[Donnée Test]=1)*Tableau1[Valeurs]<>0;(Tableau1[Donnée Test]=1)*Tableau1[Valeurs];""))

[Maady]

C'est parfait.

Merci encore

M

[sebdes01]

* Bonjour, *

Pourriez vous expliquer comment lire la formule?

J'ai la même à faire avec plusieurs conditions et je ne saisi pas pourquoi il faut écrire: *Tableau1[Valeurs];""...

je comprend qu'il faut multiplier par des cases vides... ce qui n'a pas de sens d'où mon questionnement.

* Merci *

[Pierre Fauconnier]

Salut.

Il vaut bien voir que la syntaxe que j'ai utilisée n'est valable qu'à partir de la version 2007. Pour les versions antérieures, il faut utiliser une plage nommée basée sur une liste (2003) ou une plage nommée avec DECALER (Versions < 2003).

Au départ, on veut calculer l'écart-type des données présentes dans la colonne Tableau1[Valeurs]. Mais on ne veut considérer que les données de la colonne Valeurs pour lesquelles on trouve la valeur 1 dans la colonne Données Test. On teste donc cela via (Tableau1[Donnée Test]=1) qui renvoie VRAI ou FAUX, converti par Excel respectivement en 1 et 0. Donc, (Tableau1[Donnée Test]=1)*Tableau1[Valeurs] renverra 0 pour chaque ligne contenant autre chose que 1 en Donnée Test et la donnée de Valeurs (1 * Valeurs) lorsque Donnée Test contient 1.

Complément


Tu dois donc exprimer les comparaisons dans des parenthèses puis

• soit multiplier les résultats si toutes les conditions doivent être remplies;
• soit additionner les résultats et les comparer avec le nombre de conditions qui doivent être remplies, si une ou plusieurs conditions doivent être remplies pour extraire la valeur de la ligne.

Exemples

(A=1)*(B=4)*C renverra C si A = 1 ET B=4, et renverra 0 dans tous les autres cas.
(((A=1)+(B=1)+(C=1))>0)*D renverra D si au moins une condition est remplie, et 0 si aucune condition n'est remplie.
(((A=1)+(B=1)+(C=1)+(D=1))>=2)*E renverra E si au moins DEUX conditions sont remplies, et 0 si aucune ou une seule condition est remplie.

Tu vois donc que tu as là un puissant outil d'extraction de valeurs selon des conditions posées sur les colonnes d'un tableau.
Voilà l'explication de la multiplication. J'espère que cela t'a aidé...

[CroqueMr]

Tu dois passer par une matricielle car c'est la validation matricielle qui permet d'obtenir le résultat correct (traitement des données ligne par ligne puis agrégat des résultats intermédiaires), mais tu peux lui passer en paramètres des colonnes de tableau (versions 2007 et 2010. Pour la version 2003, on peut s'appuyer sur des plages nommées qui s'appuient sur une liste [données > Liste > Créer une liste...] pour les faire évoluer en fonction des saisies dans la "liste". Pour les versions antérieures à la 2003, on peut utiliser des plages nommées avec DECALER())

Je me permets de répondre très tard à ce poste car il est facilement trouvable sur google.
Tout d'abord merci pour cette formule, mais avec ma base de donné, elle ne marchait pas parfaitement car certaines valeurs sont égales à 0 dans mon tableau du coup (Tableau1[Donnée Test]=1)*Tableau1[Valeurs] renvoie 0 et la matrice ne prendra pas en compte cette enregistrement.

J'ai rectifié la formule comme voici pour ne plus avoir de problème. Cela fonctionne parfaitement dans mon cas, mais peut être que d'autres cas spécifiques posent aussi problème.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ECARTYPE(SI((Tableau1[Donnée]=Valeurcherché)<>0;(Tableau1[Donnée]=Valeurcherché)*Tableau2[Valeurs];""))