Discussion :

[froggyaz]

Bonjour,

Je voudrais savoir comment changer les proprietes d'un certain nombre de textbox (leur fond de couleur en l'occurence) contenus dans un document word a partir d'une liste sous excel. Voila un example ci-dessous avec 3 villes mais j'en ai en tous une cinquantaine et le chiffre augmentera surement, d'ou l'automatisation.

colonne A
----------
Nantes
Paris
Toulouse

colonne B
----------
34
68
28

nom de textbox sous word
-------------------------
TextBoxNantes
TextBoxParis
TextBoxToulouse

couleur de fond de la TextBox
----------------------------
RGB(0,34/100*255,255)
RGB(0,68/100*255,255)
RGB(0,28/100*255,255)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub CommandButton1_Click()
Dim i As Integer
Dim inhib As Integer
Dim wdapp As Object
Dim target As String
 
    For i = 1 To 3 
        target = Cells(i, "A").Value
 
        With wdapp
            TextBox("target").BackColor = RGB(0, inhib, 255)
        End With
 
    Next i
End Sub

Merci pour votre aide.
Fred.

juste une precision: il s'agit de textbox inserees et a utiliser sous l'editeur VBA dans word et non des formes "textbox" inserees depuis word directement quand on on clique sur l'onglet "inserer".
Merci.
Fred

[PMO2017]

Bonjour,

Une démarche un peu compliquée

1) Dans Word, créez dans C:\ un .doc nommé "froggyaz" et y ajouter 3 TextBox nommées
TextBoxNantes
TextBoxParis
TextBoxToulouse

2) Dans Excel, nommez une feuille "test" et inscrire à partir de A1
Nantes
Paris
Toulouse
et à partir de B1
34
68
28

3) Copiez le code suivant dans un module standard. Montez les références requises indiquées en tête du code (selon votre version de Word 11.0 ou xx.0)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
'°°° Monter les références suivantes  °°°
'''Library Word
'''C:\Program Files\Microsoft Office\OFFICE11\MSWORD.OLB
'''Microsoft Word 11.0 Object Library
 
'''Library MSForms
'''C:\WINDOWS\system32\FM20.DLL
'''Microsoft Forms 2.0 Object Library
'°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
 
'### Constante à adapter ###
Const DOC_WORD = "C:\froggyaz.doc"
Const MA_FEUILLE = "test"
'###########################
 
Const TEXTBOX_TYPE As String = "Forms.TextBox.1"
 
Private Sub CommandButton1_Click()
Dim i&
Dim j&
Dim cpt&
Dim inhib As Integer
Dim myDoc As Word.Document
Dim ILS As Word.InlineShape
Dim TB() As Object  'MSForms.TextBox
Dim S As Worksheet
Set myDoc = GetObject(DOC_WORD)
For Each ILS In myDoc.InlineShapes
  If ILS.OLEFormat.ClassType = TEXTBOX_TYPE Then
    cpt& = cpt& + 1
    ReDim Preserve TB(1 To cpt&)
    Set TB(cpt&) = ILS.OLEFormat.Object
  End If
Next ILS
Set S = Sheets(MA_FEUILLE)
For i& = 1 To S.[a65536].End(xlUp).Row
  For j& = 1 To cpt&
    If UCase("TextBox" & S.Range("A" & i& & "")) = UCase(TB(j&).Name) Then
      inhib = S.Range("B" & i& & "")
      TB(j&).BackColor = RGB(0, inhib / 100 * 255, 255)
      Exit For
    End If
  Next j&
Next i&
myDoc.Save
myDoc.Parent.Quit
Set myDoc = Nothing
End Sub

Il n'y a plus qu'à lancer la macro.

Cordialement.

PMO
Patrick Morange