Discussion :

[methylene]

Bonjour, est-il possible de figer des "onglets" comme l'on fige des volets ?

Ayant une trentaine de pages j'aimerais bien que mes 3 premiers onglets restent figés quand je fais défiler la barre d'onglets, de façon à toujours avoir accès à mes 3 premières pages.

Merci.

[fring]

Bonjour,

Il n'est pas possible de figer les onglets mais je te propose un bricolage qui consiste à créer une petite barre de menu complémentaire avec 3 boutons permettant d'activer la feuille 1, 2 ou 3

Dans un Module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub Ajout_BarreMenu()
Dim Cbar As CommandBar, Cbut As CommandBarButton, x As Byte
 
Set Cbar = CommandBars.Add(Name:="MaBarre", Position:=msoBarBottom, Temporary:=True)
 
For x = 1 To 3
    Set Cbut = Cbar.Controls.Add(msoControlButton)
    With Cbut
        .Style = msoButtonCaption
        .Caption = "Feuille " & x
        .OnAction = "Select_feuil"
    End With
Next x
 
Cbar.Protection = msoBarNoMove + msoBarNoCustomize
Cbar.Visible = True
 
End Sub
 
Sub Select_feuil()
Select Case Application.CommandBars.ActionControl.Caption
    Case "Feuille 1"
        Sheets(1).Activate
    Case "Feuille 2"
        Sheets(2).Activate
    Case "Feuille 3"
        Sheets(3).Activate
End Select
End Sub
 
Sub Supp_menu()
On Error Resume Next
CommandBars("MaBarre").Delete
End Sub

Dans Thisworkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Supp_menu
End Sub
 
Private Sub Workbook_Open()
    Ajout_BarreMenu
End Sub

[fring]

Oups...j'avais zappé un détail, ce que je t'ai proposé ne va pas être pratique sous Excel 2007 vu que la barre de menu va aller se placer dans l'onglet compléments.

Dans ce cas je te propose d'ajouter les boutons permettant d'accéder aux feuilles dans le menu contextuel, accessible depuis n'importe quelle feuille via le clic droit.

Dans un Module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub Ajout_MenuContextuel()
Dim Cbar As CommandBarControls, Cbut As CommandBarButton, x As Byte
Set Cbar = CommandBars("Cell").Controls
For x = 1 To 3
    Set Cbut = Cbar.Add(msoControlButton, Temporary:=True)
    With Cbut
        .Caption = "Feuille " & x
        .OnAction = "Select_feuil"
    End With
Next x
End Sub
 
Sub Select_feuil()
Select Case Application.CommandBars.ActionControl.Caption
    Case "Feuille 1"
        Sheets(1).Activate
    Case "Feuille 2"
        Sheets(2).Activate
    Case "Feuille 3"
        Sheets(3).Activate
End Select
End Sub
 
Sub Reset_MenuContextuel()
    CommandBars("Cell").Reset
End Sub

Dans Thisworkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Reset_MenuContextuel
End Sub
 
Private Sub Workbook_Open()
    Ajout_MenuContextuel
End Sub

[methylene]

C'était une des solutions que je cherchais. Je me demandais s'il y avait moyen d'avoir un menu commun à toutes les feuilles.

Mais finalement j'ai résolu mon problème avec une combobox dans l'une des feuilles que je veux toujours accessible, puis je sélectionne la feuille que je souhaite, et donc cela m'affiche la feuille en question et déplace également les feuilles que je souhaite toujours visible.

Merci pour ta solution, dommage qu'elle ne soit pas arrivé avant que je trouve la mienne, mais le bon coté des choses pour le prochain qui cherchera, 2 solutions, un problème !!!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
Private Sub ComboBox2_Change()
 
If Worksheets(NameSheet(ComboBox2.ListIndex)).Name = "Chef" Or Worksheets(NameSheet(ComboBox2.ListIndex)).Name = "Ouvrier" Then
 
Worksheets("modele").Move after:=Worksheets("ouvrier")
 
Else
 
Worksheets(NameSheet(ComboBox2.ListIndex)).Activate
Worksheets("modele").Move before:=ActiveSheet
Worksheets(NameSheet(ComboBox2.ListIndex)).Activate
 
End If
 
End Sub
 
Private Sub ComboBox2_DropButtonClick()
 
    Dim ws As Worksheet
    Dim i, j, nbfeuil As Integer
 
    i = 0
    j = 0
 
    nbfeuil = ThisWorkbook.Worksheets.Count - 1
 
    ReDim Search(nbfeuil) As String
    ReDim NameSheet(nbfeuil) As String
 
 
    For Each ws In ThisWorkbook.Worksheets
 
        If ws.Name = "modele" Or ws.Name = "Chef" Or ws.Name = "Ouvrier" Then
 
            Search(i) = Search(j)
            Search(j) = ws.Name
            NameSheet(i) = NameSheet(j)
            NameSheet(j) = ws.Name
            j = j + 1
 
        Else
 
            Search(i) = ws.Cells(2, 3).Value & " " & ws.Cells(4, 3).Value
            NameSheet(i) = ws.Name
 
 
        End If
 
        i = i + 1
 
    Next
 
   ComboBox2.List = Search
 
End Sub

Voila en gros mon code adapté à ma situation, j'ai donc uniquement ma feuille "modele" qui sera toujours à gauche de la feuille active, sauf si la feuille que je souhaite active est la feuille "ouvrier" ou la feuille "chef", qui sont mes feuilles les plus à gauche, dans ce cas là ma feuille "modèle" sera placé en 3ème position.

Conclusion j'ai un "onglet figé".

[Didier Gonard]

Ayant une trentaine de pages j'aimerais bien que mes 3 premiers onglets restent figés quand je fais défiler la barre d'onglets, de façon à toujours avoir accès à mes 3 premières pages.

Euh, sous 2003 à 2010, en cliquant droit sur les flèches de déplacement à gauche des onglets, tu a une lisbox native qui s'ouvre et qui te donne un accès direct aux 15 premières feuilles et à toutes si tu cliques "plus de feuilles"



cordialement,

Didier

[methylene]

Encore plus simple en effet lol

Merci pour cette astuce qui est bonne à savoir.

Je retourne au Vb.net, le vba c'est moins intuitif quand on connaît pas les méthodes (Intellisense pourri ...)

Allez , et merci pour vos réponses.