Discussion :

[dawood]

Hello!

J'ai ce code que fait un copier / coller d'une plage de cellules dans un autre workbook :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Workbooks.Open Filename:=chemin, ReadOnly:=True
Workbooks(nomfichiersource).Activate
Worksheets(semainefeuille).Range(Cells(starty, 73).Address, Cells(endy, 256).Address).Select
 
Workbooks(nomfichiercible).Activate
Worksheets("base").Cells(destination, 1).Activate
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
Selection.PasteSpecial Paste:=xlPasteFormats
 
Workbooks(nomfichiersource).Close False

Ce code ne fonctionne pas dans excel 2000. Il met une erreur sur la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets(semainefeuille).Range(Cells(starty, 73).Address, Cells(endy, 256).Address).Select

Dans mon cas,
chemin = le chemin du fichier à copier
semainefeuille = "13. - 19.10.08"
starty = 756
endy = 759
destination = 1

Ca serait super si vous pouvez m'aider!

[decondelite]

C'est ton Range qui ne va pas: il faut lui renseigner 2 cellules, et non pas 2 adresses de cellules (c'est peut-être pas clair pour toi mais c'est totalement différent).

A la place de ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range(Cells(starty, 73).Address, Cells(endy, 256).Address)

Mets ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range(Cells(starty, 73), Cells(endy, 256))

[dawood]

Merci de ta réponse!

J'ai changé et mis :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets(semainefeuille).Range(Cells(starty, 73), Cells(endy, 256)).Select

Mais il me donne toujours une erreur sur la même ligne

Si ça peut aider, le numéro d'erreur est 1004...

[fring]

Bonjour,

Lorsqu'on insère des cells dans la syntaxe

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets(1).Range(...)

il faut également attribuer la feuille aux cells

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets(semainefeuille).Range(Worksheets(semainefeuille).Cells(starty, 73), Worksheets(semainefeuille).Cells(endy, 256)).Select

Ce type de syntaxe étant un peu indigeste à lire, on peut faire ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim Wsh As Worksheet
Set Wsh = Worksheets(semaine feuille)
 
Wsh.Range(Wsh.Cells(starty, 73), Wsh.Cells(endy, 256)).Select

Autre point, il n'est pas nécessaire d'utiliser une multitude de "Select" et "Activate"
Le code peut s'écrire comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Dim Wcible As Workbook, Wsource As Workbook
Dim Ssource As Worksheet, Scible As Worksheet
Application.ScreenUpdating = False
 
Set Wsource = Workbooks.Open(Filename:=chemin, ReadOnly:=True)
Set Ssource = Wsource.Sheets(semainefeuille)
Set Wcible = Workbooks(nomfichiercible)
Set Scible = Wcible.Sheets("base")
 
Ssource.Range(Ssource.Cells(starty, 73), Ssource.Cells(endy, 256)).Copy Scible.Cells(Destination, 1)
 
Wsource.Close False
Application.ScreenUpdating = True

[dawood]

Merci ça fonctionne parfaitement après avoir modifié encore 2-3 choses,