Discussion :

[frisou65]

Bonjour,
j'ai un problème de dimensionnement de la zone de traçage de mon graph. J'ai écrit le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
        ActiveChart.PlotArea.Select
        ActiveChart.PlotArea.Left = 3
        ActiveChart.PlotArea.Top = 33
        ActiveChart.PlotArea.Width = 176
        ActiveChart.PlotArea.Height = 86

Et ça marche pas pourtant quand je fais avec l'enregistreur de macro il me marque ça donc je ne comprends pas. Est ce que quelqu'un peut m'aider?
Merci d'avance.

[zazaraignée]

ActiveChart correspond au graphe sélectionné... Est-ce que ton graphe à redimentionner est sélectionné quand tu démarres ta macro?

[frisou65]

oui

Je ne comprends pas car quand je fais du pas à pas ça marche le code que j'ai écrit mais quand je fais pas du pas à pas il me redimensionne pas la zone de traçage.
Comment je peux faire pour forcer le redimensionnement?

[zazaraignée]

Je n'ai pas d'explications. Chez moi, ça marche très bien.

Tu remet (à la main) les dimensions à peu près telles qu'elles étaient avant de faire un autre test?

J'ai un peu modifié ton code pour éliminer les redondances.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub TailleZoneTracage()  ' pas d'accents dans les noms
    With ActiveChart.PlotArea
        ' Voir la position et la taille acutelles dans la
        ' fenêtre d'exécution (Ctrl + G).
        Debug.Print .Left, .Top, .Width, .Height
        ' Appliquer les nouvelles dimensions.
        .Left = 3
        .Top = 33
        .Width = 176
        .Height = 86
    End With
End Sub

J'ai même fait ceci (qui modifie la taille de tout le graphe):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub TailleDuGraphique()
    Dim nomGraph As String, pos As Integer
    ' le nom du graphe débute par le nom de la feuille et un espace
    nomGraph = ActiveChart.Name 
    ' trouver la position de l'espace
    pos = InStr(nomGraph, " ")  
    ' ne garder que le nom 
    nomGraph = Right(nomGraph, Len(nomGraph) - pos)du graphe
    ' modifier les dimensions du graphe
    With ActiveSheet.Shapes(nomGraph)
        .ScaleWidth 0.6, msoFalse, msoScaleFromTopLeft
        .ScaleHeight 0.65, msoFalse, msoScaleFromTopLeft
    End With
End Sub

[Edit : petit ajout] Même chose en plus court:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub TailleDuGraphe()
    With ActiveSheet.Shapes(Right(ActiveChart.Name, _
            Len(ActiveChart.Name) - InStr(ActiveChart.Name, " ")))
        .ScaleWidth 0.6, msoFalse, msoScaleFromTopLeft
        .ScaleHeight 0.65, msoFalse, msoScaleFromTopLeft
    End With
End Sub

[frisou65]

bonjour à tous,
j'ai tenté ce que tu m'as donné zaza et encore une fois quand je le fais pas à pas ça marche et quand je le fais d'un coup ça ne marche pas mais ça ne m'affiche pas de message d'erreur.
Donc pour l'obliger à le faire j'ai créé une autre macro à coté qui est la suivante:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
    Sheets("Récap").Activate  
        Dim FL1 As Worksheet
        Set FL1 = ActiveSheet
        With FL1.Shapes(FL1.Shapes.Count)
            .Select            
        End With
        ActiveChart.PlotArea.Select
       With ActiveChart.PlotArea
        ' Voir la position et la taille acutelles dans la
        ' fenêtre d'exécution (Ctrl + G).
        Debug.Print .Left, .Top, .Width, .Height
        ' Appliquer les nouvelles dimensions.
        .Left = 3
        .Top = 33
        .Width = 176
        .Height = 86
        End With

La ligne en bleu pose un problème (elle me donne un message d'erreur 1004: la méthode select de la plotarea a échoué) mais pourtant il faut que je sélectionne la zone de traçage avant de la dimensionner et si j'écris pas la ligne en bleu ça marche pas dans tout les cas.
Est ce que quelqu'un aurait une idée qui pourrait m'aider?
Merci d'avance.

[frisou65]

J'ai toujours un problème avec mon dimensionnement de zone de traçage. J'ai tourné autrement ma macro mais je comprends pas ça ne marche toujours pas. Voici mon code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
        Dim FL1 As Worksheet
        Set FL1 = ActiveSheet       
        With FL1.Shapes(FL1.Shapes.Count)
            .Select            
        End With      
    ActiveChart.ChartArea.Select   
    ActiveChart.PlotArea.Select
    Selection.Left = 3
    Selection.Top = 33
    Selection.Width = 176
    Selection.Height = 86
    Selection.Width = 178
    Selection.Height = 86    
    ActiveChart.ChartArea.Select

La ligne en bleu me pose problème. J'ai une erreur 1004: la méthode select de la classe chartArea a échoué.
Est ce que quelqu'un peut m'aider. Je ne comprends pas pourquoi ça plante.
Merci d'avance.

[frisou65]

Bon j'ai encore modifié ma macro:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
        Dim FL1 As Worksheet
        Set FL1 = ActiveSheet
        
        With FL1.Shapes(FL1.Shapes.Count)
            .Select            
        End With
    With ActiveChart.PlotArea
        .Select
        .Left = 3
        .Top = 33
        .Width = 176
        .Height = 86
        .Width = 178
        .Height = 86
    End With

Quand je sélectionne a la main la zone de traçage la macro marche. Si je ne mets pas de select (ligne bleu) la macro ne me redimensionne pas la zone de traçage. Mais quand je l'écris dans ma macro ça plante.
Est ce que quelqu'un peut m'aider??
Merci d'avance.

[ouskel'n'or]

Déjà une explication sur ton message précédent

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
        Dim FL1 As Worksheet
        Set FL1 = ActiveSheet       
        With FL1.Shapes(FL1.Shapes.Count)
            .Select            
        End With

Avec ce code tu peux modifier les dimensions du graphe, pas de la zone de traçage.
Et avec ça ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
    ActiveSheet.ChartObjects(ActiveSheet.ChartObjects.Count).Activate
    ActiveChart.ChartArea.Select
    ActiveChart.PlotArea.Select
    Selection.Left = 3
    Selection.Top = 33
    Selection.Width = 178
    Selection.Height = 86

Tu dis

[fring]

Bonjour tlm,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub test_dim_graph()
Dim FL1 As Worksheet
Dim ChObj As ChartObject
 
Set FL1 = Sheets("feuil1")
Set ChObj = FL1.ChartObjects(FL1.ChartObjects.Count)
 
'pour dimensionner le graphique
With ChObj
    .Height = 400
    .Width = 600
    .Top = [C5].Top
    .Left = [C5].Left
End With
 
'pour dimensionner la zone de traçage
With ChObj.Chart.PlotArea
    .Height = 300
    .Width = 450
    .Left = 5
    .Top = 35
End With
 
End Sub

[zazaraignée]

Je ne comprends pas pourquoi tous ces .Select qui, de toutes façons, ralentissent l'exécution du code... Si tu as remarqué, j'avais dit que je ferais des changements dans ton code... J'ai utilisé un bloc With... End With pour éviter la répétition (qui me tue...) et j'ai éliminé les .Select (qui m'achèvent...).

Mais surtout, dis nous clairement ce que tu veux faire:
- Modifier la taille de la zone de traçage ?
- ou modifier la taille de tout le graphe ?

[Edit] Tiens! Je viens de voir le code de fring (salut). Je crois que tu as la solution qui est plus propre que de passer par les Shapes qui, en fait, sont n'importe quoi!

[frisou65]

Merci à tous!
j'essaie vos solutions et je vous dis si cela marche chez moi.
Zaza ce que je veux faire c'est bien modifier la taille de la zone de traçage.
Encore merci beaucoup à tous. Je vous tiens au courant dès que j'ai testé le code.

[frisou65]

J'ai testé vos codes: le code de fring marche bien et celui de ouskel'n'or aussi néanmoins quand je les teste plusieurs fois celui de ouskel'n'or à un pourcentage de succès plus important donc j'ai adopté ce dernier. Merci beaucoup à tous.