Export table access vers csv

**sphinx18** · 09/10/2008, 20h42

Bonjour,

J'ai table sous Access, et j'aurais voulu savoir s'il y avait
moyen, et comment (outre le simple copier / coller) d'exporter les données
de ce table en csv.

Merci

Invité · 09/10/2008, 21h26

Bonsoir
Fonction que j'utilise.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
 
 
' exportation d'une requête SQL ou table vers un fichier
' format csv avec séparateur optionnel
Public Function ExportCsv(SQL As String, File_name As String, Optional ByVal sep As _
                                                              String = ",", Optional ByVal Quote As String = "", Optional ByVal WithFields As Boolean = False) As Boolean
 
    Dim line As String, I As Long
    Dim rst As Recordset, fld As Field
 
    On Error GoTo ExportCsv_Error
 
    ' connection pour un projet access ADP :
    'Set rst = CurrentProject.Connection.Execute(SQL)
    ' connection pour un projet access MDB :
    Set rst = CurrentDb.OpenRecordset(SQL)
    Open File_name For Output As #1
 
    If WithFields Then  ' les noms de champ si demandé
        line = ""
        For Each fld In rst.Fields
            line = line & sep & Quote & fld.Name & Quote
        Next
        Print #1, Mid(line, Len(sep) + 1)
    End If
 
    Do Until rst.EOF
        line = ""
        For I = 0 To rst.Fields.Count - 1
            line = line & sep & Quote & Nz(rst(I).Value) & Quote
        Next I
        Print #1, Mid(line, Len(sep) + 1)
        rst.MoveNext
    Loop
    rst.Close
    Close #1
 
    ExportCsv = True
    Exit Function
 
ExportCsv_Error:
 
    MsgBox "Error " & err.Number & " (" & err.Description & _
           ") in Function ExportCsv of Module mdFunctions", vbCritical
End Function

Et après tu apelles ta fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
    Call ExportCsv("SELECT *  From Matable", CurrentProject.Path & "\NomFichier.csv", , , True)

A adapter en fonction de ta requête et de ton fichier de destination.

Bon Courage

**sphinx18** · 10/10/2008, 12h10

Un grand merci GAYOT

, je vais la tester

**neoboy** · 05/12/2012, 10h18

Bonjour GAYOT,

J'ai un souci avec la fonction.
En effet , lors de l'exécution j'ai une message d'erreur : ERROR 3141 dans lintruction SELECT , un mot réservé ou un argument est mal orthographié ou absent !

je ne comprends , connais -tu ce problème ?

merci d'avance

Invité · 05/12/2012, 10h44

Bonjour
Peux tu indiquer ta ligne de commande?

**neoboy** · 05/12/2012, 11h10

Bonjour,

Sub extraction()
Call ExportCsv("SELECT *,From load", CurrentProject.Path &
"\alex.csv", , , True)
End Sub

**fclus** · 05/12/2012, 11h38

Il y a une virgule qui traine devant le From

**zoom61** · 05/12/2012, 11h39

Salut,

Envoyé par neoboy

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub extraction()
Call ExportCsv("SELECT *,From load", CurrentProject.Path &
"\alex.csv", , , True)
End Sub

Il y a une virgule avant le FROM.

Et par rapport à la fonction de GAYOT, attention sa fonction met une , comme séparateur, alors que beaucoup de fichiers CSV ont le séparateur ;, n'oubliez pas de le changer en fonction de vos besoins.

@+.

**neoboy** · 05/12/2012, 11h55

OK la procédure me donne exactement le même résultat que le enregistrer sous.
Je souhaiterai ne pas passer à la ligne à chaque fois et avoir des points virgule entre les lignes du fichier.

Pourriez-vous me dire quoi changer la procédure pour avoir ce résultat ?
merci bcp pour votre aide.

Invité · 05/12/2012, 12h00

Zoom61 a raison, mais même le séparateur ";" pose problème quand il y a des champs avec des commentaires ou désignations longues. Il m'arrive régulièrement dans ce cas de mettre en séparateur le trait vertical "|". Celui là on a peu de chance de le retrouver dans un texte.

**neoboy** · 05/12/2012, 12h01

Si vous voulez j'ai maintenant un fichier qui ressemble à ça :

sex; age ; nom
F.23;alex

et je souhaite avoir un fichier :
sex; age ; nom;F.23;alex

**zoom61** · 05/12/2012, 12h01

Envoyé par neoboy

OK la procédure me donne exactement le même résultat que le enregistrer sous.
Je souhaiterai ne pas passer à la ligne à chaque fois et avoir des points virgule entre les lignes du fichier.

Pourriez-vous me dire quoi changer la procédure pour avoir ce résultat ?
merci bcp pour votre aide.

Tu peux procéder de la même façon qu'avec ton autre discussion, cela fonctionne avec une table ou une requête.

@+.

**neoboy** · 05/12/2012, 14h20

@zoom61

Honnêtement je n'ai pas pu faire tourner ta méthode , du coup je suis resté sur le premier code.

Il me reste un souci , je souhaiterai avoir un fichier csv qui ne saute pas ligne , je avoir toutes les données du fichier concaténées et séparées avec un ;

peux-tu me dire ce qu'il faut changer dans le code suivant pour abtenir ce résultat ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
If WithFields Then  ' les noms de champ si demandé
        line = ""
        For Each fld In rst.Fields
            line = line & sep & Quote & fld.Name & Quote
        Next
        Print #1, Mid(line, Len(sep) + 1)
    End If
 
    Do Until rst.EOF
        line = ""
        For I = 0 To rst.Fields.Count - 1
            line = line & sep & Quote & Nz(rst(I).Value) & Quote
        Next I
        Print #1, Mid(line, Len(sep) + 1)
        rst.MoveNext
    Loop
    rst.Close
    Close #1

**zoom61** · 05/12/2012, 14h30

Vu que je n'ai pas tout le code, peut-être ici :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Print #1, Mid(line, Len(sep) + 1) & ";"

**neoboy** · 05/12/2012, 14h34

oui oui , ça c'est déja fait , ça permet effectivement de mettre un ; à la fin de la ligne mais ne permet pas de rester sur la même ligne .

ce qui me dérange c'est le saut de ligne à chaque fois.

**zoom61** · 05/12/2012, 14h39

Remplace :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Do Until rst.EOF
line = ""
For I = 0 To rst.Fields.Count - 1
   line = line & sep & Quote & Nz(rst(I).Value) & Quote
Next I
Print #1, Mid(line, Len(sep) + 1)
rst.MoveNext
Loop

Par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
line = ""
Do Until rst.EOF
For I = 0 To rst.Fields.Count - 1
   line = line & sep & Quote & Nz(rst(I).Value) & Quote
Next I
rst.MoveNext
Loop
Print #1, Mid(line, Len(sep) + 1)

**neoboy** · 05/12/2012, 14h57

euuu ça ne marche pas trop , ça fait une boucle infinie .....

**zoom61** · 05/12/2012, 15h02

Ce que j'ai changé n'a rien à voir avec la boucle... j'ai juste sorti l'initialisation de la variable avant la boucle et l'écriture du résultat après la boucle...

**neoboy** · 05/12/2012, 15h05

ok , bon ça ne marche toujours pas malheureusement ! merci qd même

Export table access vers csv

IHM

Discussions similaires

Partager

Partager