Rechercher et remplacer un mot dans un module feuille

**modus57** · 02/10/2008, 00h10

Bonsoir le forum

Je souhaiterais rechercher et remplacer un mot dans un module Worksheet_SelectionChange" d'une feuille, voilà la procédure que j’ai testée et qui donne un résultat innatendu

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Sub ModifierModuleFeuille()
On Error Resume Next
   RechercherRemplacer ThisWorkbook, "Feuil1", "Worksheet_SelectionChange"
End Sub
 
Sub RechercherRemplacer(Wbk As ThisWorkbook, CodeMod$, NomProc$)
 
Dim Rechercher As String
Dim Remplacer As String
Dim Trouver As Integer
Dim I As Integer
 
Rechercher = "ScrollArea="
Remplacer = "'ScrollArea="
With Wbk.VBProject.VBComponents(CodeMod).CodeModule
    For I = 1 To .CountOfLines
        Trouver = InStr(.Lines(I, 1), Rechercher)
            If Trouver > 0 Then
            'si une occurrence est trouvée, fait la modif et boucle
            'sur la ligne afin de remplacer tous les mots
                Do
                  .ReplaceLine I, Left(.Lines(I, 1) _
                      , Trouver - 1) & Remplacer & _
                      Mid(.Lines(I, 1), _
                      Trouver + Len(Rechercher) _
                      , Len(.Lines(I, 1)))
                      Trouver = InStr(Trouver + 1, _
                      .Lines(I, 1), Rechercher)
                Loop While Trouver <> 0
            End If
    Next I
End With
 
End Sub

Pourriez-vous m’aider à corriger ce problème, merci d’avance

Cordialement modus57

**fring** · 02/10/2008, 01h10

Bonjour,

Essaie comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub ModifierModuleFeuille()
    RechercherRemplacer ThisWorkbook, "Feuil1", "Worksheet_SelectionChange"
End Sub
 
Sub RechercherRemplacer(Wbk As ThisWorkbook, CodeMod$, NomProc$)
    Dim Rechercher As String, Remplacer As String
    Dim i As Integer, Ligne As String
    Dim LigDebut As Integer, NbrLig As Integer
 
    Rechercher = "ScrollArea="
    Remplacer = "'ScrollArea="
 
    With Wbk.VBProject.VBComponents(CodeMod).CodeModule
        LigDebut = .ProcStartLine(NomProc, 0) '<-- ligne de début de la procédure "NomProc"
        NbrLig = .ProcCountLines(NomProc, 0) + LigDebut '<-- ligne de fin de la procédure "NomProc"
 
        For i = LigDebut To NbrLig
            If .Lines(i, 1) <> "" Then
                Ligne = .Lines(i, 1)
                Ligne = Replace(Ligne, Rechercher, Remplacer)
                .ReplaceLine i, Ligne
            End If
        Next i
    End With
End Sub

Tu trouveras plus d'info sur la manipulation des macros via macro dans le tuto ci-dessous :
http://silkyroad.developpez.com/VBA/VisualBasicEditor/
.

**modus57** · 02/10/2008, 13h24

Bonjour fring

Merci pour ta réponse, en effet les corrections que tu as apporté à la procédure fonctionne parfaitement.

J’ai consulté le tutorial de SilkyRoad mais je n’ai pas trouver de réponse pour la question suivante :

Comment insérer la ligne de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets(1).ScrollArea = ""

à la fin du module "Worksheet_SelectionChange" de "Feuil1"

Tu as peut-être la solution

@ + modus57

**modus57** · 02/10/2008, 17h24

Re Bonjour fring

Après avoir reconsulter le tutorial, j'ai modifier le code et cela fonctionne tip top

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub DésactiverScrollArea()
    RechercherRemplacer ThisWorkbook, "Feuil1", "Worksheet_SelectionChange"
End Sub
 
Sub RechercherRemplacer(Wbk As ThisWorkbook, CodeMod$, NomProc$)
    Dim Rechercher As String, Remplacer As String
    Dim i As Integer, Ligne As String
    Dim LigDebut As Integer, NbrLig As Integer
     
    Rechercher = "ScrollArea ="
    Remplacer = "'ScrollArea ="
    
    With Wbk.VBProject.VBComponents(CodeMod).CodeModule
        LigDebut = .ProcStartLine(NomProc, 0) '<-- ligne de début de la procédure "NomProc"
        NbrLig = .ProcCountLines(NomProc, 0) + LigDebut '<-- ligne de fin de la procédure "NomProc"
    
        For i = LigDebut To NbrLig
            If .Lines(i, 1) <> "" Then
                Ligne = .Lines(i, 1)
                Ligne = Replace(Ligne, Rechercher, Remplacer)
                .ReplaceLine i, Ligne
            End If
        Next i
        X = .CountOfLines
            .InsertLines X - 1, "Worksheets(1).ScrollArea = """        
    End With
End Sub