Discussion :

[dianbobo]

bonjour tout le monde

je suis sur un code que je croix avoir presque terminé mais je bute sur un point

voici mon code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub spreadDeCredit()
Dim k As Long
Dim spot_1 As Double
Dim spot_2 As Double
Dim somme As Single
Dim diff As Double
k = Worksheets("Feuil1").Cells(Rows.Count, 1).End(xlUp).Row
 
For i = 0 To k
    If Worksheets("Feuil1").Cells(i, 16).Value Like "*AAA*" Then
       spot_1 = Worksheets("Feuil1").Cells(i, 10).Value
       spot_2 = Worksheets("Feuil1").Cells(i, 11).Value
       diff = Abs(spot_1 - spot_2)
       somme = 0
       somme = somme + diff
    End If
    Cells(6, 8).Value = somme
End Sub

dans ce code je cherche a parcourir "Feuil1" avec la condition que j'ai imposé et mettre le resultat dans feuil2
ma boucle parcours la feuille ("feuil1") daja a ce nivo j'aimerai savoir ci c'est correct mon ecriture ?
ensuite je voudrais faire la somme de toutes les differences Abs(spot_1 - spot_2) ...
est ce correct la aussi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

somme = somme + diff

enfin mon soucis majeur est que ma cellule H6 DOIT CONTENIR : H6=somme/(nombre de fois qu'on a rencontré le caractere AAA dans feuil1) en d'autres termes c'est le nombre de fois qu'on a fait la difference entre spot_1 et spot_2

sof que j'ignore comment le definir dans mon code

merci de votre aide

[methylene]

Réessayes de poster de ce coté là.

http://www.developpez.net/forums/f54...-office/excel/

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub spreadDeCredit()
Dim i As Long, k As Long, Cpt As Long
Dim spot_1 As Double, spot_2 As Double, somme As Single, diff As Double
 
With Worksheets("Feuil1")
   k = .Cells(Rows.Count, 1).End(xlUp).Row
   For i = 2 To k
      If .Cells(i, "P").Value Like "*AAA*" Then
         spot_1 = .Cells(i, "J").Value
         spot_2 = .Cells(i, "K").Value
         diff = Abs(spot_1 - spot_2)
         somme = somme + diff
         Cpt = Cpt + 1
      End If
   Next i
End With
With Worksheets("Feuil2")
   .Range("H6").Value = IIf(Cpt = 0, "", somme / Cpt)
End With
End Sub