Discussion :

[nat44]

Bonjour,

Je crée une macro pour copier des feuilles d'un classeur1 vers un classeur2.

Pour cela je demande à ouvrir mon classeur1 : Pas de problème s'il était fermé. Mais s'il était déjà ouvert j'ai le message d'alerte suivant. "Classeur1 est déjà ouvert. si vous l'ouvrez à nouveau, toutes vos modifications seront perdues..."

Donc je cherche à créer une petite macro qui ne fasse rien si le classeur est ouvert, et qui l'ouvre sinon. J'ai essayé ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub testOuvertureFichier()
 If IsOpen.Workbooks("DevisFactures.xls") Then
 MsgBox ("ça fonctionne !")
 Else: Workbooks.Open Filename:="E:\DUT GEA\3ème année\Stage\DevisFactures.xls"
 End If
End Sub

Et là j'ai une erreur d'exécution : "objet requis"

A prioris l'erreur vient de IsOpen. Pouvez-vous m'aider à éclaircir tout ça ?

Merci
Nat

[zandru]

Bonjour,

ce que j'ai fait pour contourner ce problème, c'est parcourir les fichiers ouverts et comparer leurs noms. Si on trouve celui que l'on cherche c'est qu'il est ouvert:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim Flg As Boolean
Dim X As Integer
For X = 1 To Workbooks.Count
     If Workbooks(X).Name = "DevisFactures.xls" Then
          Flg = True
          MsgBox("ça marche")
     End If
Next X

donc si Flg=true c'est déjà ouvert
il ne te reste plus qu'à adapter et tester

[kiki29]

Salut, voir aussi sur la FAQ http://excel.developpez.com/faq/?pag...ClasseurOuvert

[nat44]

Merci pour ta réponse Zandru.

Ta macro fonctionne bien, mais le soucis est que je n'arrive pas à l'adapter.

Ce que je voudrais c'est :
si mon classeur est ouvert, je sors de la macro
S'il ne l'est pas, je l'ouvre

voici comment je l'ai modifiée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Test()
Dim Flg As Boolean
Dim x As Integer
For x = 1 To Workbooks.Count
     If Workbooks(x).Name = "DevisFactures.xls" Then
        Flg = True
        End
    Else
        Flg = False
        Workbooks.Open Filename:="E:\DUT GEA\3ème année\Stage\DevisFactures.xls"
    End If
Next x
End Sub

Mais si le classeur est ouvert, la macro ne s'arrête pas pour autant et essaye de me l'ouvrir une 2ème fois...

Pourquoi ?

A bientôt pour la suite
nat

Merci à toi aussi Kiki29.

J'ai fait comme tu as dit et j'ai été sur la FAQ (je n'avais pas vu cette question là ce matin)

J'ai fait du copier-coller, modifié quelques trucs et cela donne ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Test3()
    If VerifOuvertureClasseur("E:\DUT GEA\3ème année\Stage\DevisFactures.xls") Then
        End
    Else
        Workbooks.Open Filename:="E:\DUT GEA\3ème année\Stage\DevisFactures.xls"
    End If
End Sub

et aussi ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Function VerifOuvertureClasseur(Fichier As String) As Boolean
    Dim x As Integer
 
    On Error Resume Next
    x = FreeFile()
 
    Open Fichier For Input Lock Read As #x
    Close x
 
    If Err.Number = 0 Then VerifOuvertureClasseur = False
    If Err.Number = 70 Then VerifOuvertureClasseur = True
 
    On Error GoTo 0
End Function

Cela fonctionne parfaitement, sauf que j'ai copié sans comprendre ce que je faisais.

La partie sub, c'est bon. Mais la partie fonction... Je ne sais même pas quelle est la différence entre sub et fonction (je ne savais d'ailleurs pas qu'il existait autre chose que sub)
Il faut dire que je découvre et j'apprends la programmation des macros sur le tas avec mon stage.

Quelqu'un peut-il m'expliquer et me commenter cette partie là ?

Merci
Nat

[DeaD78]

Sub correspond à une procédure où il n'y a pas de "sortie". Function est une fonction (héhé) qui te renvoie une "sortie". En gros, dans ta fonction, tu lui passes un paramètre qui est un String et elle te retourne un Booléen en sortie.
Ainsi, pour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Test3()
    If VerifOuvertureClasseur("E:\DUT GEA\3ème année\Stage\DevisFactures.xls") Then
        End
    Else
        Workbooks.Open Filename:="E:\DUT GEA\3ème année\Stage\DevisFactures.xls"
    End If
End Sub

cela signifie que si ta fonction t'a retourné TRUE tu es dans le 1er cas. Le FALSE correspond au deuxième cas. La "sortie" correspond à un résultat généré par ta fonction qui peut ainsi être réutilisé hors de ta fonction.

C'est bien ça, hein? En ce qui concerne le code de la fonction, je laisse quelqu'un d'autre t'expliquer (et m'expliquer aussi au passage quelques points sombres sur lesquels je planche aussi )

[kiki29]

Salut,l'aide en ligne devrait être suffisante : sous VBE sélectionner Open puis [F1] , dans fenêtre "Aide contextuelle" la sélection par défaut "VBA open" étant la bonne, cliquer sur bouton Aide

[AlainTech]

Voici comment je procède:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
  Dim iErr As Long
  Dim strListFile As String
  Dim strListPath As String
  Dim wbkList As Workbook
  strListPath = "LeCheminDuRepertoire"
  strListFile = "LeNomDuFichier.xls"
  Err.Clear
  On Error Resume Next
  Set wbkList = Workbooks(strListFile)
  iErr = Err.Number
  On Error GoTo 0
  If Not iErr = 0 Then
    Set wbkList = Workbooks.Open(strListPath & "\" & strListFile)
  End If

[ouskel'n'or]

Une petite variante (qui ne change rien)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Dim CL1 As Workbook
On Error Resume Next
Set CL1 = Workbooks("UnClasseur.xls")
If Not CL1 Is Nothing Then
    MsgBox "Fichier ouvert"
    Else
    MsgBox "Fichier fermé"
End If
On error goto 0

(salut Alain)

[nat44]

Merci à tous,

Bon, je vais essayer de comprendre par moi-même ce qu'est une fonction. En tout cas plus de problèmes pour ma macro.

à bientôt sans doute...
Nat