Discussion :

[ludojojo]

Bonjour,

Je cherche à créer une fonction qui me permettrai de comparer une cellule spécifique sur plusieurs feuilles. La cellule est toujours la même.

Je souhaiterais que cette fonction créée un nouvelle feuille (supprime si elle existe déjà) qui ai pour contenu une colonne avec le nom des feuilles de mon classeur et à coté la valeur de la case spécifique...
Je ne sais pas trop comment faire.

Je ne pense pas que cela soit très compliqué, mais je ne m'y connais pas trop en VBA...
Toute aide sera la bien venue.

[dadavyvy]

Bonjour,

essaie :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub comparaison()
    Dim wks As Worksheet, w As Worksheet, nom_feuille_resultat, cellule
    nom_feuille_resultat = "Résultat"       ' nom de la feuille résultat
    cellule = "B5"                          ' cellule dont la valeur est cherchée dans toutes les autres feuilles
 
    ' Recherche de la feuille de résultat ou en crée une nouvelle
    Set wk = Nothing
    For Each wks In ThisWorkbook.Worksheets     ' Parcoure toutes les feuilles du classeur
        If wks.Name Like nom_feuille_resultat Then  ' Recherche la feuille resultat si elle existe
            Set wk = wks    ' enregistrement de cette feuille resultat dans la variable objet wk
            wk.Cells.Delete ' supprime toutes les cellules
            Exit For        ' sort de la boucle
        End If
    Next wks
    If wk Is Nothing Then                       ' Si la feuille résultat n'a pas été trouvée
        Set wk = ThisWorkbook.Worksheets.Add    ' Crée une nouvelle feuille
        wk.Name = nom_feuille_resultat          ' Renomme la feuille
    End If
 
    ' Recherche toutes les valeurs de la cellule voulue
        ' Préparation de la feuille résultat
    wk.Range("A1") = "Feuille"
    wk.Range("B1") = "Valeur cellule [" & cellule & "]"
    i = 2
    For Each wks In ThisWorkbook.Worksheets     ' Parcoure toutes les feuilles du classeur
        If Not wks.Name = wk.Name Then                   ' Recherche dans toutes les feuilles sauf celle des résultats
            wk.Range("A" & i) = wks.Name                    ' enregistrement du nom de la feuille
            wk.Range("B" & i) = wks.Range(cellule).Value    ' enregistrement de la valeur de la cellule de la feuille
            i = i + 1                                       ' incrementation des lignes dans la feuille résultats
        End If
    Next wks
End Sub

[ludojojo]

Rapide et efficace, ce code est tout simplement parfait !!!
Merci beaucoup pour ton aide !!!