Discussion :

[greg110774]

J'aimerais créer dans ce FORUM, un post concernant juste des animations graphiques en batch.

Ce qui serait bien :

1° juste copier/coller les codes

2° Pas de Blabla inutile sauf pour des compléments d'informations utiles.

3° Essayer de référencer les codes ici, je sais que des sites existent...

4° Les versions Batch déjà existantes sont les bienvenues, de même que vos propres créations.

5° La question est posée sur le FORUM, elle ne sera <ital>jamais résolue.

6° A votre bon temps, à votre passion, à votre bon coeur </ital>

7° C'est un peu une petite communauté dans Developpez.com en fait !

--> Ça sera plus facile de faire ses propres créations en ayant un endroit commun et diversifié afin d'avoir le plus d'exemples à portée de main par cette mise en commun

Merci à vous


greg1107

[greg110774]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
cls
@ECHO OFF
title MATRIX ANMATION!
color 2
:START
echo %random% %random% %random% %random% %random% %random% %random% %random% %random% %random% 
goto START

[Laurent Dardenne]

Salut,
merci de ne poster que des scripts sans encodage.

[I'm_HERE]

salut,

ma petite contribution:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
@setlocal & echo off & mode 70,10  % By Walid /tester sous XPSP3 %
Call :tmz1
:tmz2
setlocal enableextensions enabledelayedexpansion
for %%: in (":=" ",=" " =0") do set "time=!time:%%~:!"
for /l %%i in (0 1 8) Do ( set /az+=1
  Set $t!z!=!time:~%%i,1!
)
for /f "tokens=2 delims==" %%i in ('set $t') do (
  for /l %%p in (1 1 5) do ( set /ao+=1     
      set _!o!=!%%i.%%p!
  )
)
cls
echo.
echo.
echo    %_1% %_6%  %_11% %_16%  %_21% %_26%  %_31% %_36%
echo    %_2% %_7%  %_12% %_17%  %_22% %_27%  %_32% %_37%
echo    %_3% %_8%  %_13% %_18%  %_23% %_28%  %_33% %_38%
echo    %_4% %_9%  %_14% %_19%  %_24% %_29%  %_34% %_39%
echo    %_5% %_10%  %_15% %_20%  %_25% %_30%  %_35% %_40%
endlocal & goto :tmz2
:tmz1
set "0.1=oooooo"&set "1.1=  ooo "&set "2.1=oooooo"&set "3.1=oooooo"&set "4.1=    oo "
set "0.2=o    o"&set "1.2=    o "&set "2.2=     o"&set "3.2=     o"&set "4.2=   o o "
set "0.3=o    o"&set "1.3=    o "&set "2.3=oooooo"&set "3.3=  oooo"&set "4.3=  o  o "
set "0.4=o    o"&set "1.4=    o "&set "2.4=o     "&set "3.4=     o"&set "4.4= oooooo"
set "0.5=oooooo"&set "1.5=  oooo"&set "2.5=oooooo"&set "3.5=oooooo"&set "4.5=     o "
set "5.1=oooooo"&set "6.1=oooooo"&set "7.1=oooooo"&set "8.1=oooooo"&set "9.1=oooooo"
set "5.2=o     "&set "6.2=o     "&set "7.2=    o "&set "8.2=o    o"&set "9.2=o    o"
set "5.3=oooooo"&set "6.3=oooooo"&set "7.3=   o  "&set "8.3=oooooo"&set "9.3=oooooo"
set "5.4=     o"&set "6.4=o    o"&set "7.4=   o  "&set "8.4=o    o"&set "9.4=     o"
set "5.5=oooooo"&set "6.5=oooooo"&set "7.5=   o  "&set "8.5=oooooo"&set "9.5=oooooo"
goto :EOF

[minnesota]

Sa...lut,

@I'm_HERE
Bien joué, dommage que c'est pas assez fluide.

@greg110774
Ceux qui connaissent Matrix seront déçus, ça manque de caractère exotique et d'espace, sinon bien.

@Laurent
ton script y marche pas.

[Laurent Dardenne]

Bien joué, dommage que c'est pas assez fluide.

C'est du batch...

@greg110774
Ceux qui connaissent Matrix seront déçus, ça manque de caractère exotique et d'espace, sinon bien.

greg110774 en a posté un second plus conséquent, mais avec de l'encodage (vbs) et comme on ne connait pas le code exécuté, par prudence j'ai préféré retirer le message.

@Laurent
ton script y marche pas.

Normal, tu n'as pas le DSL PowerShell adéquate ...

[I'm_HERE]

salut,

dommage que c'est pas assez fluide.

pour avoir un effet plus fluide tu peux essayer 3 choses:
enlève ces echo's:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9

echo.
echo.
echo    %_1% %_6%  %_11% %_16%  %_21% %_26%  %_31% %_36%
echo    %_2% %_7%  %_12% %_17%  %_22% %_27%  %_32% %_37%
echo    %_3% %_8%  %_13% %_18%  %_23% %_28%  %_33% %_38%
echo    %_4% %_9%  %_14% %_19%  %_24% %_29%  %_34% %_39%
echo    %_5% %_10%  %_15% %_20%  %_25% %_30%  %_35% %_40%

mettre un foreground qui n'est pas une couleur claire et aussi agrandir la taille des nombres.

@Laurent
ton script y marche pas.

je te retourne la question

[minnesota]

C'est vrai qu'on gagne un tout petit peu en enlevant les echo. J'ai aussi essayé en supprimant le cls et jouer avec le décalage, mais ça scintille quand même. Comme dit Laurent ça reste du batch et on ne peut vraisemblablement pas faire plus.

je te retourne la question

Lol, je ne te le fais pas dire ! Je savais que tôt ou tard ça se retournerait contre moi.

[I'm_HERE]

essayes ceci c'est encore plus fluide:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
@setlocal & echo off & mode 65,7  & color a % By Walid /tester sous XPSP3 %
Call :tmz1
:tmz2
setlocal enableextensions enabledelayedexpansion
for %%: in (":=" ",=" " =0") do set "time=!time:%%~:!"
for /l %%i in (0 1 8) Do Set $t%%i=!time:~%%i,1!
for /f "tokens=2 delims==" %%i in ('set $t') do (
  for /l %%p in (1 1 5) do ( set /ao+=1     
      set _!o!=!%%i.%%p!
  )
)
cls
echo.
echo    %_1% %_6%  %_11% %_16%  %_21% %_26%  %_31% %_36%
echo    %_2% %_7%  %_12% %_17%  %_22% %_27%  %_32% %_37%
echo    %_3% %_8%  %_13% %_18%  %_23% %_28%  %_33% %_38%
echo    %_4% %_9%  %_14% %_19%  %_24% %_29%  %_34% %_39%
echo    %_5% %_10%  %_15% %_20%  %_25% %_30%  %_35% %_40%
endlocal & goto :tmz2
:tmz1
set "0.1= #### "&set "1.1=  ### "&set "2.1= #####"&set "3.1=######"&set "4.1=   ## "
set "0.2=#    #"&set "1.2=    # "&set "2.2=     #"&set "3.2=     #"&set "4.2=  # # "
set "0.3=#    #"&set "1.3=    # "&set "2.3=######"&set "3.3=  ####"&set "4.3= #  # "
set "0.4=#    #"&set "1.4=    # "&set "2.4=#     "&set "3.4=     #"&set "4.4=######"
set "0.5= #### "&set "1.5=  ####"&set "2.5=######"&set "3.5=######"&set "4.5=    # "
set "5.1=##### "&set "6.1=##### "&set "7.1=######"&set "8.1=######"&set "9.1=######"
set "5.2=#     "&set "6.2=#     "&set "7.2=    # "&set "8.2=#    #"&set "9.2=#    #"
set "5.3=######"&set "6.3=######"&set "7.3=   #  "&set "8.3=######"&set "9.3=######"
set "5.4=     #"&set "6.4=#    #"&set "7.4=   #  "&set "8.4=#    #"&set "9.4=     #"
set "5.5=######"&set "6.5=######"&set "7.5=   #  "&set "8.5=######"&set "9.5=######"
goto :EoF

[minnesota]

On voit un peu plus de millièmes. C'est déjà ça.