Discussion :

[Kiphrine]

Bonjour,
Je souhaiterais enregistrer une plage définie d’un tableau via un bouton sur un répertoire prédéfini. Ex. Enregistrer par clic la plage (A1 :L34) dans le répertoire : C:\Documents and Settings\Administrateur\Mes documents\Mon classeur. Mais j'aimerais qu'à chaque fois qu'on cliquera sur le bouton alors la plage s'enregistrera dans un nouveau fichier excel avec comme nom: classeur_(suivi de la date en format anglais du jour de l'enregistrement).
Merci.

[Fvandermeulen]

Bonjour,
Voici un code qui devrait répondre à ton besoin, tu verras que j'ai modifier l'aspect de la date en AAAA-M-J pour faciliter la lecture dans ton dossier et pour assurer une sauvegarde plus facile.
J'ai mis des commentaire pour que tu puisse comprende ce que le code fait.
Mais, ce code tu aurais pu le trouver en utilisant l'enregistreur de macro, ce qui est un bon moyend de progresser.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub ColleEtSauve()
'
Dim MaPlage As Range
 
LaDate = Year(Date) & "-" & Month(Date) & "-" & Day(Date) 'Variable qui prend la date du jour format aaaa-m-j
Set MaPlage = Range("A1:L34") 'Applique la plage voulue à la variable, changer le range pour changer la plage
 
    MaPlage.Copy 'Fait la copie de la zone voulue
    Workbooks.Add 'Ouvre un nouveau Fichier XL
    ActiveSheet.Paste 'Colle la sélection à copier sur la feuille active, donc la nouvelle
    'Fait la sauvegarde, la deuxième ligne en retrait reprend la variable avec la date
    ActiveWorkbook.SaveAs Filename:= _
        "C:\Documents and Settings\Administrateur\Mes documents\" _
        & LaDate & ".xls", _
        FileFormat:=xlNormal, Password:="", WriteResPassword:="", _
        ReadOnlyRecommended:=False, CreateBackup:=False
End Sub

Bonne continuation

[Kiphrine]

Merci Fvandermeulen! Pas facile ton pseudo!

[jolop35]

Bonjour la compagnie

Voici une autre proposition (adapté du code VBA précédent)

(ici ne copie que les valeurs seules
pour une copie "pleine" , changer ceci

With D_WKB.ActiveSheet
.Paste
With .UsedRange
.Value = .Value
End With
End With

en

D_WKB.ActiveSheet.Paste

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub ColleEtSauveII()
Dim D_WKB As Workbook, Chemin As String, NFic As String
Dim S_WKB As Workbook: Set S_WKB = ThisWorkbook
Dim MaPlage As Range
Set MaPlage = S_WKB.Worksheets(1).Range("A1:L34")
 
Chemin = "C:\Documents and Settings\Administrateur\Mes documents\"
NFic = "classeur_" & Format(Date, "yyyy-mm-dd") & ".xls"
Application.ScreenUpdating = False
MaPlage.Copy
Set D_WKB = Workbooks.Add(xlWBATWorksheet)
With D_WKB.ActiveSheet
    .Paste
        With .UsedRange
            .Value = .Value
        End With
End With
Application.CutCopyMode = False
D_WKB.SaveAs Chemin & NFic
D_WKB.Close True
Application.ScreenUpdating = True
End Sub

A+