problème de sélection de cellules

**adriennoob** · 15/04/2010, 20h41

Bonsoir,

Je n'y arrive pas, j'ai un code qui doitme permettre de séléctionner dans un tableau les lignes correspondantes à deux valeur.

La première valeur est recherché dans la colonne A et la deuxième dans la colonne B.

donc je veux sélectionner toute les lignes qui possède valeur A et Valeur B.

Mais ça ne fonctionne pas Je sais pas pourquoi???

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub test()
 
Dim i As Integer
Dim LaDerniere As Integer
 
LaDerniere = Worksheets("Feuil1").Cells(56555, 2).End(xlUp).Row
 
For i = 1 To LaDerniere
If Not (Worksheets("Feuil1").Range("C1").Value = "") And Not (Worksheets("Feuil1").Range("C2").Value = "") Then
If Worksheets("Feuil1").Cells(i, 1) = Worksheets("Feuil1").Range("C1").Value And Worksheets("Feuil1").Cells(i, 2) = Worksheets("Feuil1").Range("C2").Value Then
Worksheets("Feuil1").Range("A" & i & "").Select
End If
End If
Next i
End Sub

J'ai fais se bout de code

**casefayere** · 15/04/2010, 20h50

Bonsoir,
veux-tu selectionner toutes les lignes concernées en une fois ou les cellules concernées ?

**adriennoob** · 15/04/2010, 20h55

je veux sélectionner les cellules concernées;

**Pierre Fauconnier** · 15/04/2010, 21h07

Bonjour

Essaie ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub Test()
  Dim ValA As Variant, ValB As Variant
  Dim Cellule As Range, Plage As Range
  Dim i As Long
 
  ValA = "Fauconnier"
  ValB = "Pierre"
 
  For Each Cellule In Range("a2:a" & Range("a" & Rows.Count).End(xlUp).Row)
    If Cellule = ValA And Cellule(1, 2) = ValB Then
      If Plage Is Nothing Then Set Plage = Rows(Cellule.Row) Else Set Plage = Union(Plage, Rows(Cellule.Row))
    End If
  Next Cellule
  Plage.Select
End Sub

**adriennoob** · 15/04/2010, 21h10

J'ai modifié quelque truc qui ne fonctionnait pas.
tu peux me dire si j'ai bien fait???
j'ai mis Dim devant plage as range

et par contre j'ai un soucis au niveau de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set plage = Union(plage.Address, .Range("A" & i))

Ca marque incompatibilité de type et ça me surligne .address

Merci pour ton aide

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub test()
 
Dim i As Integer, verif As Integer
Dim LaDerniere As Integer
With Worksheets("Feuil1")
 Dim plage As Range
   LaDerniere = .Range("B" & .Rows.Count).End(xlUp).Row
 
   For i = 1 To LaDerniere
      If Not (.Range("C1").Value = "") And Not (.Range("C2").Value = "") Then
         If .Cells(i, 1) = .Range("C1") And .Cells(i, 2) = .Range("C2").Value Then
            verif = verif + 1
            Set plage = .Range("A" & i)
            If verif > 1 Then
               Set plage = Union(plage.Address, .Range("A" & i))
            End If
         End If
      End If
   Next i
   plage.Select
End With
End Sub

**casefayere** · 15/04/2010, 21h12

oui, j'ai fait des conn...
voilà mon code corrigé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub test()
 
Dim i As Integer, verif As Integer, plage As String
 
Dim LaDerniere As Integer
With Worksheets("Feuil1")
   LaDerniere = .Range("B" & .Rows.Count).End(xlUp).Row
   verif = 0
   For i = 1 To LaDerniere
      If Not (.Range("C1").Value = "") And Not (.Range("C2").Value = "") Then
         If .Cells(i, 1) = .Range("C1") And .Cells(i, 2) = .Range("C2").Value Then
            verif = verif + 1
            If verif = 1 Then
               plage = .Range("a" & i).Address
               Else
               plage = plage & "," & .Range("A" & i).Address
            End If
         End If
      End If
   Next i
  Range(plage).Select
End With
End Sub

**Pierre Fauconnier** · 15/04/2010, 21h13

Dans ton premier message, tu dis que tu veux tester les valeurs en A et B, et dans ton code, tu testes si C = ""...

Quel est l'énoncé exact de ton problème?

Le code que je t'ai donné sélectionne les lignes entières pour lesquelles les valeurs en A et B correspondent à des valeurs test. Est-ce cela que tu veux?

**adriennoob** · 15/04/2010, 21h18

Ben en fait au final les valeur que je sélectionne en C1 et C2 seront des valeurs que j'aurais sélectionné dans des combobox1 et 2. Ces combobox sont prete à être utilisé. elles sont construite en cascade. Ma combobox2 s'alimente en fonction de ma combobox1;

Donc je veux que ces valeurs sélectionnées sélectionnent mes cellules concernées dans mon tableau.

J'éspère que c'est clair????

**casefayere** · 15/04/2010, 21h22

alors je pense que tu peux essayer mon code que j'ai rectifié

**adriennoob** · 15/04/2010, 21h23

Je suis géné mais ça marche tjr pas.

A ce niveau

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
.......
  Range(plage).Select
End With
End Sub

**Pierre Fauconnier** · 15/04/2010, 21h25

Envoyé par adriennoob

...J'éspère que c'est clair????

Pas trop, non...

Voici une procédure générique à laquelle tu passes une feuille, la valeur cherchée en A et la valeur cherchée en B...

Tu peux donc lui passer des valeurs issues de combobox, textbox, cellules, ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub SelectionnerLignes(Feuille As Worksheet, ValA As Variant, ValB As Variant)
  Dim Cellule As Range, Plage As Range
  Dim i As Long
 
  For Each Cellule In Feuille.Range("a2:a" & Feuille.Range("a" & Feuille.Rows.Count).End(xlUp).Row)
    If Cellule = ValA And Cellule(1, 2) = ValB Then
      If Plage Is Nothing Then Set Plage = Feuille.Rows(Cellule.Row) Else Set Plage = Union(Plage, Feuille.Rows(Cellule.Row))
    End If
  Next Cellule
  Feuille.Select
  Plage.Select
End Sub

Tu dois faire attention à d'abord sélectionner la bonne feuille, car tu ne peux pas sélectionner des cellules d'une feuille qui n'est pas sélectionnée

**Pierre Fauconnier** · 15/04/2010, 21h37

Dominique,

Pas de soucis... Mais ton code ne sélectionne de toutes façons que les cellules en A, et pas les lignes entières...

**adriennoob** · 15/04/2010, 21h38

Franchement je sais que je vais passer pour un naze mais là je sais pas si c'est comme ça qu'il faut que j'écrive ???

Et cette formule elle recherche bien les valeurs C1 dans la colonne A et Les valeur C2 dans la colonne B????

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub Rectangle1_Clic(Feuille As Worksheet, ValA As Variant, ValB As Variant)
  Dim Cellule As Range, Plage As Range
  Dim i As Long
  ValA = Range("C1").Value
  ValB = Range("C2").Value
  For Each Cellule In Feuille.Range("a2:a" & Feuille.Range("a" & Feuille.Rows.Count).End(xlUp).Row)
    If Cellule = ValA And Cellule(1, 2) = ValB Then
      If Plage Is Nothing Then Set Plage = Feuille.Rows(Cellule.Row) Else Set Plage = Union(Plage, Feuille.Rows(Cellule.Row))
    End If
  Next Cellule
  Feuille.Select
  Plage.Select
 
    Range("C1").Select
End Sub

**casefayere** · 15/04/2010, 21h40

je sais mais le premier code d'adrien laissait penser qu'il ne voulait que les cellules et en A, son code ci-dessous avec son erreur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets("Feuil1").Range("A" & i & "").Select

je ne suis peut-etre pas assez perspicace

**Pierre Fauconnier** · 15/04/2010, 21h42

Cette procédure requiert que tu lui passes trois arguments:
1) Le nom de la feuille
2) La valeur à tester en A
3) La valeur à tester en B

Comme tu es semble-t-il dans un userform, tu n'as pas besoin de passer les valeurs des combos dans des cellules... Passe directement les valeurs en paramètres de la procédure...

Range("C1").Select en fin de proc doit être supprimé, puisque cette ligne va supprimer la sélection des lignes ^^

**adriennoob** · 15/04/2010, 21h43

ca me marque Plage =""

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Range(plage).Select
End With
End Sub

**Pierre Fauconnier** · 15/04/2010, 21h44

Envoyé par casefayere

...je ne suis peut-etre pas assez perspicace

Non, moi j'ai lu le premier message sans regarder le code, mais comme l'énoncé et la configuration du classeur ne sont pas clairs, on risque de tourner en rond

**casefayere** · 15/04/2010, 21h49

bien Pierre tu me rassures
Maintenant Adrien, tu dis que plage n'a aucune valeur et quand j'ai fait un test, j'ai provoqué volontairement des correspondances entre a c1, b et c2
peut-etre n'avais-tu pas de correspondance ?

**Pierre Fauconnier** · 15/04/2010, 21h51

Si tu veux absolument passer par C1 et C2,
Recopie ma macro exactement comme je te l'ai donnée, et modifie ta ligne d'appel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Sub Rectangle1_Clic
  SelectionnerLignes worksheets("Feuil1"), worksheets("Feuil1").range("c1").Value, worksheets("Feuil1").range("c2")Value

Tu gagneras à la faire tourner en pas à pas pour comprendre le principe

**adriennoob** · 15/04/2010, 21h52

au pire je répète se que je veux en essayant d'être très clair

alors j'ai un tableau à deux colonnes A et B.

Je veux sélectionner les lignes qui correspondent à mes deux sélections.

Par exemple si j'ai
1 A B C1 = 1
2 1 2 C2 = 1 alors je sélectionne mes lignes 5 et 7 seulements
3 2 2
4 3 1
5 1 1
6 2 3
7 1 1

problème de sélection de cellules

Macros et VBA Excel

Discussions similaires

Partager

Partager