Importation fichier texte avec DoCmd.Transfertext

**clemini** · 30/07/2009, 11h58

Bonjour,

Je cherche à importer automatiquement dans Access un fichier texte au format personnalisé ("ITI Ipc Spécification d'importation"), mais au chemin d'accès non figé.

J'ai pour cela fait une macro de façon automatique directement dans Access (grâce à l'action TransférerTexte), mais je n'ai alors pas le choix du chemin d'accès.

J'essaie donc de faire un module avec l'objet DoCmd ce qui me donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
DoCmd.TransferText acImportDelim, "ITI Ipc Spécification d'importation", "ITI", "chemin d'accès que je souhaite non fixe", -1

Là j'ai deux problèmes que je n'avais pas à résoudre malgré mes recherches sur internet ! Car je débute !

1) comment faire pour qu'une boîte de dialogue s'ouvre me proposant le fichier à choisir => comment faire pour me donner le choix du chemin d'accès.

2) comment faire en sorte que tout cela marche dans une macro automatique ? Grâce à l'action ExécuterApplication ? J'essaie en tapant ma ligne de commande ci-dessus, mais cela ne fonctionne pas (ce serait trop simple !

, je me doute que c'est plus compliqué ).

Pourriez-vous m'apporter votre aide s'il vous plaît ? Je patauge !

D'avance merci pour vos réponses.

Clemini.

**clemini** · 30/07/2009, 15h58

Re-bonjour,

j'ai résolu à forces de recherche le problème numéro 2)
Reste le 1) sur lequel je sèche... si vous avez des réponses

Merci !
Clémini

**clemini** · 30/07/2009, 16h02

Je vous mets mon code au cas où :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Function import()

DoCmd.TransferText acImportDelim, "monformatdimport", "monnomdetable", "monchemindaccesfixe", True

End Function

Et j'appelle cette fonction dans une macro automatique grâce à l'action ExécuterCode (qui sera complétée par d'autres actions ensuite)

Il me reste juste à rajouter ce qui me permettra d'ouvrir une boîte de dialogue pour choisir mon fichier à importer !

Merci !
Clémini

**Didier71** · 30/07/2009, 21h30

Bonsoir

Utilise cette fonction toute faite, trouvée sur ce même site

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
Option Compare Database
 
  'Déclaration de l'API
Private Declare Sub PathStripPath Lib "shlwapi.dll" Alias "PathStripPathA" (ByVal pszPath As String)
Private Declare Function GetOpenFileName Lib "comdlg32.dll" Alias _
                   "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long
 
 'Structure du fichier
Private Type OPENFILENAME
    lStructSize As Long
    hwndOwner As Long
    hInstance As Long
    lpstrFilter As String
    lpstrCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    lpstrFile As String
    nMaxFile As Long
    lpstrFileTitle As String
    nMaxFileTitle As Long
    lpstrInitialDir As String
    lpstrTitle As String
    flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    lpstrDefExt As String
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type
 
 'Constantes
Private Const OFN_READONLY = &H1
Private Const OFN_OVERWRITEPROMPT = &H2
Private Const OFN_HIDEREADONLY = &H4
Private Const OFN_NOCHANGEDIR = &H8
Private Const OFN_SHOWHELP = &H10
Private Const OFN_ENABLEHOOK = &H20
Private Const OFN_ENABLETEMPLATE = &H40
Private Const OFN_ENABLETEMPLATEHANDLE = &H80
Private Const OFN_NOVALIDATE = &H100
Private Const OFN_ALLOWMULTISELECT = &H200
Private Const OFN_EXTENSIONDIFFERENT = &H400
Private Const OFN_PATHMUSTEXIST = &H800
Private Const OFN_FILEMUSTEXIST = &H1000
Private Const OFN_CREATEPROMPT = &H2000
Private Const OFN_SHAREAWARE = &H4000
Private Const OFN_NOREADONLYRETURN = &H8000
Private Const OFN_NOTESTFILECREATE = &H10000
 
Private Const OFN_SHAREFALLTHROUGH = 2
Private Const OFN_SHARENOWARN = 1
Private Const OFN_SHAREWARN = 0
 
 
Public Function OuvrirUnFichier(Handle As Long, _
                                Titre As String, _
                                TypeRetour As Byte, _
                                Optional TitreFiltre As String, _
                                Optional TypeFichier As String, _
                                Optional RepParDefaut As String) As String
 'OuvrirUnFichier est la fonction a utiliser dans votre formulaire pour ouvrir _
 'la boîte de dialogue de sélection d'un fichier.
 'Explication des paramètres
    'Handle = le handle de la fenêtre (Me.Hwnd)
    'Titre = Titre de la boîte de dialogue
    'TypeRetour (Définit la valeur, de type String, renvoyée par la fonction)
        '1 = Chemin complet + Nom du fichier
        '2 = Nom fichier seulement
    'TitreFiltre = Titre du filtre
        'Exemple: Fichier Access
        'N'utilisez pas cet argument si vous ne voulez spécifier aucun filtre
    'TypeFichier = Extention du fichier (Sans le .)
        'Exemple: MDB
        'N'utilisez pas cet argument si vous ne voulez spécifier aucun filtre
    'RepParDefaut = Répertoire d'ouverture par defaut
        'Exemple: C:\windows\system32
        'Si vous laissé l'argument vide, par defaut il se place dans le répertoire de votre application
 
Dim StructFile As OPENFILENAME
Dim sFiltre As String
 
 'Construction du filtre en fonction des arguments spécifiés
If Len(TitreFiltre) > 0 And Len(TypeFichier) > 0 Then
  sFiltre = TitreFiltre & " (" & TypeFichier & ")" & Chr$(0) & "*." & TypeFichier & Chr$(0)
End If
sFiltre = sFiltre & "Tous (*.*)" & Chr$(0) & "*.*" & Chr$(0)
 
 
 'Configuration de la boîte de dialogue
  With StructFile
    .lStructSize = Len(StructFile) 'Initialisation de la grosseur de la structure
    .hwndOwner = Handle 'Identification du handle de la fenêtre
    .lpstrFilter = sFiltre 'Application du filtre
    .lpstrFile = String$(254, vbNullChar) 'Initialisation du fichier '0' x 254
    .nMaxFile = 254 'Taille maximale du fichier
    .lpstrFileTitle = String$(254, vbNullChar) 'Initialisation du nom du fichier '0' x 254
    .nMaxFileTitle = 254  'Taille maximale du nom du fichier
    .lpstrTitle = Titre 'Titre de la boîte de dialogue
    .flags = OFN_HIDEREADONLY  'Option de la boite de dialogue
    If ((IsNull(RepParDefaut)) Or (RepParDefaut = "")) Then
        RepParDefaut = CurrentDb.Name
        PathStripPath (RepParDefaut)
        .lpstrInitialDir = Left(CurrentDb.Name, Len(CurrentDb.Name) - Len(Mid$(RepParDefaut, 1, _
InStr(1, RepParDefaut, vbNullChar) - 1)))
        Else: .lpstrInitialDir = RepParDefaut
    End If
  End With
 
If (GetOpenFileName(StructFile)) Then 'Si un fichier est sélectionné
    Select Case TypeRetour
      Case 1: OuvrirUnFichier = Trim$(Left(StructFile.lpstrFile, InStr(1, StructFile.lpstrFile, vbNullChar) - 1))
      Case 2: OuvrirUnFichier = Trim$(Left(StructFile.lpstrFileTitle, InStr(1, StructFile.lpstrFileTitle, vbNullChar) - 1))
    End Select
  End If
 
End Function

Ensuite, tu l'appelles sur un fomulaire, par exemple comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

  ChoixFichier = OuvrirUnFichier(Me.Hwnd, "Message boite dialogue a personnaliser", 2, "Format de fichier désiré exemple :Texte", "Extension : exemple TXT", "Si vide, répertoire par défaut.)

Les paramètres sont expliqués dans le corps de la fonction..

Dans mon exemple, ChoixFichier est la variable qui recueille le nom du fichier et ou le chemin complet.
Ensuite, tu fais ton traitement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DoCmd.TransferText acImportDelim, "monformatdimport", "monnomdetable", etc

avec la variable ChoixFichier à la place du nom de fichier..

J'espère que ça t'aidera

Bon courage
Didier71

**fgiambelluco** · 31/07/2009, 08h31

Bonjour
Pour choisir un fichier, il y a peut être plus simple.
J'ai utilisé le code ci-dessous qui lors d'un import de fichier texte, permet de choisir le fichier à importer.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
    Dim oFile As FileDialog, txtCheminFichier As String
 
    Set oFile = Application.FileDialog(msoFileDialogOpen)
    oFile.AllowMultiSelect = False
    If oFile.Show = -1 Then ' bouton ouvrir
        txtCheminFichier = oFile.SelectedItems(1)
    End If

**clemini** · 31/07/2009, 10h24

Merci beaucoup à tous les deux !

Didier, quand tu dis appeler sur un formulaire le code :

ChoixFichier = OuvrirUnFichier(Me.Hwnd, "Message boite dialogue a personnaliser", 2, "Format de fichier désiré exemple :Texte", "Extension : exemple TXT", "Si vide, répertoire par défaut.)

C'est-à-dire concrètement ?

Je dois créer un formulaire avec un bouton de commande etc, ou y a t-il une simple ligne de code spécifique à intégrer dans une nouvelle fonction ou nouvelle sub ? J'ai vu sur internet des choses sur l'application DoCmd. OpenForm. Est-ce de ça qu'il s'agit.

D'avance merci !
Clémentine.

**clemini** · 31/07/2009, 10h46

Encore une question à Frédéric cette fois

Comment placer dans ma fonction tes lignes de code ? Je n'arrive pas à le faire marcher.

Merci encore.
Clémentine.

**fgiambelluco** · 31/07/2009, 11h07

A essayer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Function import()
    Dim oFile As FileDialog, txtCheminFichier As String
 
    Set oFile = Application.FileDialog(msoFileDialogOpen)
    oFile.AllowMultiSelect = False
    If oFile.Show = -1 Then ' bouton ouvrir
        txtCheminFichier = oFile.SelectedItems(1)
      DoCmd.TransferText acImportDelim, "monformatdimport", "monnomdetable", txtCheminFichier,True
   End If
End Function

**clemini** · 31/07/2009, 11h17

Merci.
J'ai déjà essayé ainsi et il me dit qu'il y a une erreur de compilation au niveau du type défini par l'utilisateur non défini sur "oFile As FileDialog".

**fgiambelluco** · 31/07/2009, 11h21

Il faut vérifier que dans Outils/Références la bibilothèque Microsoft Office xx Object Library est cochée

**clemini** · 31/07/2009, 11h38

ça marche !!!! génial merci mille fois !

Vous avez illuminé ma journée (rien que ça !)

Clémentine.

Importation fichier texte avec DoCmd.Transfertext [AC-2003]

VBA Access

Discussions similaires

Partager

Partager