Discussion :

[Wanaka]

Bonjour à tous

Je me mets tout tout doucement au VBA d'Access ...
Voici mon petit bout de code, honteusement pompé de ci de là ...
La macro est déclenchée par un bouton dans un formulaire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub Btn_Formulaire1_Click()
'Paramètres de connection
Set Cnx = New ADODB.Connection
Cnx.Provider = "Microsoft.Jet.Oledb.4.0"
Cnx.ConnectionString = "E:\Mes documents\SuivisDesCadeaux.mdb"
Cnx.Open
 
'Zone de requête
Dim ListFields As String
ListFields = "TP,Paye,Beneficiaire"
Cnx.Execute "INSERT INTO Suivis_des_coupons (TP,Paye,Beneficiaire,CodeCoupon) VALUES('" & TP_Form & "','" & Chkb_Paye & "','" & Benef & "','" & CodeCoup & "')"
Cnx.Close
End Sub

La macro fonctionne bien, quand elle veut bien ...
Lorsqu'elle arrive à Cnx.Open, il m'arrive, mais pas tout le temps , d'avoir un message d'erreur du style : "La base de données a été placée par l'utilisateur "Admin" dans un état l'empêchant d'être ouvert ou verrouillée"
Pourtant, j'ai bien mon Cnx.Close ...
Je ne vois pas bien d'ou ca peut venir ?? Une petite idée ???

[pier.antoine]

Bonjour.

Je ne répondrais pas à votre interrogation principale.

Je vous signale simplement qu'il ne faut pas avoir honte de copier des bouts de codes.
C'est le début pour apprendre.

Et puis, en général, un code copier ne fonctionne pas tel quel. Il faut l'adapter, ce qui aide à la compréhension.

Pierre

[Wanaka]

Merci pour ces encouragements !!

C'est vrai que rien que pour ces quelques lignes de code, il m'a fallu faire un mixte de plusieurs morceaux ...
Et c'est d'ailleurs comme ca que j'ai réussi à bien progresser en VBA sur Excel.
Mais Access est loins d'etre aussi facile d'utilisation !!

Encore merci !!
Wanaka

[argyronet]

Bonjour,

Ce qui ne va pas dans ton code tel que je le lis, c'est que Cnx est déclarée ailleurs et on ne peut dans ce cas connaître son état...

Tu dois, surtout si tu débutes, te donner de bonnes habitudes et user de procédures génériques, notamment celle pour la connexion, soit par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
 
Option Compare Database
Option Explicit
'Module connexion
'----------------------------
'Variable de module de la connexion
Private m_oCnx                As ADODB.Connection
 
Public Function ConnectAndExecute(ByVal SQLScript As String, ByVal CloseConnection As Boolean, ByRef RecordsAffected As Long, Optional ByVal ConnectionString As String) As Boolean
'Paramètres de connection
    On Error GoTo ConnectAndExecute_Error
    Set m_oCnx = New ADODB.Connection
    With m_oCnx
        ' On vérifie l'état de la conexion
        If Not (.State = adStateOpen) Then
            .Provider = "Microsoft.Jet.Oledb.4.0"
            'On vérifie si le paramètre ConnectionString est renseigné sinon c'est la BDD en cours
            If Len(ConnectionString) = 0 Then
                .ConnectionString = CurrentProject.FullName
            End If
            'On ouvre et on attend l'établissement de la connexion
            .Open
            While (.State = adStateConnecting)
                DoEvents
            Wend
 
        End If
        'On exécute le script avec retour du nombre d'enregistrements affectés
        .Execute SQLScript, RecordsAffected
    End With
 
    ConnectAndExecute = True
    On Error GoTo 0
ConnectAndExecute_Exit:
    'On ferme si c'est demandé
    If CloseConnection Then
        If m_oCnx.State = adStateOpen Then
            m_oCnx.Close
            Set m_oCnx = Nothing
        End If
    End If
    'On sort
    Exit Function
ConnectAndExecute_Error:
    'Une erreur est levée
    ConnectAndExecute = False
    If m_oCnx.Errors.Count > 0 Then
        'Affichage de l'erreur dans la fenêtre de débogage
        Debug.Print m_oCnx.Errors.Item(0)
    End If
    'On reprend l'instruction à l'étiquette
    Resume ConnectAndExecute_Exit
End Function

que tu peux utiliser comme suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
'Classe du formulaire
'----------------------------
Option Compare Database
Option Explicit
 
Private Sub Btn_Formulaire1_Click()
Dim strSQL                    As String
Dim lngRecordsAffected        As Long
 
    strSQL = "INSERT INTO Suivis_des_coupons (TP,Paye, Beneficiaire, CodeCoupon) "
    strSQL = strSQL & "VALUES('" & Me!TP_Form & "','" & Me!Chkb_Paye & "','" & Me!Benef & "','" & Me!CodeCoup & "')"
    If ConnectAndExecute(strSQL, True, lngRecordsAffected) Then
        MsgBox "C'est OK, il y a eu " & lngRecordsAffected & " enregistrement(s) affecté(s)...", vbInformation
    Else
        MsgBox "Ooops, il y a eu une boulette !", vbExclamation
    End If
End Sub

Argy