Discussion :

[Contrec]

Bonjour,

Je suis confronté à un problème que je n'arrive pas à résoudre malgré mes recherches :

J'aimerai récupérer le nom d'une variable (string, double, integer...) dans une autre variable string comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim toto as Integer
Dim nomToto as String
 
nomToto = NomDeLaVariable(toto)

nomToto doit contenir "toto". Ceci doit fonctionner pour tout type de variable (string, integer, double).

Merci pour vos réponses.

[Jean-Philippe André]

Bonjour,

j'ai un doute, cherches-tu à récupérer la valeur d'une variable ou son nom ?

exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim piou as String
piou = "Pioupi"

tu veux trouver "piou" ou bien "Pioupi" ?

S'il s'agit du premier, je ne comprends pas l'intérêt ou l'objectif
S'il s'agit du second, un simple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Debug.Print piou

suffira

[Contrec]

Je veux récupérer "Piou", le nom de la variable et non sa valeur. Puisque tu te demandes quel interêt j'y apporte, je te réponds, peut-être auras-tu une meilleure solution à mon problème, je n'ai pas de contraintes :

Je possède des modules de classe dont voici un exemple simple, module mModuleTest :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private mPath As String
Private mNumber As Integer
 
Property Get Path() As String
    Path = mPath
End Property
 
Property Let Path(Path As String)
    mPath = Path
End Property
 
Property Get Number() As Integer
    Number= mNumber
End Property
 
Property Let Number(Number As Integer)
    mNumber = Number
End Property

Je voudrai faire un système permettant de sortir une collection de cet objet pour aire du débug dans un fichier Excel. Par exemple, j'ai une collection de cet objet :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim moduleTestList as Collection

Elle contient 3 objets mModuleTest :

1) - "Toto"
- 34

2) - "Tata"
- 45

3) - "Titi"
- 72

Je voudrai sortir ces 3 résultats dans un fichier excel avec comme nom de colonne "Path" et "Number". Pour faire cela, il ne me manque plus qu'à récupérer le nom des 2 variables et m'en servir pour les colonnes. Cette méthode doit s'adapter à tous les objets que j'ai (pas seulement à mModuleTest).

Voici le résultat final à sortir dans l'excel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Path    Number
Toto     34
Tata     45
Titi       72

Voilà

[Jean-Philippe André]

hum, pas convaincu, mais si le résultat attendu dans Excel est celui indiqué, il suffirait de faire une boucle for each + utilisation de mpath et mnumber.

Mis à part cela, pas la moindre idée

[Pierre Fauconnier]

Salut.

Je suis aussi perplexe que jpcheck (Salut JP)...

Si tu charges une collection d'objets, tu recherches l'objet sur sa clé d'entrée dans la collection puis tu exprimes ses propriétés, ou tu itères sur les objets de la collection...

Peux-tu préciser?

[Contrec]

En général je fais une boucle for each monObjet in moduleTestList.

Pour le contenu il n'y a pas de problème mais c'est pour les entêtes de colonne qu'il me faut récupérer le nom des variables membres de l'objet ("Path" et "Number" à mettre sur la première ligne de l'excel).

J'ai l'impression que l'on ne peut pas faire ce que je veux...

[Pierre Fauconnier]

Ok... Je commence à comprendre...

Tu veux pouvoir itérer sur toutes les propriétés de l'objet sans en connaitre les noms...?

Je pense que ce n'est possible que si la classe met une propriété de type "Properties" à disposition.

[Contrec]

Exact, d'une part je voulais itérer sur tous les membres (propriétés VBA) de mon objet, récupérer le nom des variables membres pour créer mes futurs noms de colonnes Excel.

Pas possible en VBA hein ?

[ilank]

Bonjour,
voilà deux pistes pour toi.

1) Tu peux aller lire le module de class de tes objets en récupérant le nom du module par un TypeName() sur une instance de l'objet.

2) Insérer dans chaque module de class une fonction WhoAmI renvoyant les noms de colonnes de l'objet.

[Contrec]

Merci de ta réponse, le TypeName va m'être bien utile, par contre le but était de ne pas avoir à écrire un code spécifique à chaque module, que tout soit dynamique quel que soit le module de classe.
Si ce n'est pas possible, possédant plus de 50 modules, ce sera trop lourd à écrire.

[ilank]

Bonjour,
c'est bien le but de mes propositions.
Le problème est que si tu ne connais pas le nom des colonnes; comment comptes-tu accèder à leur contenu ?

Voici un exemple de fonctions qui affiche le nom des colonnes d'un objet contenu dans la collection passé en paramètre. La fonction recherche les procédures Porperty Get en tant que libellé de colonne.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Public Function GetObjColName(Listing As Collection)
    Dim cbdVBComp As VBComponent, IsFound As Boolean, CurLigne As Long
    Dim ClsModule As CodeModule, ClsObjName As String, LibColonne() As String, colonne As Long, Message As String
'Si la collection est vide sortir
    If Listing.Count = 0 Then Exit Function
    ClsObjName = TypeName(Listing(1))
    Message = "Collection d'Objets : " & ClsObjName
'Rechercher le module de class des objets de la collection
   IsFound = False
   For Each cbdVBComp In Application.VBE.ActiveVBProject.VBComponents
    If cbdVBComp.Name = ClsObjName Then IsFound = True: Exit For
   Next
'Si le module de class est introuvable sortir
   If Not IsFound Then Exit Function
   Set ClsModule = Application.VBE.ActiveVBProject.VBComponents(ClsObjName).CodeModule
'Lire le module et rechercher les procédures Property Get
    With ClsModule
        colonne = 0
        CurLigne = .CountOfDeclarationLines + 1
        Do While CurLigne <= .CountOfLines
            If InStr(.Lines(CurLigne, 1), "Property Get") = 1 Then
                colonne = colonne + 1
                ReDim Preserve LibColonne(1 To colonne)
                LibColonne(colonne) = .ProcOfLine(CurLigne, vbext_pk_Get)
                Message = Message & vbCrLf & "Colonne " & colonne & ": " & LibColonne(colonne)
                CurLigne = CurLigne + .ProcCountLines(.ProcOfLine(CurLigne, vbext_pk_Get), vbext_pk_Get)
            End If
            CurLigne = CurLigne + 1
        Loop
    End With
   MsgBox Message
End Function

[DarkVader]

Bonjour,
Je crois «commencer» à comprendre cette fois-ci.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
' Ajouter une référence à Typelib information
Dim clsTLI As New TLI.TLIApplication
 
 
Sub EnumMemberClasse(uneClass As Object)
    Dim IInf As InterfaceInfo, m As MemberInfo
 
    Set IInf = clsTLI.InterfaceInfoFromObject(uneClass)
 
    For Each m In IInf.Members
        ' exemple de traitement
        Debug.Print m.Name, m.ReturnType
    Next
 
End Sub

S'il s'agissait de classes contenues dans une librairie, il faudrait passer par Typelibinfofromfile ou Typelibinfofromregistry.

Utilisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub test()
    Dim clsMyClass As New myClass   ' myClass : La classe à analyser
 
    EnumMemberClasse clsMyClass
End Sub

C'est ce que tu recherches ?

[Contrec]

Merci pour vos réponses, c'est bien cela que je cherche. J'ai adapté votre code pour que ça fonctionne dans mon cas précis.

Il ne me reste plus que la difficulté à boucler sur les valeurs des membres de l'objet :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
' Création d'un objet pour l'exemple.
Dim myObject as new cTest
 
' L'objet test a 2 variables membres Id en Integer et Name en string.
myObject.Id = 5
myObject.Name = "Toto"

Peux-ton faire un truc comme cela pour récupérer les données :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Msgbox(myObject.Cols(1).Value()) ' (Qui contient l'Id 5).
 
Msgbox(myObject.Cols(2).Value()) ' (Qui contient le nom "Toto").

[ilank]

bonjour,
Oui on peut avec l'instruction CallByname (object,procname,proctype)

Voici un exemple de code qui affiche par un msgbox les entêtes et les valeurs de chaque objet contenu dans la collection passé en paramètre.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Public Function GetObjInList(Listing As Collection)
    Dim TLIObj As New TLI.TLIApplication, MyObjImp As TLI.MemberInfo
    Dim LibColonne() As String, Message As String
    Dim colonne As Long, i As Long, ligne As Long
    Dim ListingItem As Object
 
'Si la collection est vide sortir
    If Listing.Count = 0 Then Exit Function
    colonne = 0
    Message = "Collection d'Objets : " & TypeName(Listing(1)) & " " & Listing.Count & IIf(Listing.Count > 1, " items", " item")
'Récupération de l'entête des colonnes
    For Each MyObjImp In TLIObj.InterfaceInfoFromObject(Listing(1)).Members
'Recherche des membres Property Get en tant qu'entête de colonne
        If MyObjImp.InvokeKind = 2 Then
            colonne = colonne + 1
            ReDim Preserve LibColonne(1 to colonne)
            LibColonne(colonne) = MyObjImp.Name
            Message = Message & IIf(colonne = 1, vbCrLf & vbCrLf, "") & vbTab & LibColonne(colonne)
        End If
    Next
'Si aucune colonne trouvée sortir
If colonne = 0 Then Exit Function
'Récupération des valeurs des colonnes pour tous les objets de la collection
    For Each ListingItem In Listing
        Message = Message & vbCrLf
        ligne = ligne + 1
        For i = 1 To colonne
            Message = Message & IIf(i = 1, ligne, "") & vbTab & CallByName(ListingItem, LibColonne(i), VbGet)
        Next i
    Next
    MsgBox Message
End Function

[Contrec]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Message = Message & IIf(i = 1, ligne, "") & vbTab & CallByName(ListingItem, LibColonne(i), VbGet)

C'est exactement ça que je recherche, j'essaye tout ça ce matin et je vous tiens au courant, merci beaucoup.

[DarkVader]

Ilank ,
Comme quoi avec VB/VBA il est difficile de dire "ce n'est pas possible".

[Pierre Fauconnier]

J'aurai encore appris quelque chose de bien utile... Merci!