Bouton de UserForm mis en variable

**danbo52** · 01/10/2009, 10h16

bonjour,

myope, je n'ai pas vu traité ce sujet, et je ne trouve pas dans la littérature.

prob:

sur une feuille 'feuil1' de classeur (XL 2003-2007), j'ai un bouton 'Btn'.
En cliquant dessus, j'appelle un Userform, qui se nomme bêtement 'UserForm1'.

Ce Userform contient des boutons d'actions. Leur légende (caption) est en français.

Sur la feuille 'feuil2' du même classeur, j'ai des listes de mots, qui représentent les termes de toutes les legendes des boutons du Userform:
colonne 1 => francais
colonne 2 => allemand
colonne 3 => anglais

Or, sur la feuilll 'feuil1', j'ai trois boutons 'francais', 'allemand' et 'anglais'.
En appuyant sur l'un des trois, les legendes devraient changer dans le userform:
exemple
'ouvrir fichier courant' deviendrait 'Open current file', etc...

Remarque :

je souhaite que les boutons soient et restent sur la feuille 'feuil1', car j'ai d'autres Userforms en cours.

Question:

Quelle est la syntaxe depuis les trois boutons de langues la feuil 'feuil1' qui permettrait de faire changer la légende des boutons du Userform, en posant que les noms des boutons seront dans une variable, puisque je vais boucler chaque liste de la colonne de langue choisie.

ex bidon :
choix du Userform k du classeur
for i....'pour i legendes à changer dans le Userform
prendre item(i) de la colonne j de la feuil2
changer la legende du bouton(i) du userform(k)
next i 'boucler

merci (développement freelance pour une Société)

**Fvandermeulen** · 01/10/2009, 12h46

Salut,
Est-ce que tes légendes dans ton Userform ont le nom de type Label1, Label2,...
As tu bien autant de lignes dans ta feuille 2 que de légende dans ton UF ?

A+

Edit: Si la réponse est oui aux questions, voici une proposition, il y a certainement plus efficace que faire 3 codes distinct associés à chaque bouton mais il faudrait en savoir plus sur ton fichier. Donc en l'état, ton bouton Français doit être lié à la macro AfficheFr, ton bouton Allemand à la macro AfficheDe, etc.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub AfficheFr()
 
Dim i As Long, NbLeg As Long
Dim ob As Object
 
NbLeg = Sheets("sheet2").Cells(Columns(1).Cells.Count, 1).End(xlUp).Row
 
For i = 1 To NbLeg
    For Each ob In UserForm1.Controls
        If ob.Name = "Label" & i Then
            ob.Caption = Sheets("sheet2").Cells(i, 1)
        End If
    Next ob
Next i
UserForm1.Show
 
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub AfficheDe()
 
Dim i As Long, NbLeg As Long
Dim ob As Object
 
NbLeg = Sheets("sheet2").Cells(Columns(2).Cells.Count, 2).End(xlUp).Row
 
For i = 1 To NbLeg
    For Each ob In UserForm1.Controls
        If ob.Name = "Label" & i Then
            ob.Caption = Sheets("sheet2").Cells(i, 2)
        End If
    Next ob
Next i
UserForm1.Show
 
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub AfficheGB()
 
Dim i As Long, NbLeg As Long
Dim ob As Object
 
NbLeg = Sheets("sheet2").Cells(Columns(3).Cells.Count, 3).End(xlUp).Row
 
For i = 1 To NbLeg
    For Each ob In UserForm1.Controls
        If ob.Name = "Label" & i Then
            ob.Caption = Sheets("sheet2").Cells(i, 3)
        End If
    Next ob
Next i
UserForm1.Show
 
End Sub

**danbo52** · 01/10/2009, 13h22

Merci pour ta réponse rapide.
Je fais un test et je réponds, j'espère au plus tôt cet a.midi ou ce soir... à moins que j'ai 5 mn là.

Danbo

**aalex_38** · 01/10/2009, 13h29

Plutot que trois procédure, une seule avec un paramètre peux suffire.

**danbo52** · 01/10/2009, 13h57

le Userform dispose de boutons et de zones de textes
Pour faciliter la tache des programmeur (maintenance) et des utilisateurs, chaque bouton porte le nom de la fonction qu'il gère.
Par exemple, le bouton d'importation de données s'appelle 'ImportDonnees', et c'est ainsi pour tout, boutons et zones de texte.
Il n'y a donc pas de Label1, 2, 3 ...
Tout doit être explicite pour la maintenance du code.

Je suis très pointilleux là dessus, j'aime commenter et libeller de manière à ce qu'un néophyte comme un professionnel puisse travailler sans chercher le sens du code durant des heures.

Excel ne reconnait pas la forme 'ob.caption' que tu m'as proposée, sans me répondre sur le type d'erreur.

Petite précision que j'avais énoncé au début, je souhaite aussi disposer d'une scrutation en relatif des 'userform', et non en dur. Je m'explique:

au lieu d'écrire Userform1.propriétés....
je préférerai écrire
("Userform" & indice).propriétés....

---------------------

AALEX 38 , c'est bien ce que je pensais aussi !

Fvandermeulen,

le ob.Caption répond que l'objet n'est pas le Userform mais le fichier actif (qui en l'occurence s'appelle objet1.xls)

**Fvandermeulen** · 01/10/2009, 14h10

Re,
La piste proposée était selon mes questions, tu peux toujours utiliser l'ordre des éléments de ton userform pour autant que ce soit plus ou moins logique (ou d'ajouter le numéro d'ordre sur ta feuille 2)
Je reste dans les suppositions car je n'arrive pas a avoir une d'idée clair de ton classeur. (c'est d'ailleurs pourquoi il y avait trois procédure et pas une)
Premier principe la suite est logique; Label-Bouton,Label-Bouton; tu fais une boucle avec step 2
Deuxième en bouclant sur les lignes de ta feuilles 2 tu récupère en variable le numéro de l'élément

Pour ce qui est du userform récupéré 'dynamiquement' théoriquement pas de problème mais qu'est-ce qui va définir ton K de ton exemple ?

Sinon pour le problème de Ob.caption, j'avoue que je sèche chez moi ça passait bien...

A+

Edit: Je viens de voir ton poste avec ton test sur Ob, l'as tu bien utiliser dans une une boucle de type:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each ob In UserForm1.Controls

Ce qui précise qu'on ne regarde que les objets dans les controles du userform.

**danbo52** · 01/10/2009, 14h27

Fvandermeulen

Oui, je boucle bien en appelant le userform, mais Excel me répond qu'il s'agit du classeur, car il bloque sur cette ligne, justement.
Il ne reconnait pas le Userform, à priori.

Je regarde autant dans les déclarations que dans la méthode d'appel.

**laetitia** · 01/10/2009, 17h33

bonjour danbo52 Fvandermeulen l'ami aalex le forum
comme j' ai compris!!!! code dans la feuille1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Option Explicit
Dim i As Byte, j As Control, x As Byte, z As Byte
 
Private Sub CommandButton1_Click()
UserForm1.Show
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub CommandButton2_Click()
z = 1
Affic
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub CommandButton3_Click()
z = 2
Affic
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub CommandButton4_Click()
z = 3
Affic
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Affic()
With Sheets(2)
x = 1
For Each j In UserForm1.Controls
If TypeOf j Is MSForms.CommandButton Then
j.Caption = .Cells(x, z)
x = x + 1
End If: Next: End With
End Sub

ps tu es pas oblige de ouvrir userform1 avant click sur tes 3 boutons.

**danbo52** · 01/10/2009, 17h56

merci Laetitia et les autres...

mais, 1 petite chose non résolue:

peut-on passer un Userform en variable comme ceci:

.....("Userform" & indice)...... ?

Mais je ne reste ps les bras croisés, je teste encore, et en fonction des propriétés trouvées dans l'aide Excel et le Web.

**laetitia** · 01/10/2009, 18h42

re, peut être comme cela a tester ???

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim z As String
 z = "UserForm2"
VBA.UserForms.Add(z).Show

ou encore

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim z As String, x As Byte
z = "UserForm"
x = 2
VBA.UserForms.Add(z & x).Show

**danbo52** · 01/10/2009, 19h25

Merci à vous,

Ca avance bien, il me reste l'affectation de valeur.

Question après différents tests:

Comment affecter une valeur 'trad' à un contrôle de Userform ?
J'ai tenté ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

VBA.UserForms.Add(U & "." & typeComposant) = trad

où U = "Userform" & indice
et typeComposant = Nom du bouton (dans ce cas)
trad = "Open File Only", je mets la traduction de "Ouvrir le fichier seulement" qui est la légende du bouton.

Faut-il explicitement anoncer entre U et typeComposant, le bouton , et comment, car 'CommandButton' ne donne rien , comme ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

VBA.UserForms.Add(U & "." & "CommandButton." & typeComposant) = trad

**laetitia** · 01/10/2009, 19h58

re ,comme je comprends sans "cliker" sur un user pas forcement charge (load) tu veus ouvrir classeur en lecture seule dont la reference & le caption d'un commanbutton ????

**danbo52** · 01/10/2009, 20h14

Pour simplifier et etre clair:

J'ai un classeur ouvert avec une feuille 'feuil1' qui possède 3 boutons 'francais','anglais' et 'allemand'.
Lorsque je clique sur l'un de ces 3 boutons, le code change les légendes des boutons du 'Userform' que j'ai créé, soit les boutons ont des légendes en francais si j'ai cliqué francais, allemand si j'ai cliqué sur allemand, soit anglais si j'ai cliqué anglais.

L'idée,c'est de lire des colonnes d'une feuil2 du classeur dans laquelle il y a les traductions des légendes.

Le problème est de savoir comment affecter ces légendes aux boutons du userform ?

**laetitia** · 01/10/2009, 21h30

re pour exemple j' ajoute une listbox ou combobox dans userform1
j'ai pris listbox
clic sur commandbutton1 caption ="a" pour l'exemple
je me refere au caption du commandbutton1 de userform1
les donnees sont dans colonne d de la sheets (2)

idem pour le commandbutton2 donnee dans la colonne e

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Option Explicit
Dim t As Variant
Private Sub CommandButton1_Click()
If CommandButton1.Caption = "a" Then
With Sheets(2)
t = .Range("d1:d" & .Range("d65536").End(xlUp).Row)
ListBox1.List = t
End With: End If
End Sub
 
Private Sub CommandButton2_Click()
If CommandButton2.Caption = "b" Then
With Sheets(2)
t = .Range("e1:e" & .Range("e65536").End(xlUp).Row)
ListBox1.List = t
End With: End If
End Sub

pour faire simple j'exploite le caption du bouton de l'user..

par contre beaucoup de boutons sur userform1 il faut passer par un module de classe pour simplifier le code

**danbo52** · 01/10/2009, 22h12

Merci Laetitia,

J'ai pensé à cette solution, mais dans le projet sur lequel je travaille, absolument tous les textes et libellés doivent pouvoir être traduits, sur toutes les 'feuil', dans tous les Userforms.
C'est la raison pour laquelle je me suis appuyé sur la première feuil du classeur pour réaliser les manips du code, comme si elle était la référence du code de taduction.
Mais toutes les listes des termes sont ne fait dans la feuil2.
Derrière, il va y avoir plusieurs userforms.
----------------------------------------------------------------------
MAIS, J'essaie de manigancer une voie parallèle en configurant autrement mes userforms, c'est-à-dire, en appliquant pour chaque bouton 3 couches:
- une couche rectangle gris
- une couche etiquette (label) qui supportera les textes traduits
- une couche bouton transparent qui recevra le code

Ainsi, en ne gérant que les 'labels', je me soustrais de la recherche de l'identification des typeof bouton, combobox, etc...

j'affecte une variable à chaque userform afin de faire les traductions selon une arborescence simple.
----------------------------------------------------------------------
Je programme ça dès Samedi, car demain je suis occupé sur un autre code chez un client.

Merci pour votre persévérance, et les éclairages de Laetitia.

suite....un peu plus tard !

**Pierre Fauconnier** · 02/10/2009, 05h57

Bonjour

Je ne suis pas certain de tout comprendre, mais je pencherais pour

clic sur le bouton de la langue => mémorisation de la langue dans une variable publique.
A l'initialisation d'un userform => on récupère la langue choisie et on adapte les caption

Mise en place
Dans une feuille de calcul, créer une plage de 4 colonnes (Nom/Français/Anglais/allemand (dans cet ordre)), insérer les noms des contrôles et les valeurs, nommer la plage Controles

Créer le userform de choix de la langue, et attribuer la valeur souhaitée à une variable publique (Langue, en l'occurrence)

Dans un module public

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Public Enum eLangue
    eLangueFrancais = 1
    eLangueAnglais = 2
    eLangueallemand = 3
End Enum
 
Public Langue As eLangue
 
Sub GetCaption(Controle As Control)
    Dim Cellule As Range
 
    Set Cellule = shControles.Range("controles").Columns(1).Cells.Find(what:=Controle.Name, LookIn:=xlValues, lookat:=xlWhole)
    If Not Cellule Is Nothing Then Controle.Caption = Cellule.Offset(0, Langue)
End Sub

Dans le code de chaque userform

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub UserForm_Initialize()
    Dim Controle As Control
 
    For Each Controle In Controls
        GetCaption Controle
    Next Controle
End Sub

Ainsi, les contrôles sans caption ne posent pas de problème car non présents dans la liste.

Dans le classeur exemple, j'ai mis une petit routine pour simuler le clic sur le bouton de la langue. La plage des contrôles est dynamique (DECALER)

http://fauconnier.developpez.com/for...rs/langues.xls

**danbo52** · 02/10/2009, 21h55

Bonsoir Pierre,

bien vu la manip
Je l'essaie dès que possible
C'est certainement plus pratique que de vouloir tout faire à partir des boutons de langues du classeur.
Chaque Userform fait sa popote pour convertir les labels dans la langue choisie.

Je te dirais cela demain tard ou après.

sincèrement, et aux autres participants...

**danbo52** · 09/10/2009, 23h23

Je viens de faire un test qui a 'foiré', je reconsidère le fonctionnement de Enum avec le Set, et je te redis ça.

Bon week end

**Pierre Fauconnier** · 10/10/2009, 07h51

Petite précision que je n'avais pas donnée:

Il faut que les noms des contrôles soient uniques pour le classeur. On pourrait les rendre uniques par userform, mais il faudrait adapter la procédure et cela risquerait de ralentir la conception du userform lors de son initialisation.

**helas** · 10/10/2009, 12h13

Bonjour,
voici un exemple
Le principe est la numérotation des controles
L1, L2, L3 pour les boutons des langues
o1, o2, o3, ... pour les controls des formulaires

Bouton de UserForm mis en variable

Macros et VBA Excel

Discussions similaires

Partager

Partager