Discussion :

[redwarf]

Bonjour,

Grace au forum j'ai pu mettre en place ce code qui me permet d'exuter une requete à partir d'un champs numérique :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub douchette_afterupdate()
Me.Filter = "code=" & Me.douchette 'si rérérence est numérique
Me.FilterOn = True
DoCmd.SetWarnings False
Dim rst As Recordset
Set rst = CurrentDb.OpenRecordset("select * from presence where code=" & douchette)
If rst.EOF Then
  MsgBox "Ce badge n'est pas enregistrer pour ce rallye !"
ElseIf rst!presence = "oui" Then
  MsgBox "Ce badge a déjà été validé !"
  douchette = Null
Else
DoCmd.RunSQL "update Presence set presence='oui' where code=" & douchette & ";"
DoCmd.SetWarnings True
douchette = Null 'réinitialise le champ
Me.Requery        'met à jour l'affich
douchette.SetFocus
End If
rst.Close
End Sub

J'essaye d'éxécuter ce même code mais avec un champs au format texte

mais recherches mon mené à modifier cette ligne : Me.Filter = "[code]=" & Me.douchette 'si rérérence est numérique

Me.Filter = "[CODE]='" & Me.douchette & "'"

J'ai donc rajouté des guillemets pour le texte, mais rien y fait !

Merci de me dépanner

[Tofalu]

Parfois, les lecteurs de code barres ajoutent des caractères supplémentaires dans les champs (genre chr(0)). A vérifier.

Ce qui est aussi curieux, c'est que vous encadrez correctement la variable de ' ' dans l'expression filter mais pas dans les autres requêtes.

Une erreur est générée ?

[redwarf]

erreur d'éxécution 3061

trop peu de paramètre 1 attendu

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Set rst = CurrentDb.OpenRecordset("select * from presence where Nom=" & recherche)

[olive_tp]

Je ne sais pas si le pb vient de là, mais il faut bien modifier ton code pour mettre des guillemets partout. Ci-dessous ton code que j'ai modifié dans le cas d'une donnée "douchette" qui est du texte:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub douchette_afterupdate()
Me.Filter = "(code='" & Me.douchette & "')" 'si rérérence est texte
Me.FilterOn = True
DoCmd.SetWarnings False
Dim rst As Recordset
Set rst = CurrentDb.OpenRecordset("select * from presence where code='" & douchette & "'")
If rst.EOF Then
  MsgBox "Ce badge n'est pas enregistrer pour ce rallye !"
ElseIf rst!presence = "oui" Then
  MsgBox "Ce badge a déjà été validé !"
  douchette = Null
Else
DoCmd.RunSQL "update Presence set presence='oui' where code='" & douchette & "';"
DoCmd.SetWarnings True
douchette = Null 'réinitialise le champ
Me.Requery        'met à jour l'affich
douchette.SetFocus
End If
rst.Close
End Sub

Tu peux tester et me faire un feed-back?

[redwarf]

Un grand merci ca marche au poil !

Je suis un peu en retard mon disque dur avait laché.